Wikidata:Társalgó

From Wikidata
Jump to navigation Jump to search


Társalgó
A Wikidatával kapcsolatos kérdések helye. Ha jól beszélsz angolul, és nem magyar projektekhez kapcsolódik a kérdésed, érdemesebb lehet az angol társalgóban kérdezni, valószínűleg több választ kapsz kevesebb idő alatt.

Magyar szerkesztők a Wikidatán (add hozzá magad a bábelsablonnal)

Lásd még: hu:Wikipédia:Wikidata-segítségkérés

Barsi László[edit]

A súlyemelő Barsi Lászlót nyelvközi hivatkozással egybekapcsoltam az angol nyelvű szócikkel. Az angol Wikiben viszont a távfutóról van szócikk. --Holdkóros (talk) 19:08, 18 December 2017 (UTC)

✓ Done. Bencemac (talk) 12:56, 29 November 2018 (UTC)
I think that this discussion is resolved and can be archived. If you disagree, don't hesitate to replace this template with your comment. Bencemac (talk) 12:56, 29 November 2018 (UTC)

Wikidata:Requests for comment/Privacy and Living People[edit]

Additional proposals have been made on the RFC, and your comments are welcome. --MediaWiki message delivery (talk) 03:40, 9 April 2018 (UTC) (for Rschen7754)

I think that this discussion is resolved and can be archived. If you disagree, don't hesitate to replace this template with your comment. Bencemac (talk) 19:00, 29 November 2018 (UTC)

Star Wars: A régi Köztársaság és a Star Wars: Knights of the Old Republic (comics) szerintem nem ugyanaz[edit]

Gyanús, hogy a Star Wars: A régi Köztársaság és a Star Wars: Knights of the Old Republic (comics) nem egymás wikidata-párjai, mivel utóbbi 2006-2010 között jelent meg és más alkotók vannak (író: John Jackson Miller, rajzolók: Brian Ching, Bong Dazo), mint a Star Wars: A régi Köztársaságnak (Alexander Freed és Robert Chestney).

Ellenben a Star Wars: The Old Republic (comics) írói tényleg Rob Chestney és Alexander Freed voltak. Igaz, nem 2009 febr.-2011 okt., hanem 2010 júl.-2011 okt. között jelent meg. Apród (talk) 12:55, 11 July 2018 (UTC)

✓ Done, valóban. @Apród: A magyar cikk több sebből is vérzik, kéne kezdeni vele valamit (felsablonozni/TMB?). Bencemac (talk) 13:02, 29 November 2018 (UTC)

@Bencemac: Köszönöm. A magyar cikk sorsán még gondolkodom. Apród (talk) 14:01, 29 November 2018 (UTC)

Lekérdezés a WP-szócikk nélküli magyar elemekre[edit]

Hát, én még nagyon ugatom ezt a Query Service-t... Hosszas próbálkozás után jöttem ide: hogy tudok olyan lekérdezést csinálni, ami azokat a Wikidata-elemeket listázza, ahol

  • Az állampolgárság Hungary (Q28), és nem tartozik hozzá egyetlen egy Wikipédia szócikk sem (tehát se magyar, se külföldi, hanem WP kapcsolat nélküli adatlap)?
  • Remélem, hogy az előző alapján meg tudom csinálni, de ha mégsem, akkor egy olyat is szeretnék, ahol a country of origin (P495)-nál szerepel Hungary (Q28), és nincs semmilyen Wikipédia lap hozzá.
  • Végül ugyanezek, de úgy, hogy van valamilyen Wikipédia-lap hozzá kapcsolva, csak az nem magyar, vagyis a "hu" hiányzik.

Kösz előre is. Palotabarát (talk) 13:15, 15 November 2018 (UTC)

Cikk nélküliek:
SELECT DISTINCT ?item ?itemLabel WHERE {
    ?item wdt:P27 wd:Q28 .
    FILTER NOT EXISTS { ?article schema:about ?item } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
Try it!
Magyar cikk nélküliek:
SELECT DISTINCT ?item ?itemLabel (COUNT(?sitelink) AS ?sitelinks) WHERE {
    ?item wdt:P27 wd:Q28 .
    ?sitelink schema:about ?item .
    FILTER NOT EXISTS { ?huwiki schema:about ?item . ?huwiki schema:inLanguage "hu" } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?item ?itemLabel
ORDER BY ?sitelinks
Try it!  (sajnos nem sikerült kitalálnom, hogyan kéne szűrni az egycikkesekre, de mindenesetre cikkszám szerint növekvően van rendezve, így az első négy és fél oldal adja meg a kért elemeket). – Tacsipacsi (talk) 20:18, 15 November 2018 (UTC)
Tacsipacsi kösz szépen! Palotabarát (talk) 22:24, 15 November 2018 (UTC)
A fentiből kimaradtak azok, akiknek van pl. Wikiforrás-oldaluk vagy Commons-kategóriájuk.
Cikk nélküliek:
SELECT DISTINCT ?item ?itemLabel WHERE {
    ?item wdt:P27 wd:Q28 .
    FILTER NOT EXISTS { ?article schema:about ?item FILTER REGEX(STR(?article), ".wikipedia.org/wiki/")  } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
Try it!
Illetve bekerültek, akiknek nincs Wikipédia-szócikkük, csak pl. Wikiforrás-oldaluk vagy Commons-kategóriájuk.
Magyar cikk nélküliek:
SELECT DISTINCT ?item ?itemLabel (COUNT(?sitelink) AS ?sitelinks) WHERE {
    ?item wdt:P27 wd:Q28 .
    ?sitelink schema:about ?item FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") .
    FILTER NOT EXISTS { [] schema:about ?item; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?item ?itemLabel
ORDER BY ?sitelinks
Try it!
Ha kell ami az egyszócikkesekre van szűrve:
SELECT DISTINCT ?item ?itemLabel (COUNT(?sitelink) AS ?sitelinks) WHERE {
    ?item wdt:P27 wd:Q28 .
    ?sitelink schema:about ?item FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") .
    FILTER NOT EXISTS { [] schema:about ?item; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?item ?itemLabel
HAVING (?sitelinks = 1)
Try it!
Máté (talk) 08:38, 16 November 2018 (UTC)
Máté kösz szépen neked is! Palotabarát (talk) 10:36, 16 November 2018 (UTC)
@Palotabarát: Bocs, közben még valamit javítottam benne :). – Máté (talk) 13:25, 16 November 2018 (UTC)


félig OFF: Nem mindenhol van megadva az állampolgárság, de néha a szervezeten keresztül is meg lehet találni magyar személyeket. ( meg talán arra is jó a példa, hogy a MINUS -t szemléltesse. ) pl1. Magyar Politikai szervezetek tagjai - de nincsen magyar wiki oldaluk.

SELECT DISTINCT ?item ?itemLabel ?polszervezetLabel ?polszervezet WHERE {
    ?polszervezet wdt:P17 wd:Q28 .
    ?polszervezet wdt:P31/wdt:P279* wd:Q43229 .
    ?item wdt:P102 ?polszervezet .
    MINUS {
    ?hu_article schema:about ?item.
    ?hu_article schema:isPartOf <https://hu.wikipedia.org/>.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,ms,de,zh,lv,fi,id,ru,es,fr,da,pt,pl,it,sv,ceb". }
}

Try it!

pl2. Magyar Politikai szervezetek tagjai - de nincsen magyar wiki oldaluk és nincs megadva a magyar állampolgárság. ( most 8 találat )

SELECT DISTINCT ?item ?itemLabel ?polszervezetLabel ?polszervezet WHERE {
    ?polszervezet wdt:P17 wd:Q28 .
    ?polszervezet wdt:P31/wdt:P279* wd:Q43229 .
    ?item wdt:P102 ?polszervezet .
    MINUS { 
    ?hu_article schema:about ?item.
    ?hu_article schema:isPartOf <https://hu.wikipedia.org/>.
    }
    MINUS { ?item wdt:P27 wd:Q28. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,ms,de,zh,lv,fi,id,ru,es,fr,da,pt,pl,it,sv,ceb". }
}

Try it!

--ImreSamu (talk) 19:49, 16 November 2018 (UTC)

Tacsipacsi, Máté, ImreSamu kösz szépen mindannyiótoknak! A kérésem eredeti oka az volt, hogy az elmúlt hónapokban létrehoztam én is egy pár olyan elemet, amihez nem volt szócikk, egyszerűen azért, mert valahogy hivatkozni kellett rájuk, fontosak is voltak, de adathiányosak, ezért amolyan "félreteszem későbbre, majd megírom" okból összehordtam annyi adatot, amennyit tudtam. Fel is jegyezgettem mik azok, de vissza akartam ellenőrizni, tényleg megvannak-e a saját listámon, nem maradt ki egy-egy elem. Ehhez az ellenőrzéshez kellett volna eredetileg a cikktelenek listája. Gondoltam lesz belőlük mondjuk ötven. Hát lett 1300 :) De nem baj, mert egyrészt egy csomót javítottam, kiegészítettem, egy párat össze is vontam, mert találtam hozzájuk szócikket vagy másik Wd-elemet, de azért még lehet velük vacakolni.
De eszembe jutott még valami: a kért cikkek sorozatban van hat olyan lap, ami idegen nyelven megírt magyar Wiki-szócikk nélküli, de magyar vonatkozású cikkek vannak felsorolva (pl.: angol vagy a valamelyest karbantartott német). Azok 2011-ben készült listák, és azóta csak kézzel frissültek, vagyis ami mégis megíródott, azt egyenként törölték. Az jutott eszembe, hogy a fenti kódokat kiegészítve lehetne olyan bottal karbantartott listát is csinálni, ami a Wikidata-elemekre épül, nem a kategóriákra. A fenti listák halála ugyanis az, hogy hiába van meg a szócikk német, spanyol vagy pláne orosz címe, azt, hogy a magyarban hogy írnák a cikket, a robot nem tudja kitalálni (pl. az egyértelműsítést, vagy a kifejezések, idegen nyelvű elnevezések pontos magyar neveit a bot nem tudja kitalálni). Ellenben a Wikidata adatok magyar label és description mezői már informatívabbak (ha ki vannak töltve), abból már lehet listát csinálni.
Egyszer ha sok időnk lesz, a fenti kódok alapján lehet, hogy újra megcsinálhatnánk az idegen nyelven megírt, de a magyarból hiányzó, magyar vonatkozású listákat úgy, hogy automatikusan frissülve a Wikidatából veszi az adatokat. Megemlítem Binárist, aki a fent említett hat kért cikk lapot csinálta annak idején.
Inkább csak mint jövőbeni ötletet írtam le, nem kell most rögtön foglalkozni vele. Palotabarát (talk) 11:03, 17 November 2018 (UTC)
Tacsipacsi, Máté, ImreSamu közben elkészült a lista a kódok alapján, itt van: [1]. Kösz az ihlető segítséget. Lehet még egy kérésem? Egy olyan kódot tudnátok csinálni nekem, amiben egyben van az összes olyan magyar állampolgárságú személy tétele, akiknek nincs magyar Wikipédia szócikke? Tehát míg fent külön kód van azokról, akiknek semelyik Wikipédián nincs szócikkük, és külön kód azokról, akiknek van valamilyen nem magyar szócikkük, most ez a kettő egyben kellene.
És még egy kérdésem lenne. A tételek listázásakor az adatlap fejlécében szereplő Címke (Label) is megjelenik. Azt hogy lehet megcsinálni, hogy a Leírás (Description) is kiíródjon? (Próbáltam beleírni a kódba, de nem ismerem a szintaktikáját, nekem nem jött elő). Palotabarát (talk) 21:52, 23 November 2018 (UTC)
@Palotabarát: Az összes magyar cikk nélküli magyar állampolgárságú személy, a nulla cikkestől a 25 cikkel rendelkezőig:
SELECT DISTINCT ?item ?itemLabel ?itemDescription (COUNT(?sitelink) AS ?sitelinks) WHERE {
    ?item wdt:P27 wd:Q28 .
    OPTIONAL { ?sitelink schema:about ?item FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER NOT EXISTS { [] schema:about ?item; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY ?sitelinks
Try it! – Tacsipacsi (talk) 22:46, 23 November 2018 (UTC)


@Palotabarát: Ha már tisztogatás, ahogy látom rengeteg Magyarországhoz köthető sportoló személy is létezik - állampolgárság nélkül. ( amikor ezt irom: 253 személy )

  • A Sakkozók dominálnak.
  • Talán itt akár lehet más állampolgárság is. például a magyar NB1-ben játszhatnak külföldi - idegenlégiós játékosok is.
  • Ukrajnai magyar nevüeknél nem biztos, hogy célszerű megadni a "magyar" állampolgárságot.
# -----------------------------------------------------------------------------------------------------
#  Azok az emberek, 
#  - akik Magyarországhoz köthetően sportolnak, 
#  - de nincs megadva az állampolgárságuk.
# -----------------------------------------------------------------------------------------------------
#  Palotabarát-nak szeretettel,  ( készült: Tacsipacsi-kódját felhasználva)
#
SELECT DISTINCT ?item ?itemLabel ?itemDescription   (COUNT(?sitelink) AS ?sitelinks) WHERE {
    ?item   wdt:P1532 wd:Q28 .  # Country for sport = Hungary
    ?item   wdt:P31   wd:Q5.    # Instance of  = Human
    MINUS { ?item wdt:P27 ?citizenship } .  # Nincs citizenship megadva.
    OPTIONAL { ?sitelink schema:about ?item FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER NOT EXISTS { [] schema:about ?item; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,de,es,fr,pt,ru,zh,jp,ceb" }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY DESC (?sitelinks)  # csökkenő sorrendben kerül listázásra

Try it! --ImreSamu (talk) 11:37, 24 November 2018 (UTC)


ImreSamu, Tacsipacsi köszönöm mindkettőtöknek! A sakkozókat már én is észrevettem, a németek nagyon komolyan számontartják a világ sakkéletét :) Palotabarát (talk) 17:10, 24 November 2018 (UTC)

díjak feltüntetése és keresztnevek[edit]

Még ezt a kettőt nem látom át teljesen, segítsetek légyszi. Vannak a díjak, amiket úgy kell feltüntetni, hogy:

De emellett még vannak olyan minősítők, hogy: art prize (Q1792571), science award (Q11448906), architecture prize (Q1829324), television award (Q1407225) stb.

Ezeket a legkülönbözőbb helyekre biggyesztik: van, hogy kimarad a award (Q618779) jelölés az osztályból, és annak helyén csak a fentiek valamelyike látható, van, hogy az osztályban kettő szerepel: a díj, és mondjuk hogy művészeti díj, de olyan is, hogy az alosztályhoz kerül a művészeti (építészeti stb.) jelzés.

Hol a legjobb jelölni ezeket az "al"-meghatározásokat?

A másik, hogy vannak konkrétabb díj-jelölések, mint pl. a Japan Academy Prize (Q194258), British Academy Film Awards (Q732997) stb. Ezeket hova tegyem?

A kérdés arra vonatkozik, ha magának a díjnak az elemét csinálom meg.


Azt látom, hogy a keresztnevek közt nincs semmilyen átjárhatóság, külön van az Izrael (Q1098961) és a Israel (Q19819746), külön a Daniel (Q14516546), Dániel (Q17190118), Daniël (Q18040588) stb. Van logikája ennek is, mert az írásmód nem egyezik, de mit tegyünk pl. a Johannes Priwitzer (Q17093964) szócikk keresztnevéhez? Ő egy magyar származású, de angol és német nyelvterületen ismert festő, akit a magyar szakirodalom Priwitzer Jánosként ír, de leginkább külföldön ismert Johannes Priwitzerként. Most bukkantam az adatlapjára, de még nem javítottam át a keresztnevét, ami persze Johannes (Q2117521). Szélsőséges példának tűnik, de sok olyan személy van, aki máshol élt, mint ahol született, és többféle névváltozata ismert, de nem feltétlenül tudjuk, hogy mettől meddig élt itt vagy ott.

Kösz előre is Palotabarát (talk) 11:24, 25 November 2018 (UTC)


Nem biztos, hogy értem a kérdést, de nekem ez amolyan Taxonomia problémára hasonlít. Nekem elég kaotikusnak tünik a fogalmak hierarchiába rendezése, a földrajzi területwkwn mindenképp, de a díjaknál is hasonló.

Egy Kezdetleges SPARQL lekérdezés

#
 # Díjak - hierarchiája 
 # Ez néha többszintes,  most csak az egyszerűség miatt csak az egyel feletibb szintet listázom.
 # Nem tökéletes ,  quick&dirty lekérdezés.
 #
 SELECT  ?broaderLabel  ?broader ?itemLabel ?item ?instances ?sites WITH {
    SELECT DISTINCT ?item { ?item wdt:P279* wd:Q618779 }
  } AS %items WHERE { 
    INCLUDE %items .
    OPTIONAL { ?item wdt:P279 ?broader } .
    {
      SELECT ?item (count(distinct ?element) as ?instances) {
        INCLUDE %items.
        OPTIONAL { ?element wdt:P31 ?item }
      } GROUP BY ?item
    }
    {
      SELECT ?item (count(distinct ?site) as ?sites) {
        INCLUDE %items.
        OPTIONAL { ?site schema:about ?item }
      } GROUP BY ?item
    }
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "hu,en,de,es,fr,it,ru,uk,bg,zh,ja,ko"
    }
  }
ORDER BY  ?broaderLabel  ?broader ?itemLabel ?item

Try it!


Nekem a másik fajta lekérdezés jobban tetszik:

  • Lekérdezés eredménye wdtaxonomy programmal -> "Díjak - hierarchiája" vagyis egy többszintes hierarchiát képzelj el. Hogy össze vissza kötögetik őket - az már egy másik probléma ...

de szerintem nem biztos, hogy értem a kérdést. Elnézést.

--ImreSamu (talk) 21:12, 25 November 2018 (UTC)


Itt nem lekérdezésről volt szó, hanem hogy hogyan kell jelölni a díjakat és keresztneveket. Nos, elegendő a legspecifikusabbat, elvileg minden díjnál van subclass of (P279)  award (Q618779) (akár direkten, akár indirekten, még néhány, egyre kevésbé specifikus kategórián keresztül) – ha mégsincs, akkor kikötésmegszegés keletkezik, amikor felviszed egy díjazott adatlapjára, ilyenkor a díjtípushoz hozzá kell adni a fenti állítást (vagy egy specifikusabbat, ugyanúgy subclass of (P279) tulajdonsággal, ha találsz). Az Oscar-díjak (pl. Academy Award for Best Live Action Short Film (Q1324407)) alapján úgy tűnik, ez igaz a még konkrétabb kategóriákra is. A keresztnevekre viszont nem találtam semmilyen útmutatót, szerintem senki nem gondolt arra, hogy valakinek nem egyértelmű, pontosan hogyan írják a nevét… – Tacsipacsi (talk) 23:59, 25 November 2018 (UTC)

Nekem a tulajdonság leírólapja alapján az tűnik a legtisztább megoldásnak, ha mindkettőt ráteszed a(z) language of work or name (P407) minősítővel. – Máté (talk) 09:14, 26 November 2018 (UTC)

Tacsipacsi, Máté, ImreSamu kösz szépen mindannyiótoknak! Palotabarát (talk) 21:14, 29 November 2018 (UTC)

HAVING paraméter szűrőként?[edit]

Valahogy be lehet rakni a HAVING paramétert egy lekérdezés szűrői (FILTER) közé? Jelentősen felgyorsítaná, amit csinálok, jelenleg csak a kimeneti paraméterek között tudom használni, de gyakran egyéb kényszerű filterekkel kell bővítenem a lekérdezést, például itt lent születési intervallumok szerint haladok, máskülönben elakad a nagy adatmennyiségtől. Pasztilla (talk) 08:37, 2 December 2018 (UTC)

SELECT DISTINCT ?politik ?politikLabel ?politikDescription (COUNT(distinct ?sitelink) AS ?sitelinks) WHERE {
    ?politik wdt:P106 wd:Q82955 .
    ?politik wdt:P569 ?szul .
    OPTIONAL { ?sitelink schema:about ?politik FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER (?szul > "1947-01-01T00:00:00Z"^^xsd:dateTime) .
    FILTER (?szul < "1950-01-01T00:00:00Z"^^xsd:dateTime) .
    FILTER NOT EXISTS { ?politik wdt:P570 ?date } . # Nem halt még meg.
    FILTER NOT EXISTS { [] schema:about ?politik; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,fr" }
}
GROUP BY ?politik ?politikLabel ?politikDescription
HAVING (?sitelinks > 29)

Try it!


A SERVICE wikibase:label sokat lassít, ha azt kihagyod, lefut a születés szerinti szűrés nélkül is a lekérdezés. A címkét (és leírást), ha elég csak a pl.magyar, máshogy is ki lehet gyűjteni:

?politik rdfs:label ?politikLabel FILTER ( lang(?politikLabel) = "hu" )

Egyébként mivel a ?sitelinks aggregált változó, így nem lehet a filterek közé beemelni, hacsak nem egymásba ágyazott lekérdezéseket használsz. De itt a legegyszerűbb megoldás a wikibase:label-től való megszabadulás. – Máté (talk) 21:00, 2 December 2018 (UTC)

Köszönöm, nézem, csinálom. Pasztilla (talk) 17:31, 3 December 2018 (UTC)

@Máté: Biztosan valamit rosszul csinálok, de ugyanúgy időkorlát-elérésre hivatkozva elakad, nem fut le, hiába veszem ki a service-t és rakom be a te sorodat. Pasztilla (talk) 18:51, 5 December 2018 (UTC)

@Pasztilla: - beágyazottal lekérdezésként működik. kivül csak a labeleket és a descriptiont kapja meg. ( Sitelinks>10-re tesztelve )

SELECT DISTINCT ?politik ?politikLabel ?politikDescription ?sitelinks
WHERE {
{
  SELECT DISTINCT ?politik (COUNT(distinct ?sitelink) AS ?sitelinks) WHERE {
    ?politik wdt:P106 wd:Q82955 .
    OPTIONAL { ?sitelink schema:about ?politik FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER NOT EXISTS { ?politik wdt:P570 ?date } . # Nem halt még meg
    FILTER NOT EXISTS { [] schema:about ?politik; schema:isPartOf <https://hu.wikipedia.org/> } .
   }
   GROUP BY ?politik
   HAVING (?sitelinks > 10)
  }
SERVICE wikibase:label {bd:serviceParam wikibase:language "hu,en,fr,de,es,it,ru,uk,bg,zh,ja,ko"}
}
ORDER BY DESC (?sitelinks)

Try it!

--ImreSamu (talk) 22:16, 5 December 2018 (UTC)

Ez meg egy olyan módosítása, ami kiszűri azokat is, amelyeknek már van magyar címkéje.

SELECT DISTINCT ?politik ?politikLabel ?politikDescription ?sitelinks
WHERE {
{
  SELECT DISTINCT ?politik (COUNT(distinct ?sitelink) AS ?sitelinks) WHERE {
    ?politik wdt:P106 wd:Q82955 .
    OPTIONAL { ?sitelink schema:about ?politik FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER NOT EXISTS { ?politik wdt:P570 ?date } . # Nem halt még meg
    #Nincs magyar wikipedia oldala
    FILTER NOT EXISTS { [] schema:about ?politik; schema:isPartOf <https://hu.wikipedia.org/> } .
    #  Nincs magyar description-ja ! 
    FILTER(NOT EXISTS { ?politik schema:description ?politikdesc. FILTER(LANG(?politikdesc) = "hu")  })    
   }
   GROUP BY ?politik
   HAVING (?sitelinks > 10)   
  }
SERVICE wikibase:label {bd:serviceParam wikibase:language "hu,en,fr,de,es,it,ru,uk,bg,zh,ja,ko"}
}
ORDER BY DESC (?sitelinks)

Try it!

--ImreSamu (talk) 11:43, 6 December 2018 (UTC)

Köszönöm, kiválóan működik és gyors is. Pasztilla (talk) 17:48, 9 December 2018 (UTC)

Syntrichia ruraliformis duplán[edit]

Sziasztok!

Elkezdtem a saját szerkesztésű wikipédia szócikkeknél a taxonbar adatokat átnézni és belefutottam egy olyan hibába, hogy a Syntrichia ruraliformis kétszer szerepel a wikidata-ban: Q12336652 és Q19843665. Az elsőben van benne a magyar wikipédia szócikk (és egy dán) a másodikban az angol és sok más oldal. Valahogy egyesíteni lehet a kettőt? Üdv, Veszt (talk) 11:51, 8 December 2018 (UTC)

@Veszt: → ← Merged. Bencemac (talk) 12:03, 8 December 2018 (UTC)
@Bencemac: Köszönöm!  – The preceding unsigned comment was added by Veszt (talk • contribs) at 12:18, 8 December 2018 (UTC).

Rachel Laurin[edit]

Rachel Laurin (Q3416104) jelentős zeneszerző is. Ez nem szerepel a wd lapján. Köszönöm, ha valaki beírja, mert én nem értek ehhez. Tulipanos (talk) 20:57, 22 December 2018 (UTC)

Tulipanos beírtam. Azért leírom, hátha kedvet kapsz hozzá :) Az adatlapján egy foglalkozás már meg volt adva, így csak az "érték hozzáadása" linkre kell kattintani a foglalkozás dobozban, és rögtön felbukkan egy beviteli mező, ahova be lehet írni az új foglalkozást. Arra kell figyelni, hogy csak olyan foglalkozás írható be, ami már szerepel az adatbázisban, de ritka, hogy valami ne lenne benne. Ha mégsincs amit keresel, meg kell próbálni szinonimákkal, aztán angolul, hátha csak nincs lefordítva. Ha így sem jön elő, akkor írj ide. Ha az adatlapon egyáltalán nincs még feltüntetve foglalkozás (mert pl. egy teljesen új szócikk adatait viszed fel), akkor az állítás hozzáadása linkre kell kattintani, amire kiad egy "üres" dobozt. Oda kell beírni először, hogy "foglalkozás", aztán a mellette felbukkanó beviteli mezőbe a szakmát. Palotabarát (talk) 21:14, 22 December 2018 (UTC)

Köszönöm az információt..Tulipanos (talk) 08:46, 23 December 2018 (UTC)

Foglalkozások[edit]

Sziasztok, szerintetek ennek az elemnek: classical scholar (Q2468727) (klasszika-filológusnak van írva) mi lehet a helyes magyar címkéje? Azért kérdem, mert létezik egy másik classical philologist (Q16267607) elem is, és annak a leírása, ill. a csatolt szócikkek jobban passzolnak. Palotabarát (talk) 22:13, 28 December 2018 (UTC)

@Palotabarát: ókortudós? – Máté (talk) 23:37, 28 December 2018 (UTC)
Az ókortudós tágabb, ez csak a görög-római világgal foglalkozó történész, aki közelítően tényleg a klasszika-filológus. Pasztilla (talk) 08:45, 29 December 2018 (UTC)

Máté, Pasztilla kösz mindkettőtöknek, amíg nincs jobb, átírtam ókortudósra. Az angol/német egyébként az antiquarian/altertumsforscher kifejezéseket is használja rá, de én ezzel sem lettem előrébb. Ha lesz valami közmegegyezés, tovább lehet javítani, de addig se maradjon két egyforma elnevezés. Palotabarát (talk) 22:40, 29 December 2018 (UTC)

Lelkész[edit]

Ez is okozott már párszor főfájást:

  • pastor (Q152002) - lelkipásztor, lelkész. Én ezt használnám a római katolikus papokhoz, bár a magyar lelkipásztor van megadva, mint bármely keresztény egyház papját.
  • presbyter (Q831474) - keresztény pap, lelkipásztor keresztény egyházban, lelkész. A magyar leírás alapján őt is inkább r. kat. papnak gondolnám, de végső soron bármi lehet, hiszen az evangélikus, raformátus, stb. is keresztény egyház, de őket inkább lelkésznek mondják, nem papnak. Őt egyébként a magyar presbiterhez, mint ókeresztény méltósághoz kötik.
  • minister (Q1423891) - lelkész.
  • worship pastor (Q17040649) - lelkész.

Ti melyiket használnátok egy adventista lelkészhez? Bevallom a vallással, egyházzal kapcsolatos műveltségem hiányos, de a magyarban lehetnének jobban elkülönülő megnevezések is a lelkészre. Ha tudtok, segítsetek légyszi javítani a magyar elnevezéseket. Palotabarát (talk) 21:00, 9 January 2019 (UTC)

huwiki-kapcsolat létrejötte[edit]

Próbáltam a Special:NewPages segítségével a huwikin átnézni a 2018-ban létrejött új szócikkeket, de az csak egy hónapra visszamenőleg mutatja az új lapokat. Itt a Wikidatán létezik-e olyan lekérdezési lehetőség, ami kilistázza tetszőleges egyéb paraméterek mellett (mondjuk írók vagy települések vagy bármi) azokat, amelyeknek huwiki-kapcsolata 2018-ban került a Wikidata-elemre? Pasztilla (talk) 10:01, 3 January 2019 (UTC)

Közben tárgytalanná vált, a huwikin megoldották. Pasztilla (talk) 20:54, 3 January 2019 (UTC)

Alma mater lekérdezés[edit]

Sziasztok! Tudnátok segíteni egy olyan Query Service lekérdezés megírásában, ahol azokat a szócikkeket kapom, ahol

És ettől függetlenül érdekel egy olyan is, ahol

Kösz, ha tudtok segíteni Palotabarát (talk) 19:46, 8 January 2019 (UTC)

Az első:

SELECT DISTINCT ?item ?sitelink WHERE {
  ?item wdt:P27 wd:Q28; p:P69 ?s .
  MINUS { ?s pq:P582 [] }
  ?sitelink schema:about ?item; schema:isPartOf <https://hu.wikipedia.org/> .
}

Try it!

A második:

SELECT DISTINCT * WHERE {
  ?item wdt:P27 wd:Q28; wdt:P69 [] .
  ?sitelink schema:about ?item; schema:isPartOf <https://hu.wikipedia.org/> .
}

Try it! Máté (talk) 20:29, 8 January 2019 (UTC)

Az én verzióm ( minden iskoláját feltüntetem, emiatt több sor , és azok is benne vannak akiknek nincs magyar wiki oldaluk) : A két lekérdezés között csak egy MINUS->OPTIONAL kölönbség van. Lehet szabadon bővítani.

SELECT DISTINCT ?itemLabel ?item ?eduLabel ?start ?end  WHERE
{ 
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P27 wd:Q28 .
  ?item    p:P69 ?education_statement .
  ?education_statement ps:P69 ?edu .
  OPTIONAL { ?education_statement pq:P580 ?start . }
  MINUS    { ?education_statement pq:P582 ?end     }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,de,fr" . }
} ORDER BY ?itemLabel

Try it!

SELECT DISTINCT ?itemLabel ?item ?eduLabel ?start ?end  WHERE
{ 
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P27 wd:Q28 .
  ?item    p:P69 ?education_statement .
  ?education_statement ps:P69 ?edu .
  OPTIONAL { ?education_statement pq:P580 ?start . }
  OPTIONAL { ?education_statement pq:P582 ?end     }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,de,fr" . }
} ORDER BY ?itemLabel

Try it!

--ImreSamu (talk) 21:29, 8 January 2019 (UTC)

v2. - részletesebb és pontosabb lista. minden elem opciós, ha azok kellenek ami nincs megadva - akkot irt át az "OPTIONAL"-t "MINUS"-ra az adott elemnél.

SELECT DISTINCT ?itemLabel ?item ?eduLabel ?start ?end ?adegreeLabel ?amajorLabel  WHERE
{ ?item wdt:P27 wd:Q28 .
  ?item p:P69 ?education_statement .
  OPTIONAL {?education_statement ps:P69  ?edu    }
  OPTIONAL {?education_statement pq:P580 ?start  }
  OPTIONAL {?education_statement pq:P582 ?end    }
  OPTIONAL {?education_statement pq:P512 ?adegree}
  OPTIONAL {?education_statement pq:P812 ?amajor }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en,de,fr,it,es,ru,zh" . }
} ORDER BY ?itemLabel ?start ?end

Try it!

--ImreSamu (talk) 21:51, 8 January 2019 (UTC)


Máté, ImreSamu kösz szépen mindkettőtöknek! Palotabarát (talk) 11:43, 9 January 2019 (UTC)

Befejezetlen egyetemek, főiskolák[edit]

Sziasztok, szerintetek hogy kellene jelölni azt, ha valaki:

  1. elkezd egy egyetemet, de nem fejezi be azt (nem szerez diplomát)
  2. elkezd egy egyetemet, de egy másik egyetemen szerez diplomát
  3. elvégez egy egyetemet, de közben áthallgat egy másik egyetemre, de a diplomát nem ott kapja, hanem ott, ahol kezdte a tanulmányait
  4. elvégez egy egyetemet, majd ugyanott továbbtanul és tudományos fokozatot szerez

Az educated at (P69) tulajdonságban csak end time (P582) minősítő van, "abbahagyás ideje" vagy hasonló nincs. De nyilván nem is mindegyik fenti szituáció "abbahagyás", ha valaki elvégez egy teljes évet valahol, akkor másutt folytathatja a tanulmányait.

Példák:

  1. Ferenc Molnár (Q296809) (hu:Molnár Ferenc) két egyetemre is járt, de nem diplomázott
  2. Magda Kósáné Kovács (Q6729801) (hu:Kósáné Kovács Magda) Debrecenben kezdte el, majd Budapesten fejezte be az egyetemet
  3. az áthallgatásra most nem találtam példát, de sok hasonlóra emlékszem (pl. egy év ösztöndíjjal külföldön tanult)
  4. Pál Selényi (Q250525) (hu:Selényi Pál) visszament az ELTÉ-re doktorálni

Az első három példában talán egy új minősítőre lenne szükség (nem befejez, hanem abbahagy, de ez sem pontosan fedi a helyzetet), a negyedik esetben pedig az infoboxban volna jó összesíteni az azonos iskolákat, hogy ne szerepeljen kétszer ugyanaz az egyetem. Magukban az infoboxokban kézi beírással akárhogy jelölhetjük ezeket az eltéréséket, de a Wikidatán nem. Ha az infoboxok később fejlődnek, félreérthetően jöhetnek le az adatok: például aki két egyetemre járva szerezte a diplomáját, úgy tűnhet az infoboxban, mintha két diplomája lenne.

Figyelembe kell venni azt is, hogy nagyon sok esetben nem ismerjük a felsőoktatási tanulási időszak kezdetét, és az is gyakori, hogy nem tudjuk pontosan miként végzett (a kart tudjuk, de a fő szakirányt nem).

Ha itt nem tudunk jó választ adni, esetleg fel lehetne vetni a kérdést egy új minősítő beépítése kezdeményezésével. Mi a véleményetek? Palotabarát (talk) 09:13, 10 January 2019 (UTC)

Az első esetben szerintem a

subject > educated at (P69) View with SQID object or value >
academic degree (P512) View with SQID < no value Help >

megoldás működik. A negyedik esetben pedig a többszörös felvitel a jó megoldás. Ha ez gond az infoboxban, akkor azt a Wikipédián kell megoldanunk, nem itt. Fun fact: az AkH. 288. a) szerint helyesen ELTE-re.Máté (talk) 10:02, 10 January 2019 (UTC)

Máté az első esetben arra gondolsz , hogy érték nélkül mentsem el a academic degree (P512)-t? Palotabarát (talk) 09:13, 11 January 2019 (UTC)
@Palotabarát: A van két különleges érték, a novalue és a somevalue – az első azt jelenti, hogy az adott dolog nincs, nem létezik, a második pedig, hogy létezik, csak nem tudjuk miaz (pl. egy ismeretlen születési dátumnál). (Ezeket úgy tudod megadni, hogy szerkesztéskor a értékmező előtti kis téglalapokra kattintasz, közvetlen a rangjelölő mögött.) Jelen esetben, ha minősítőként megadod az egyetemhez, hogy a megszerzett diploma novalue (azaz nincs érték), akkor ebből látható, hogy az adott egyetemen nem szerzett diplomát. – Máté (talk) 10:06, 11 January 2019 (UTC)
Máté így valahogy? [2] Palotabarát (talk) 10:42, 11 January 2019 (UTC)
@Palotabarát: Nem, ez most azt jelenti, hogy nem járt iskolába. Az iskolát megadod, és ahhoz minősítőként a P512-t nincs értekkel. – Máté (talk) 10:57, 11 January 2019 (UTC)
Máté jaja, értem: [3] (remélem). Köszönöm Palotabarát (talk) 11:11, 11 January 2019 (UTC)

Könyvtárosok kérdezik[edit]

Sziasztok, könyvtárosok kérdezik, hogy egy folyóirat köré csoportosuló szerzői kört miként lehet felvinni a Wikidatára. Tehát nem editor-in-chief (P5769), nem editor (Q1607826) és nem is employee (Q703534) az, amit keresünk, hanem annak a jelölése, hogy a folyóiratba több-kevesebb rendszerességgel írókat milyen tulajdonsággal lehet összekapcsolni oda-vissza. Kösz előre is (példa: a Nyugat (Q661916)-hoz hogy kössük Béla Balázs (Q469963)-t és viszont). Palotabarát (talk) 10:47, 17 January 2019 (UTC)