Wikidata:WikiProject Czech Republic/Showcase Queries

Home

Czech Properties

Maintenance Queries

Showcase Queries

Interesting external databases

Events

Tools

Thematic areas

Projects

Map of Czech castles

The following query uses these:

• Items: castle (Q23413)   , Czech Republic (Q213)   

• Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , coordinate location (P625)   , image (P18)   , architectural style (P149)   

Features: map (Q24515275)   

# Map of Czech castles
#defaultView:Map{"hide":["?coord", "?img"]}
SELECT ?item ?itemLabel ?coord ?img ?styleLabel
WHERE
{
	?item wdt:P31/wdt:P279* wd:Q23413 .
	?item wdt:P17 wd:Q213 .
	?item wdt:P625 ?coord .
	OPTIONAL { ?item wdt:P18 ?img } .
	OPTIONAL { ?item wdt:P149 ?style } .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } .
}

Try it!

List of Czech companies

The following query uses these:

• Items: business (Q4830453)   , Czech Republic (Q213)   

• Properties: instance of (P31)   , headquarters location (P159)   , located in the administrative territorial entity (P131)   

  # List of Czech companies
  SELECT ?item ?itemLabel ?hqLabel
  WHERE
  {
    ?item wdt:P31 wd:Q4830453 .
    ?item wdt:P159 ?hq . ?hq wdt:P131* wd:Q213 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "cs,en" } .
  }
  ORDER BY ?itemLabel
  

Try it!

Parts of the cultural monument of the Prague Castle

The following query uses these:

• Items: part of cultural heritage site in the Czech Republic (Q30118385)   , Prague Castle (Q193369)   

• Properties: coordinate location (P625)   , image (P18)   , heritage designation (P1435)   , of (DEPRECATED) (P642)   

Features: ImageGrid (Q24515278)   

# Parts of the cultural monument of the Prague Castle
#defaultView:ImageGrid{"hide":["?img"]}
SELECT ?objectLabel ?img WHERE {
  ?object p:P1435 [ ps:P1435 wd:Q30118385; pq:P642 wd:Q193369 ] .
  ?object wdt:P625 ?coord .
  ?object wdt:P18 ?img .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "cs" } .
}

Try it!

Municipalities colour-coded by rising or falling population between 1930 and 1950

The following query uses these:

• Items: municipality of the Czech Republic (Q5153359)   

• Properties: instance of (P31)   , coordinate location (P625)   , population (P1082)   , point in time (P585)   

Features: map (Q24515275)   

# Municipalities colour-coded by rising or falling population between 1930 and 1950
#defaultView:Map{"hide":["?coord"]}
SELECT ?item ?coord ?populace1930 ?populace2001 ?prirustek (IF(?prirustek > 1, CONCAT(">", STR(IF(?prirustek > 4, 4, FLOOR(?prirustek))), "x"), "prirustek") AS ?layer) WHERE {
  ?item wdt:P31 wd:Q5153359; wdt:P625 ?coord .
  ?item p:P1082 [ ps:P1082 ?populace1930; pq:P585 ?datum1930 ] .
  FILTER (YEAR(?datum1930) = 1930) .
  ?item p:P1082 [ ps:P1082 ?populace2001; pq:P585 ?datum2001 ] .
  FILTER (YEAR(?datum2001) = 1950) .
  BIND ( ?populace1930 / ?populace2001 AS ?prirustek ) .
}

Try it!

Male/female ratio in Czech municipalities

The following query uses these:

• Items: municipality of the Czech Republic (Q5153359)   

• Properties: instance of (P31)   , population (P1082)   , male population (P1540)   , female population (P1539)   

  #Male/female ratio in Czech municipalities
  #defaultView:BarChart
  SELECT DISTINCT ((?zeny / ?muzi) AS ?result) ?item ?itemLabel ?muzi ?zeny
  WHERE
  {
      ?item wdt:P31 wd:Q5153359 .
      ?item p:P1082 ?populace .
      ?populace a wikibase:BestRank .
      ?populace pq:P1540 ?muzi .
      ?populace pq:P1539 ?zeny .
      SERVICE wikibase:label { bd:serviceParam wikibase:language "cs" } .
  }
  ORDER BY DESC(?result)
  LIMIT 50
  

Try it!

Map of Czech villages with name ending with -no

The following query uses these:

• Items: human settlement (Q486972)   , Czech Republic (Q213)   

• Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , coordinate location (P625)   

Features: map (Q24515275)   

#Map of Czech villages with name ending with -no
#defaultView:Map{"hide":["?coord"]}
SELECT DISTINCT ?item ?itemLabel ?coord WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q486972. hint:Prior hint:gearing "forward".
  ?item wdt:P17 wd:Q213.
  ?item wdt:P625 ?coord.
  ?item rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "cs")
  FILTER(STRENDS(?itemLabel, "no"))
}

Try it!

Number of descendants of Bořivoj I.

Manually update chart

WDQS | PetScan | TABernacle | Find images | Recent changes

372015 📈

End of automatically generated list.

List of hospitals

• see Wikidata:WikiProject Medicine/Hospitals by country/Czech Republic

Map of railway lines

The following query uses these:

• Items: railway (Q22667)   , Czech Republic (Q213)   , railway station (Q55488)   , metro station (Q928830)   

• Properties: instance of (P31)   , subclass of (P279)   , part of (P361)   , country (P17)   , coordinate location (P625)   , adjacent station (P197)   , end time (P582)   

Features: map (Q24515275)   

#defaultView:Map{"hide":["?coord1", "?coord1lat", "?coord1lon", "?coord2", "?coord2lat", "?coord2lon", "?str", "?line"]}
SELECT * WHERE {
  ?comm1 wdt:P31/wdt:P279*/wdt:P361 wd:Q22667 ; wdt:P17 wd:Q213 ; wdt:P625 ?coord1 ; wdt:P197 ?comm2 .
  MINUS { ?comm1 p:P31 [ ps:P31 wd:Q55488 ; pq:P582 [] ] } .
  MINUS { ?comm2 p:P31 [ ps:P31 wd:Q55488 ; pq:P582 [] ] } .
  MINUS { ?comm1 p:P31 [ ps:P31 wd:Q928830 ] } .
  MINUS { ?comm2 p:P31 [ ps:P31 wd:Q928830 ] } .
  ?comm2 wdt:P625 ?coord2 .
  ?comm1 p:P625 [ ps:P625 []; psv:P625 [ wikibase:geoLongitude ?coord1lon; wikibase:geoLatitude ?coord1lat; ] ] .
  ?comm2 p:P625 [ ps:P625 []; psv:P625 [ wikibase:geoLongitude ?coord2lon; wikibase:geoLatitude ?coord2lat; ] ] .
  BIND(CONCAT('LINESTRING (', STR(?coord1lon), ' ', STR(?coord1lat), ',', STR(?coord2lon), ' ', STR(?coord2lat), ')') AS ?str) .
  BIND(STRDT(?str, geo:wktLiteral) AS ?line) .
}

Try it!

CEO of Ředitelství silnic a dálnic

The following query uses these:

• Items: Q63486417

• Properties: position held (P39)   , start time (P580)   , end time (P582)   

  #defaultView:Timeline
  select ?reditel ?reditelLabel ?start ?end where {
    ?reditel p:P39 ?position.
    ?position ps:P39 wd:Q63486417;
              pq:P580 ?start;
              pq:P582 ?end.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "cs,en" } .
  }
  

Try it!

Pták roku

The following query uses these:

• Items: Bird of the Year (Q12047564)   

• Properties: image (P18)   , award received (P166)   , point in time (P585)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid{"hide":["?obrazek"]}
select ?item (?sitelink_Label AS ?itemLabel) ?rok (sample(?img) as ?obrazek) where {

  ?item p:P166 [ ps:P166 wd:Q12047564 ; pq:P585 ?datum ] .
  ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" . ?sitelink schema:name ?sitelink_Label .
  ?item wdt:P18 ?img . 
  bind(year(?datum) as ?rok) .
}
group by ?item ?sitelink_Label ?rok 
order by desc(?rok)

Try it!

Buildings on Wenceslas Square

The following query uses these:

• Items: building (Q41176)   , Wenceslas Square (Q847613)   

• Properties: instance of (P31)   , subclass of (P279)   , conscription number (P4856)   , image (P18)   , located on street (P669)   , house number (P670)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid{"hide":["?img"]}
SELECT DISTINCT ?item ?itemLabel ?streetno ?cons ?img
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q41176.
  ?item p:P669 ?street .
  ?street ps:P669 wd:Q847613 .
  OPTIONAL { ?street pq:P670 ?streetno } . 
  OPTIONAL { ?item wdt:P4856 ?cons } .
  OPTIONAL { ?item wdt:P18 ?img } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "cs,en" } .
}
ORDER BY xsd:integer(?streetno)

Try it!