Wikidata:WikiProject Czech Republic/Maintenance Queries
|
|
|
Missing images
[edit]# Items in the Czech Republic that have coordinates missing an image
SELECT ?item ?itemLabel ?coord
WHERE
{
?item wdt:P17 wd:Q213; wdt:P625 ?coord .
MINUS { ?item wdt:P18 ?image } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs" } .
}
Also works with "WikiData Free Image Search Tool": [1]
Items without statements
[edit]Duplicates of monument IDs
[edit]- See also /Duplicates of monument IDs
#Find duplicate monument IDs
SELECT * WHERE {
{
SELECT ?id (COUNT(?obj) AS ?count) (GROUP_CONCAT(?obj; SEPARATOR = " , ") AS ?items) WHERE {
?obj wdt:P762 ?id.
}
GROUP BY ?id
}
FILTER(?count > 1)
}
Missing articles on cswiki
[edit]SELECT ?item ?sitelinks WHERE {
?item wdt:P17 wd:Q213 .
MINUS { ?item ^schema:about/schema:isPartOf <https://cs.wikipedia.org/> } .
?item wikibase:sitelinks ?sitelinks .
} ORDER BY DESC(?sitelinks)
Possible duplicates with zanikleobce.cz abandoned objects ID (P3003)
[edit]#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?coord ?layer {
?item1 wdt:P3003 []; wdt:P625 ?coord1; rdfs:label ?label .
BIND( STRLANG( STR( IF( CONTAINS( ?label, ' (' ), STRBEFORE( ?label, ' (' ), ?label ) ), 'cs' ) AS ?itemLabel ) .
?itemLabel ^rdfs:label ?item2 .
FILTER( ?item1 != ?item2 ) .
FILTER EXISTS {
?item2 wdt:P17 wd:Q213; wdt:P625 ?coord2; wdt:P31/wdt:P279* wd:Q486972 .
FILTER( geof:distance( ?coord1, ?coord2 ) < 2 ) .
} .
OPTIONAL { ?item2 wdt:P625 ?coord2 } .
VALUES ?x { 1 2 } .
BIND( IF( ?x = 1, ?item1, ?item2 ) AS ?item ) .
BIND( IF( ?x = 1, ?coord1, ?coord2 ) AS ?coord ) .
BIND( IF( ?x = 1, 'zaniklá', 'druhá' ) AS ?layer ) .
} ORDER BY ?itemLabel
Possible duplicates with sv/cebwiki articles
[edit]#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?coord ?layer WITH {
SELECT DISTINCT ?item1 ?coord1 ?itemLabel {
VALUES ?links { 1 2 3 } .
VALUES ?wikis { <https://ceb.wikipedia.org/> <https://sv.wikipedia.org/> } .
?item1 wdt:P17 wd:Q213; wikibase:sitelinks ?links; wdt:P625 ?coord1;
^schema:about/schema:isPartOf ?wikis; rdfs:label ?label .
MINUS { ?item1 ^schema:about/schema:isPartOf <https://cs.wikipedia.org/> } .
BIND( STRLANG( STR( IF( CONTAINS( ?label, ' (' ), STRBEFORE( ?label, ' (' ), ?label ) ), 'cs' ) AS ?itemLabel ) .
}
} AS %sub WHERE {
INCLUDE %sub .
?itemLabel ^rdfs:label ?item2 .
FILTER( ?item2 != ?item1 ) .
FILTER EXISTS {
?item2 wdt:P17 wd:Q213; wdt:P625 ?coord2 .
FILTER( geof:distance( ?coord1, ?coord2 ) < 2 ) .
} .
OPTIONAL { ?item2 wdt:P625 ?coord2 } .
VALUES ?x { 1 2 } .
BIND( IF( ?x = 1, ?item1, ?item2 ) AS ?item ) .
BIND( IF( ?x = 1, ?coord1, ?coord2 ) AS ?coord ) .
BIND( IF( ?x = 1, 'sv/ceb', 'ok' ) AS ?layer ) .
} ORDER BY ?itemLabel
New Czech persons
[edit]This list is periodically updated by a bot. Manual changes to the list will be removed on the next update!
WDQS | PetScan | TABernacle | Find images | Recent changesEnd of automatically generated list.
New Czech entities
[edit]This list is periodically updated by a bot. Manual changes to the list will be removed on the next update!
WDQS | PetScan | TABernacle | Find images | Recent changesEnd of automatically generated list.