Wikidata:WikiProject Archival Description/Use cases

Home

Data Structure

Typology

Data Sources

Use Cases

Tools & Tasks

Statistics

Wikipedia Infobox

Petscan

En utilisant Petscan, il est possible de savoir quels sont les éléments Wikidata qui sont archives at (P485) une institution donnée et dont la page Wikipédia réutilise ces valeurs.

Exemple :

• exemple 1 avec les Departmental archives of Yvelines (Q2860507)

Pour varier les exemples, il suffit de changer la valeur sous l'onglet Wikidata dans le champs "Uses items/props" dans la formule de l'exemple 1.

WDQS

SELECT DISTINCT * WHERE {
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
	bd:serviceParam wikibase:api "Generator" .
    bd:serviceParam mwapi:generator "search" .
    bd:serviceParam wikibase:endpoint "fr.wikipedia.org" .
    bd:serviceParam mwapi:gsrsearch "insource:Biographie2".
    bd:serviceParam mwapi:gsrlimit "max" .    
    bd:serviceParam mwapi:gsrnamespace "0" . 
    ?item wikibase:apiOutputItem mwapi:item .
  }
  ?item wdt:P485 wd:Q2860507.
  ?link schema:about ?item; schema:isPartOf <https://fr.wikipedia.org/>; schema:name ?title .

Try it!

Human in dans WP-ca

archives at (P485)

• more information on the use of P485.
• https://twitter.com/b3d2c/status/1190351267979300870
• https://www.wikidata.org/wiki/User_talk:Amadalvarez#P485_in_Plantilla%3AInfotaula_persona
• https://www.wikidata.org/wiki/Topic:V9skz7p4n2yd9773
• https://ca.wikipedia.org/wiki/Plantilla:Infotaula_persona/%C3%BAs#Exemples

Personnalité dans WP-fr

archives at (P485)

• Plus d'informations sur l'utilisation de la propriété P485.
• Modèle:Infobox_Biographie2
• Catégorie: Page utilisant P485
  • 3'718 pages (14.11.2019)
  • 3'737 pages (19.11.2019)
  • 4'105 pages (17.03.2020)
  • 4'535 pages (07.08.2020)
  • 5'436 pages (13.02.2021)
  • 6'284 pages (17.03.2021)
  • 7'705 pages (20.11.2021)
  • 8'163 pages (06.04.2022)
  • 9'652 pages (24.10.2023)
• https://twitter.com/b3d2c/status/1190356010608791553
• User_talk:2le2im-bdc#archivé_par_(P485)
• Statistique : Discussion sur le bistrot
• exemples : w:fr:Claire_Auzias Claire Auzias

GLAM (Archives) dans WP-fr

• projet de passage des Infobox Archives de Wikipédia en français en Lua

External ID

Voir explications en français.

Liste des institutions d'archives ayant délivrés des identifiants externes (triés par nombre de ID)

#Liste des institution d'archives ayant délivré (ou étant élément associé à) des identifiants externes (et leur nombre)
SELECT ?ArchivesLabel ?Archives (COUNT(distinct (?item)) AS ?total) (GROUP_CONCAT(DISTINCT ?itemLabel; separator=", ") as ?items) (GROUP_CONCAT(DISTINCT ?natureLabel; separator=", ") as ?natures) 
WHERE 
{
  {?item wdt:P2378 ?Archives.}
  UNION {?item wdt:P1629 ?Archives.}
    ?item wdt:P31 ?nature., on entend de manière générale

  OPTIONAL {?nature rdfs:label ?natureLabel. filter(lang(?natureLabel)="fr") }
  OPTIONAL {?item rdfs:label ?itemLabel. filter(lang(?itemLabel)="fr") }
  ?Archives wdt:P31/wdt:P279* wd:Q166118.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?items ?total ?natures ?ArchivesLabel ?Archives
ORDER BY DESC (?total)

Try it!

Résultats :

• 88 (08.08.2020)

Liste des institutions d'archives ayant délivrés des identifiants externes (triés par pays)

#Liste des institution d'archives ayant délivré (ou étant élément associé à) des identifiants externes (trié par pays)
SELECT ?paysLabel ?ArchivesLabel ?Archives (COUNT(distinct (?item)) AS ?total) (GROUP_C, on entend de manière généraleONCAT(DISTINCT ?itemLabel; separator=", ") as ?items) (GROUP_CONCAT(DISTINCT ?natureLabel; separator=", ") as ?natures) 
WHERE 
{
  {?item wdt:P2378 ?Archives.}
  UNION {?item wdt:P1629 ?Archives.}
    ?item wdt:P31 ?nature.

  OPTIONAL {?nature rdfs:label ?natureLabel. filter(lang(?natureLabel)="fr") }
  OPTIONAL {?item rdfs:label ?itemLabel. filter(lang(?itemLabel)="fr") }
  ?Archives wdt:P31/wdt:P279* wd:Q166118;
            wdt:P17 ?pays.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?items ?total ?natures ?ArchivesLabel ?Archives ?paysLabel
ORDER BY ?paysLabel

Try it!

#Liste des institution d'archives ayant délivré (ou étant élément associé à) des identifiants externes (trié par pays). Moins les cinémathèques et en affichant leurs natures.
SELECT ?paysLabel ?ArchivesLabel ?Archives (GROUP_CONCAT(DISTINCT ?natureArchivesLabel; separator=", ") as ?nal)  (COUNT(distinct (?item)) AS ?total) (GROUP_CONCAT(DISTINCT ?itemLabel; separator=", ") as ?items) (GROUP_CONCAT(DISTINCT ?natureLabel; separator=", ") as ?natures) 
WHERE 
{
  {?item wdt:P2378 ?Archives.}
  UNION {?item wdt:P1629 ?Archives.}
    ?item wdt:P31 ?nature.

  OPTIONAL {?nature rdfs:label ?natureLabel. filter(lang(?natureLabel)="fr") }
  OPTIONAL {?item rdfs:label ?itemLabel. filter(lang(?itemLabel)="fr") }
  ?Archives wdt:P31/wdt:P279* wd:Q166118;
            wdt:P31 ?natureArchives;
            wdt:P17 ?pays.
  OPTIONAL {?natureArchives rdfs:label ?natureArchivesLabel. filter(lang(?natureArchivesLabel)="fr") }
  MINUS { ?Archives wdt:P31 wd:Q1352795}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?items ?total ?natures ?ArchivesLabel ?Archives ?paysLabel ?nal
ORDER BY ?paysLabel

Try it!

Liste des identifiants externes liées à des institutions d'archives (triés par nature)

#Liste des identifiants externes par nature délivrés par une institution d'archives ou dont cette institution est un élément associé
SELECT ?item ?itemLabel ?natureLabel ?ArchivesLabel ?Archives
WHERE 
{
  {?item wdt:P2378 ?Archives.}
  UNION {?item wdt:P1629 ?Archives.}
    ?item wdt:P31 ?nature.
  ?Archives wdt:P31/wdt:P279* wd:Q166118.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?natureLabel

Try it!

Nombre d'éléments disposant d'un identifiant externe XY

#Nombre d'éléments disposant d'un identifiant externe XY
SELECT (COUNT(distinct (?item)) AS ?total) 
WHERE 
{
  ?item wdt:P3029 ?ID_NAUK;
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Liste des éléments avec un indentifiant externe XY

1. Éléments avec un indentifiant externe XY

SELECT ?item ?itemLabel ?natureLabel WHERE {

 ?item wdt:P3029 ?ID_NAUK;
       wdt:P31 ?nature.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

} }}

Liste des éléments disposant d'un identifiant externe XY groupé par nature avec leur nombre

#éléments dispodant d'un identifiant externe XY classés par nombre par nature
SELECT ?natureLabel (COUNT(distinct (?item)) AS ?total) 
WHERE 
{
  ?item wdt:P3029 ?ID_NAUK;
        wdt:P31 ?nature
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?natureLabel ?total
ORDER BY DESC (?total)

Try it!

Liste des éléments de nature XY disposant d'un identifiant externe donné par une institution type archives

SELECT ?item ?itemLabel
WHERE {
  {
    ?item wdt:P31 wd:Q10648343;
        wikibase:identifiers ?identifiers.
  }
 UNION 
  {
    {?identifiers wdt:P2378 ?Archives.}
     UNION {?item wdt:P1629 ?Archives.}
    ?Archives wdt:P31/wdt:P279* wd:Q166118.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Liste des éléments disposant d'un identifiant externe donné par une institution XY dont l'ID externe est affiché

1. Liste des éléments avec un indentifiant externe XY dont on demande d'affiché cet ID

SELECT ?item ?itemLabel ?natureLabel ?ID ?link WHERE {

 ?item wdt:P1225 ?ID;
       wdt:P31 ?nature.
   wd:P1225 wdt:P1630 ?ffu .
   BIND(URI(REPLACE(?ffu,'\\$1',?ID)) AS ?link)
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

} LIMIT 10 }}

Liste des éléments disposant d'un nombre donné d'identifiant externe

SELECT * WHERE {
  ?item wdt:P31 wd:Q5;
        wdt:P21 wd:Q6581072;
        wikibase:identifiers ?identifiers .
  FILTER( ?identifiers > 10 ) .
}

Try it!

Countries

Brazil

List of the archival fonds at the National Archives of Brazil (generated from Wikidata)

Canada

University of Ottawa Library

Canadian archive of Women in STEM

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P361 wd:Q63647303.
}

Try it!

Documentation

• Using Wikidata to Provide Visibility to Women in STEM (Mairelys Lemus-Rojas and Yoo Young Lee), September 24, 2019 at DCMI 2019.

McGill Library Archival Collections

McGill University Library (Q6801308)

• Rare Books and Special Collections (Q62535993)
• Osler Library of the History of Medicine (Q7106994)
• Marvin Duchow Music Library (Q63644951)
• McGill University Archives (Q6801297)

SELECT ?item ?itemLabel ?natureLabel ?nature
WHERE 
{
  {?item wdt:P485 wd:Q6801308} UNION {?item wdt:P485 wd:Q62535993} UNION {?item wdt:P485 wd:Q63644951} UNION {?item wdt:P485 wd:Q63644951} .
       ?item wdt:P31 ?nature.  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?natureLabel ?archivedBYLabel

Try it!

Documentation

• From boxes to AtoM to Wikidata (Ekatarina Grguric, Frédéric Giuliano, Anna Dysert, Rachel Black), October 10th, 2019, Access 2019 (library technology conference).
  • video
  • slide and more
  • McGill archives catalogue
  • General designation material (P6608)

University of Toronto Libraries Archival Collections

University of Toronto Libraries (Q7896490)

• Thomas Fisher Rare Book Library (Q7789602)
• University of Toronto Archives & Records Management Services (Q64825166)
• University of Toronto Mississauga Library (Q7896491)
• University of Toronto Scarborough Library (Q43543428)
• E.J. Pratt Library (Q76176053)
• Victoria University Archives (Q76178000)
• John M. Kelly Library (Q64760824)
• University of Toronto Music Library (Q76005462)
• University of Toronto Media Commons (Q75837464)
• Trinity College Archives (Q76167620)
• University of St. Michael's College Archives (Q76165610)
• OISE Library (Q76004477)

Queries individual institutions, using one the QIDs above:

SELECT ?archivesAtLabel ?itemLabel ?url ?item WHERE {
  ?item wdt:P485 wd:Q76005462;
        wdt:P485 ?archivesAt;
    p:P485 [
      pq:P973 ?url
   ].
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Try it!

Documentation

• Wikidata:WikiProject University of Toronto Libraries/Discover Archives

Clara Thomas Archives and Special Collections, York University

Clara Thomas Archives and Special Collections (Q61467363)

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P485 wd:Q61467363.
}

Try it!

Documentation

• Wikidata and Archivists presentation includes links to tutorials and sample SPARQL queries
• List to review WIP wikidata properties including name authorities

Western Libraries Archives and Special Collections

University of Western Ontario Libraries (Q57939861)

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P485 wd:Q57939861.
}

Try it!

Documentation

• Western Libraries Wikidata project work

France

Archives municipales déposées au sein des archives départementales

Comment documenter dans Wikidata, les fonds d'archives municipales déposés dans des archives départementales et les rendre requêtables via SPARQL?

• Proposition 1 : utiliser la déclaration archives at (P485) sur l'élément Wikidata de la commune, avec en référence inventory number (P217) . Exemple : Lambesc (Q474025).
• Proposition 2 : utiliser la déclaration archives at (P485) sur l'élément Wikidata de la commune, avec en qualificatif inventory number (P217). Exemple : Allauch (Q269862).
• Proposition 3 : utiliser la déclaration archives at (P485) sur l'élément Wikidata de la commune, avec en qualificatif inventory number (P217) et en référence reference URL (P854) et retrieved (P813). Exemple : Adissan (Q656270).
• Idée : Créer un fichier d'import CSV pour créer en masse la déclaration archives at (P485) sur l'élément Wikidata de la commune, avec une référence inventory number (P217)
• Idée : Pour une meilleure visibilité de ces archives municipales, il faudrait aussi réfléchir à un moyen d'automatiser depuis Wikidata la citation de leur inventaire en référence dans Wikipédia à l'image du modèle Cite:Archive mais en code Lua comme le Modèle:Bibliographie .

SPARQL Requête qui utilise la syntaxe de la proposition 2:

#Requête SPARQL sur l'ensemble des communes du département des Bouches-du-Rhône et les références des fonds déposés aux Archives départementales.
SELECT ?commune ?communeLabel ?serviceArchivesLabel ?numInventaire 
WHERE 
{
  ?commune wdt:P31/wdt:P279* wd:Q484170;
           wdt:P131 wd:Q3240;
           wdt:P485 wd:Q2860505.
  ?commune p:P485 ?declaration_serviceArchives.
  ?declaration_serviceArchives ps:P485 ?serviceArchives.
  OPTIONAL 
        {?declaration_serviceArchives pq:P217 ?numInventaire.
        
        }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!

Switzerland

• Liste de personnes dont la production documentaire est archivée par les AEN (d'après Wikidata P485) dans Wikipédia (fr) https://fr.wikipedia.org/wiki/Discussion:Archives_de_l'État_de_Neuchâtel

United States of America

NARA

National Archives and Records Administration (Q518155)

Pilote project lead by Dominic Byrd-McDevitt.

Extern ID :

• NARA record group number (P6759) public fonds from public administration
• NARA collection ID (P6761) private fonds
• U.S. National Archives Identifier (P1225) general ID for all entities

Organisation

SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P749 wd:Q518155.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Resultats : 42 (24.10.2019)

NARA P6759

NARA record group number (P6759)

#NARA P6759
SELECT ?item ?itemLabel ?natureLabel ?ID
WHERE 
{
  ?item wdt:P6759 ?ID;
        wdt:P31 ?nature.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY xsd:integer(?ID)

Try it!

Résultats : 571 (24.10.2019)

NARA P6761

NARA collection ID (P6761)

#NARA P6761
SELECT ?item ?itemLabel ?natureLabel ?ID
WHERE 
{
  ?item wdt:P6761 ?ID;
        wdt:P31 ?nature.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?ID

Try it!

Résultats :

• 4'597 (06.07.2019)
• 4'754 (21.11.2019)

NARA P1225

U.S. National Archives Identifier (P1225)

#NARA P1225
SELECT (COUNT(?item) as ?total)
WHERE 
{
  ?item wdt:P1225 ?ID.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Résults :

• 146'227 (06.07.2019)
• 429'295 (21.11.2019)

#NARA P1225
SELECT ?natureLabel ?total WITH { 
  SELECT ?nature (COUNT(?item) as ?total)
  WHERE 
  {
    ?item wdt:P1225 ?ID;
          wdt:P31 ?nature.
  } GROUP BY ?nature }  as %i
where 
{
  include %i
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY DESC(?total)

Try it!

#NARA P1225
SELECT ?item ?itemLabel (GROUP_CONCAT(DISTINCT(?natureLabel); separator=", ") AS ?natures) ?ID
WHERE 
{
  ?item wdt:P1225 ?ID;
        wdt:P31 ?nature.
        OPTIONAL {?nature rdfs:label ?natureLabel. filter(lang(?natureLabel)="fr") }       
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?natures ?ID
LIMIT 5

Try it!

#NARA P1225
SELECT ?item ?itemLabel ?ID_NARA
WHERE 
{
  ?item wdt:P1225 ?ID_NARA;
        wdt:P31 wd:Q2668072.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?ID_NARA)
LIMIT 5

Try it!

#NARA P1225
SELECT ?niveau ?niveauLabel (COUNT(?item) AS ?total)
WHERE 
{
  ?item wdt:P1225 ?ID_NARA;
        wdt:P31 wd:Q2668072;
        wdt:P6224 ?niveau.  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?niveau ?niveauLabel

Try it!

#NARA P1225 example of series
SELECT ?item ?itemLabel
WHERE 
{
  ?item wdt:P1225 ?ID_NARA;
        wdt:P31 wd:Q2668072;
        wdt:P6224 wd:Q3511132.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 5

Try it!

#NARA P1225 repartition of the séries by part of elements
SELECT ?partie ?partieLabel (COUNT(?item) as ?total)
WHERE 
{
  ?item wdt:P1225 ?ID_NARA;
        wdt:P31 wd:Q2668072;
        wdt:P6224 wd:Q3511132;
        wdt:P361 ?partie.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?partie ?partieLabel
ORDER BY DESC(?total)

Try it!

Thematic Queries

Private Fonds

A SPARQL Query to watch the information on the people's archives donation on a territory:

#Liste des personnes (connues de Wikidata) nées ou mortes dans le Canton de Vaud (Suisse) avec leurs occupations et l'institution où sont déposées leurs archives
SELECT ?humain ?humainLabel ?lieuNaissanceLabel ?lieuMortLabel ?occ ?archive_at
WITH { SELECT ?humain (group_concat(distinct ?occupLabel;separator=", ") as ?occ) (group_concat(distinct ?archiveLabel;separator=", ") as ?archive_at) WHERE 
{
  ?humain wdt:P31 wd:Q5.
  OPTIONAL {?humain wdt:P106 ?occup.
            ?occup rdfs:label ?occupLabel. filter(lang(?occupLabel)="fr")}
  OPTIONAL {?humain wdt:P485 ?archive.
             ?archive rdfs:label ?archiveLabel. filter(lang(?archiveLabel)="fr")}
  {?humain wdt:P19 ?lieuNaissance.
  ?lieuNaissance wdt:P131 wd:Q12771.}
  UNION
  {?humain wdt:P20 ?lieuMort.
  ?lieuMort wdt:P131 wd:Q12771.}
  } group by ?humain  } as %i
WHERE {include %i
  OPTIONAL {?humain wdt:P19 ?lieuNaissance.}
  OPTIONAL {?humain wdt:P20 ?lieuMort.} 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
} ORDER BY ?humainLabel

Try it!

DIVERS

• archive (Q166118)

#Trouve tous les éléments connus de Wikidata qui sont des "archives" (ou l'une de ses sous-classes) et affiche leur nom
SELECT ?item ?itemLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q166118.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

• departmental archives (Q2860456)

#Trouve tous les éléments connus de Wikidata qui sont des "archives départementales"
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q2860456.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

• municipal archive (Q604177)

#Trouve tous les éléments connus de Wikidata qui sont des "archives communales"
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q604177.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

• membre de la collection

SELECT ?item ?itemLabel ?Institution ?InstitutionLabel
WHERE
{
?item wdt:P31 wd:Q2668072. # les item qui sont des collections
?item wdt:P195 ?Institution #qui dispose d'un rattachement à une collection
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}

Try it!

• Personnes dont il est précisé quelles sont les institutions qui conservent les documents qu'elles ont produits (ou dont elles sont le sujet).

#Trouve toutes les personnes disposant de la propriété 'archivées par' (P805) et dont l'institution qui en est la valeur conserve des archives (Q166118)

SELECT DISTINCT ?personne ?personneLabel ?institution ?institutionLabel WHERE {
  ?personne wdt:P31 wd:Q5. #je cherche des êtres humains
  ?personne wdt:P485 ?institution. #ayant été "archivé par" une institution        
  ?institution wdt:P31*/wdt:P279* wd:Q166118. # une institution faisant partie de la (sous-)classe archives
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}

Try it!