User:MisterSynergy/sysop/items for deletion

From Wikidata
Jump to navigation Jump to search
+/−
MisterSynergy’s sysop work lists

Special:PrefixIndex/User:MisterSynergy/sysop • User:MisterSynergy/header

Worklists

[edit]

My own

[edit]

Database reports

[edit]

Other users’ item for deletion lists

[edit]

Misc

[edit]

See also

[edit]

Page deleted archive size statistics

[edit]

Page sizes (bytes of wikitext) of page deleted archives: (current page: 213,890). See also: pagedeleted stats, archivebox-pagedeleted.

Page deleted queries

[edit]
SELECT DISTINCT ?item WITH {
  SELECT DISTINCT ?item WHERE {
    SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api 'Generator';
                      wikibase:endpoint 'www.wikidata.org';
                      mwapi:generator 'links';
                      mwapi:titles 'User:Pasleim/Items_for_deletion/Page_deleted/Archive/2019' .
      ?title wikibase:apiOutput mwapi:title  .
      ?ns wikibase:apiOutput '@ns' .
      ?pageId wikibase:apiOutput mwapi:pageid .
    }
    FILTER(BOUND(?pageId)) .
    FILTER(STR(?ns) = '0') .
    BIND(IRI(CONCAT(STR(wd:), ?title)) AS ?item) .
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  # further filtering here
}
Try it!

Items with questionable notability (direct queries without lists)

[edit]

human (Q5)

[edit]
SELECT DISTINCT ?item ?statements WHERE {
  ?item wikibase:sitelinks 0; wikibase:identifiers 0; wdt:P31 wd:Q5 .
  MINUS { [] ?backlink ?item }
  MINUS { [] schema:about ?item }
  OPTIONAL { ?item ?p [ prov:wasDerivedFrom [ ?pr [] ] ] . FILTER (?pr NOT IN (pr:P143, pr:P3452, pr:P4656)) } FILTER(!BOUND(?p))
  MINUS { ?item p:P973|p:P1343|p:P166|p:P5008 [] }
  ?item wikibase:statements ?statements .
} ORDER BY ASC(?statements)
Try it!

organization (Q43229)

[edit]
SELECT DISTINCT ?item ?statements WHERE {
  ?item wdt:P31/wdt:P279* wd:Q43229; wikibase:sitelinks 0; wikibase:identifiers 0 .
  MINUS { [] ?backlink ?item }
  MINUS { [] schema:about ?item }
  OPTIONAL { ?item ?p [ prov:wasDerivedFrom [ ?pr [] ] ] . FILTER (?pr NOT IN (pr:P143, pr:P3452, pr:P4656)) } FILTER(!BOUND(?p))
  MINUS { ?item p:P973|p:P1343 [] }
  ?item wikibase:statements ?statements .
} ORDER BY ASC(?statements)
Try it!

business (Q4830453)

[edit]
SELECT DISTINCT ?item ?statements WHERE {
  ?item wdt:P31/wdt:P279* wd:Q4830453; wikibase:sitelinks 0; wikibase:identifiers 0 .
  MINUS { [] ?backlink ?item }
  MINUS { [] schema:about ?item }
  OPTIONAL { ?item ?p [ prov:wasDerivedFrom [ ?pr [] ] ] . FILTER (?pr NOT IN (pr:P143, pr:P3452, pr:P4656)) } FILTER(!BOUND(?p))
  MINUS { ?item p:P973|p:P1343 [] }
  ?item wikibase:statements ?statements .
} ORDER BY ASC(?statements)
Try it! 
SELECT DISTINCT ?item ?identifiers WHERE {
  ?item wdt:P31/wdt:P279* wd:Q4830453; wikibase:sitelinks 0; wikibase:identifiers ?identifiers .
  MINUS { [] ?backlink ?item }
}
Try it!

creative work (Q17537576) (except scholarly article (Q13442814))

[edit]
SELECT DISTINCT ?item ?statements WITH {
  SELECT DISTINCT ?class WHERE {
    ?class wdt:P279* wd:Q17537576 .
    FILTER(?class NOT IN (wd:Q13442814)) .
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  ?item wdt:P31 ?class; wikibase:identifiers 0; wikibase:sitelinks 0; wikibase:statements ?statements .
  MINUS { [] ?backlink ?item }
  MINUS { ?item p:P973|p:P1343|p:P528 [] }
  OPTIONAL { ?item ?p [ prov:wasDerivedFrom [ ?pr [] ] ] . FILTER(?pr NOT IN (pr:P143, pr:P3452, pr:P4656)) . } FILTER(!BOUND(?p)) .
}
Try it!

occurrence (Q1190554) (times out)

[edit]
SELECT DISTINCT ?item ?statements WHERE {
  ?item wdt:P31/wdt:P279* wd:Q1190554; wikibase:sitelinks 0; wikibase:identifiers 0 .
  MINUS { [] ?backlink ?item }
  MINUS { [] schema:about ?item }
  OPTIONAL { ?item ?p [ prov:wasDerivedFrom [ ?pr [] ] ] . FILTER (?pr NOT IN (pr:P143, pr:P3452, pr:P4656)) } FILTER(!BOUND(?p))
  MINUS { ?item p:P973|p:P1343 [] }
  ?item wikibase:statements ?statements .
} ORDER BY ASC(?statements)
Try it!

CEOs, entrepreneurs

[edit]
SELECT ?item WHERE {
  VALUES ?class { wd:Q484876 wd:Q131524 } # Q484876=CEO, Q131524=entrepreneur
  ?item ?any ?class; wikibase:sitelinks 0; wikibase:identifiers 0 .
  MINUS { [] ?backlink ?item }
} ORDER BY DESC(xsd:integer(STRAFTER(STR(?item), 'entity/Q')))
Try it!
[edit]

Celebrities

[edit]

Emtpy items

[edit]

(Does not work correctly in any case, thus check manually; in use at User:MisterSynergy/sysop/empty items.) 

# Look for empty items (no sitelinks, no statements, no use in other items)
SELECT ?item {
  ?item wikibase:sitelinks 0 . # no sitelinks (sometimes unreliable); alternative: ?sitelinkCount . FILTER(?sitelinkCount = 0) .
  ?item wikibase:statements 0 . # no statements (sometimes unreliable); alternative: ?statementCount . FILTER(?statementCount = 0) .
  MINUS { # not used in other items (mainsnak)
    ?mainsnakProperty wikibase:propertyType wikibase:WikibaseItem; wikibase:claim ?claim; wikibase:statementProperty ?statementProperty; wikibase:directClaim ?directClaim .
    [] ?claim [ ?statementProperty ?item ] .
  }
  MINUS { # not used in other items (as qualifier)
    ?qualifierProperty wikibase:propertyType wikibase:WikibaseItem; wikibase:qualifier ?qualifier .
    [] ?qualifier ?item .
  }
  MINUS { # not used in other items (as reference)
    ?referenceProperty wikibase:propertyType wikibase:WikibaseItem; wikibase:reference ?reference .
    [] prov:wasDerivedFrom [ ?reference ?item ] .
  }
  MINUS { # second check: no statements
    ?anyProperty a wikibase:Property; wikibase:claim ?anyClaim .
    ?item ?anyClaim [] .
  }
  MINUS { # second check: no sitelinks; unreliable as well
    ?sitelink schema:about ?item .
  }
}
Try it!

Commons notability

[edit]
#defaultView:LineChart
SELECT ?bin (COUNT(*) AS ?cnt) WITH {
  SELECT ?item WHERE {
    ?item ^schema:about/schema:isPartOf <https://commons.wikimedia.org/>; wikibase:sitelinks 1; wdt:P31 wd:Q5 .
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  BIND(CEIL(xsd:integer(SUBSTR(STR(?item), 33)) / 1000000) AS ?bin) .
  ?item wikibase:identifiers 0 .
  OPTIONAL { [] ?any ?item . FILTER(?any != schema:about) }
  FILTER(!BOUND(?any)) .
} GROUP BY ?bin ORDER BY ASC(?bin)
Try it!

(Mainly) social network based identification

[edit]
SELECT DISTINCT ?item ?term ?property ?propertyLabel WITH {
  SELECT DISTINCT ?property ?propertyLabel ?p WHERE {
    ?property wdt:P31/wdt:P279* wd:Q30041186; wikibase:propertyType wikibase:ExternalId; wikibase:claim ?p .
    SERVICE wikibase:label { bd:serviceParam wikibase:language 'en' }
  }
} AS %subquery1 WITH {
  SELECT DISTINCT ?item ?property ?propertyLabel WHERE {
    INCLUDE %subquery1 .
    ?item wikibase:identifiers 1; wikibase:sitelinks 0; ?p []; wikibase:statements 2 .
  }
} AS %subquery2 WHERE {
  INCLUDE %subquery2 .
  MINUS { [] schema:about ?item }
  MINUS { [] ?any ?item }
  MINUS { ?item ?any [ prov:wasDerivedFrom [ ?pr [] ] ] . FILTER(?pr NOT IN (pr:P813, pr:P143, pr:P4656, pr:P3452, pr:P887)) }
  MINUS { ?item p:P528|p:P973|p:P1343|p:P166
Try it!

"Indicates notability" properties

[edit]
SELECT ?property ?propertyLabel ?dataType ?notability_item WHERE {
  ?property wikibase:propertyType ?dataType .
  {
    ?property wdt:P31 wd:Q62589316 .
    BIND('suggests notability' AS ?notability_item) .
  } UNION {
    ?property wdt:P31 wd:Q62589320 .
    BIND('does not suggest notability' AS ?notability_item) .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'en' }
} ORDER BY ASC(xsd:integer(STRAFTER(STR(?property), 'entity/P')))
Try it!

Other stuff

[edit]
  • artists, musicians, actors, producers
  • sportspersons
  • empty-Quora-only identified items
  • dictionary entries
Retrieved from "https://www.wikidata.org/w/index.php?title=User:MisterSynergy/sysop/items_for_deletion&oldid=2062957653"