User:Bouzinac

From Wikidata
Jump to navigation Jump to search
Babel user information
en-5 This user has professional knowledge of English.
fr-N Cet utilisateur a pour langue maternelle le français.
de-2 Dieser Benutzer beherrscht Deutsch auf fortgeschrittenem Niveau.
es-0 Esta persona no tiene ningún conocimiento del español (o lo entiende con mucha dificultad).
it-1 Questo utente può contribuire con un livello elementare in italiano.
br-0 Ne oar an implijer-mañ tamm Brezhoneg ebet (pe en deus mil boan o kompren anezhañ).
nb-0 Denne brukeren har lite eller ingen kjennskap til norsk (bokmål) (eller har svært vanskelig for å forstå det).
Users by language

Harvest[edit]

https://tools.wmflabs.org/pltools/harvesttemplates/share.php?action=savenew&siteid=ceb&project=wikipedia&namespace=0&property=131&template=geobox&parameter=region&addprefix=&removeprefix=&category=Mga%20tugpahanan%20sa%20Tinipong%20Bansa&depth=2&set=1&offset=0&limit=10000&wikisyntax=0&

tring search elements without P31 P279[edit]

SELECT DISTINCT ?item ?itemLabel 
WHERE {
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "siege -haswbstatement:P31 -haswbstatement:P279" .
    ?title wikibase:apiOutput mwapi:title.
  }
  BIND(IRI(CONCAT(STR(wd:), ?title)) AS ?item)
  #add any other requirements here
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Geographical-GPS lookups[edit]

Recherches géographiques


Airports[edit]

Ontologie des aéroports/Airport ontology in Wikidata[edit]

Ontologie

Patronages of airports[edit]

Fréquentations & patronages

Airports in a country[edit]

Airports lists

Airports/railways stations with a text search/codes[edit]

Recherches d'aéroports par codes IATA, ICAO etc

Data quality[edit]

Requêtes de data quality


Countries[edit]

Number of countries in the history[edit]

select ?bound (count(?country) as ?count)
with {
select ?country {
?country wdt:P31/wdt:P279* wd:Q3624078 # sovereign states, I don’t know if it’s the right item
} 
}as %countries
with
{
select distinct ?bound {
?country (wdt:P571
Try it!

List of countries + nature + time[edit]

select distinct ?country (group_concat(?NatureLabelFr;separator=", ") as ?NatureLabelFr) ?countryLabel  ?creationDate ?dissolutionDate
with {
select ?country (coalesce(?countryLabelFr, ?countryLabelEn,  ?country) as ?countryLabel) ?creationDate ?dissolutionDate{
VALUES ?what { 
               wd:Q3624078 # sovereign states, I don’t know if it’s the right item
               wd:Q3024240 # états historiques
             }
?country wdt:P31/wdt:P279* ?what . 
MINUS { ?country (wdt:P31/wdt:P279*) wd:Q1790360. } #empires coloniaux
MINUS { ?country (wdt:P31/wdt:P279*) wd:Q1371288. } #états vassals
MINUS { ?country (wdt:P31/wdt:P279*) wd:Q21512251. } #états autoproclamés
MINUS { ?country (wdt:P31/wdt:P279*) wd:Q1642488. } #chefferies
optional { ?country rdfs:label ?countryLabelFr filter(lang(?countryLabelFr)= "fr")} .
optional { ?country rdfs:label ?countryLabelEn filter(lang(?countryLabelEn)= "en")}
optional { ?country wdt:P571 ?creationDate }
optional { ?country wdt:P576 ?dissolutionDate }
} order by ?countryLabel
} as %datas
where {
include %datas .
optional{
?country wdt:P31/rdfs:label ?NatureLabelFr filter(lang(?NatureLabelFr)= "fr") .
}
} group by ?country ?countryLabel  ?creationDate ?dissolutionDate
Try it!

autre liste à nettoyer[edit]

SELECT distinct ?item ?itemLabel ?itemdesc ?creat  ?dissolution  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P31/wdt:P279* wd:Q3024240.
  OPTIONAL { ?item wdt:P571 ?creat. }
  OPTIONAL { ?item wdt:P576 ?dissolution. }
  ?item schema:description ?itemdesc .
  FILTER((LANG(?itemdesc)) = "fr")
} order by ?creat
Try it!

nouvelle liste des 2800 à nettoyer[edit]

SELECT distinct ?item ?itemLabel ?itemdesc_fr ?itemdesc_en ?creat  ?dissolution  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,fr". }
#  values ?item {wd:Q101104073}
  ?item wdt:P31/wdt:P279* wd:Q3024240.
MINUS { ?item (wdt:P31/wdt:P279*) wd:Q1790360. } #empires coloniaux
MINUS { ?item (wdt:P31/wdt:P279*) wd:Q1371288. } #états vassals
MINUS { ?item (wdt:P31/wdt:P279*) wd:Q21512251. } #états autoproclamés
MINUS { ?item (wdt:P31/wdt:P279*) wd:Q1642488. } #chefferies
  OPTIONAL { ?item wdt:P571 ?creat. }
  OPTIONAL { ?item wdt:P576 ?dissolution. }
  FILTER (!bound(?dissolution))
  OPTIONAL {?item schema:description ?itemdesc_fr . FILTER((LANG(?itemdesc_fr)) = "fr") BIND (TRUE as ?true) }
  OPTIONAL {?item schema:description ?itemdesc_en . FILTER((LANG(?itemdesc_en)) = "en") BIND (TRUE as ?true) }
  OPTIONAL { FILTER NOT EXISTS {?item schema:description ?itemdesc .} BIND (TRUE as ?true)}
  filter(BOUND(?true))
} order by ?creat
Try it!

Spanish taifas[edit]

SELECT ?ta_fa ?ta_faLabel ?date_de_fondation_ou_de_cr_ation ?capitale ?capitaleLabel ?partie_de ?partie_deLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?ta_fa wdt:P31 wd:Q217177.
  OPTIONAL { ?ta_fa wdt:P571 ?date_de_fondation_ou_de_cr_ation. }
  OPTIONAL { ?ta_fa wdt:P36 ?capitale. }
  OPTIONAL { ?ta_fa wdt:P361 ?partie_de. } 
}
Try it!

Borders[edit]

Frontières

Military battles[edit]

https://w.wiki/3H3J (qualité des données pauvre)

Durée des sièges dans l'histoire v3[edit]

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

select ?siège ?siègeLabel (sample(?whereLabel) as ?whereLabel2) ?start ?tp_end ?tv_end ?end ?days ?years ?_articleFR ?_articleEN {
SELECT ?siège ?siègeLabel ?whereLabel ?start ?tp_end ?tv_end ?end ?days ?years ?_articleFR ?_articleEN WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?siège wdt:P31 wd:Q188055.
OPTIONAL { ?siège wdt:P580 ?start. }
OPTIONAL { 
           ?siège p:P582/psv:P582 ?p582node. 
           ?p582node wikibase:timeValue ?tv_end .       # get the time value
           ?p582node wikibase:timePrecision ?tp_end .   # get the time precision
           BIND(
             IF(?tp_end=9,?tv_end + "P1Y"^^xsd:duration - "P1D"^^xsd:duration,# set end date to 31 December if time precision is "year" (9)
             IF(?tp_end=10,?tv_end + "P1M"^^xsd:duration - "P1D"^^xsd:duration,# set end date to 28th if time precision is "month" (10)
             ?tv_end))
              AS ?end).
         }
OPTIONAL { ?siège wdt:P276 ?where. } 
OPTIONAL { ?siège p:P2047/psn:P2047/wikibase:quantityAmount ?lengthNorm.}
BIND(COALESCE(?lengthNorm/86400,(?end - ?start+1)) as ?days)
BIND(?days/365.00 as ?years)
    OPTIONAL {
    ?_articleFR schema:about ?siège.
    ?_articleFR schema:isPartOf <https://fr.wikipedia.org/>.
    ?_articleEN schema:about ?siège.
    ?_articleEN schema:isPartOf <https://en.wikipedia.org/>.
  }
}
}
group by ?siège ?siègeLabel ?start ?tp_end ?tv_end ?end ?days ?years  ?_articleFR ?_articleEN
order by desc(?years) ?whereLabel2
Try it!

à faire[edit]

SELECT DISTINCT ?item ?itemLabel 
WHERE {
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "airport -haswbstatement:P31 -haswbstatement:P279" .
    ?title wikibase:apiOutput mwapi:title. 
  }
  BIND(IRI(CONCAT(STR(wd:), ?title)) AS ?item)
  #add any other requirements here
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

à faire 2[edit]

SELECT DISTINCT ?item ?itemLabel 
WHERE {
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "bataille -haswbstatement:P31 -haswbstatement:P279" .
    ?title wikibase:apiOutput mwapi:title. 
  }
  BIND(IRI(CONCAT(STR(wd:), ?title)) AS ?item)
  #add any other requirements here
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?itemLabel
Try it!

Streets[edit]

à faire 3 rues en FR[edit]

https://w.wiki/c8q

rues Martinique[edit]

SELECT ?item ?itemLabel ?nomm__en_r_f_rence__ ?nomm__en_r_f_rence__Label WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?item wdt:P131 ?local;
    wdt:P31 wd:Q79007;
    (wdt:P131*) wd:Q617806.
  OPTIONAL { ?item wdt:P138 ?nomm__en_r_f_rence__. }
}
Try it!

Rues bilingues[edit]

SELECT ?item ?itemLabel ?place_name_sign ?lang1Label ?lang2Label
WHERE
{
  ?item p:P1766 ?sign_statement .
  ?sign_statement a wikibase:BestRank .
  ?sign_statement ps:P1766 ?place_name_sign .
  ?sign_statement pq:P407 ?lang1 .
  ?sign_statement pq:P407 ?lang2 .
  FILTER (STR(?lang1) < STR(?lang2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Rues bilingues alsacien/français[edit]

https://w.wiki/3Yev

Train, buses and subways[edit]

Stations in India[edit]

SELECT ?item ?itemLabel ?Indian_Railways WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P31 wd:Q55488.
  ?item wdt:P17 wd:Q668.
  OPTIONAL { ?item wdt:P5696 ?Indian_Railways. }
    MINUS    { ?item wdt:P576 [].}                    # remove items with P576 (dissolved, abolished or demolished) as a main property
  MINUS    { ?item wdt:P582 [].}                    # remove items with P582 (end date) as a main property
}
Try it!

Shanghai metro map[edit]

Map of Shanghai Metro (query)

Y shaped subways[edit]

SELECT ?metroline ?metrolineLabel ?endpoints ?carte_d_itin_raire WHERE {
  {
    SELECT ?metroline (COUNT(?endpoint_statement) AS ?endpoints) WHERE {
      ?metroline wdt:P31 wd:Q15079663;
        p:P559 ?endpoint_statement.
      ?endpoint_statement a wikibase:BestRank.
      FILTER NOT EXISTS { ?endpoint_statement pq:P582 []. }
    } 
    GROUP BY ?metroline 
    HAVING (?endpoints > 2 )
  } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  OPTIONAL { ?metroline wdt:P15 ?carte_d_itin_raire. }
}
Try it!


Y shaped subways, other query[edit]

#defaultView:ImageGrid
SELECT ?metroline ?metrolineLabel ?endpoints ?carte_d_itin_raire WHERE {
  {
    SELECT ?metroline (COUNT(?endpoint_statement) AS ?endpoints) WHERE {
      ?metroline wdt:P31 wd:Q105967897;
        p:P559 ?endpoint_statement.
      ?endpoint_statement rdf:type wikibase:BestRank.
      FILTER(NOT EXISTS { ?endpoint_statement pq:P582 _:b2. })
    }
    GROUP BY ?metroline
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
   ?metroline wdt:P15 ?carte_d_itin_raire.
}
Try it!

subway networks[edit]

subway lines[edit]

https://w.wiki/3KLw

Subways stations[edit]

https://w.wiki/3rKn

https://w.wiki/3Mic

https://w.wiki/3gUE (les sans partie de ; sans ligne de chemin de fer) https://w.wiki/4UFx (sans gares voisines) https://w.wiki/3NU$ les zhan en chinois (850 résultats)

https://w.wiki/3nz8 les descriptions en FR

Map of some bus lines in Rennes[edit]

https://w.wiki/3GbR

Map of some tramway lines in Stuttgart[edit]

https://w.wiki/3LtP

Map of Strasbourg tramway

Map of Strasbourg tramway (query)

Map of trams in Geneva

Map of trams in Geneva (query)

Map of tramway lines in Paris suburbs[edit]

#defaultView:Map{"hide":["?coordinates", "?line", "?rgb"]}
SELECT DISTINCT ?coordinates ?line ?item ?itemLabel ?connectLabel ?image ?opening ?rgb 

WITH {
  SELECT ?item (SAMPLE(?coordinates) AS ?coordinates)  (sample(?lat1) as ?lat1) (sample(?lon1) as ?lon1)
         WHERE {
    ?item wdt:P31 wd:Q2175765 ;
          wdt:P361 wd:Q1142114 ;
          wdt:P625 ?coordinates ;
          p:P625 / psv:P625 / wikibase:geoLatitude ?lat1 ;
          p:P625 / psv:P625 / wikibase:geoLongitude ?lon1 . 
MINUS { ?item wdt:P5817 ?interdit VALUES ?interdit {wd:Q811683 wd:Q63065035 wd:Q12377751 wd:Q30108381 wd:Q11639308} } 
MINUS { ?item (wdt:P576|wdt:P582|wdt:P3999) ?dispar. }

  } GROUP BY ?item
} AS %stations
WITH { 
  SELECT ?nextstation (sample(?lat2) as ?lat2) (sample(?lon2) as ?lon2) WHERE {
    ?nextstation wdt:P31  wd:Q2175765 ;
                 wdt:P361 wd:Q1142114 ;
                 p:P625 / psv:P625 / wikibase:geoLatitude ?lat2 ;
                 p:P625 / psv:P625 / wikibase:geoLongitude ?lon2 .
  } GROUP BY ?nextstation
} AS %nextstations 

WITH {
  SELECT ?line ?connect ?rgb WHERE { 
    INCLUDE %stations .
    INCLUDE %nextstations .
    ?item p:P197 ?nextstationstatement .
    ?nextstationstatement ps:P197 ?nextstation ;
                          pq:P81 ?connect .
    ?connect                         wdt:P465 ?rgb.
    FILTER(STR(?item) < STR(?nextstation)) .
    BIND(CONCAT('LINESTRING (', STR(?lon1), ' ', STR(?lat1), ',', STR(?lon2), ' ', STR(?lat2), ')') AS ?str) .
    BIND(STRDT(?str, geo:wktLiteral) AS ?line)  
  }
} AS %lines 

WHERE {
  { INCLUDE %stations }  UNION { INCLUDE %lines  } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,de". } 
}
Try it!

Map of Montpellier tramway[edit]

#defaultView:Map{"hide":["?coords", "?line","?rgb"]}
SELECT ?station ?stationLabel ?coords ?line ?layer ?rgb  WHERE {
  ?station wdt:P31 wd:Q2175765;
    wdt:P361 wd:Q1753254;
    wdt:P625 ?coords;
    wdt:P81 ?subwayLine;
    wdt:P197 ?pred .  
  MINUS { ?station (wdt:P576|wdt:P582|wdt:P3999) ?dispar. }
  MINUS { ?station wdt:P5817 ?interdit.
    VALUES ?interdit {
      wd:Q811683
      wd:Q63065035
      wd:Q12377751
      wd:Q55653430
      wd:Q30108381
      wd:Q55570340
      wd:Q11639308
    }
  }
  ?pred wdt:P625 ?cds .
  BIND(IF((xsd:double(?depth / 10 )) = (xsd:integer(?depth / 10 )), ?cds, "") AS ?coords)
  ?pred (p:P625/psv:P625/wikibase:geoLatitude) ?lat1;
    (p:P625/psv:P625/wikibase:geoLongitude) ?lon1 .
  ?station (p:P625/psv:P625/wikibase:geoLatitude) ?lat2;
    (p:P625/psv:P625/wikibase:geoLongitude) ?lon2.
  BIND(CONCAT("LINESTRING(", STR(?lon1), " ", STR(?lat1), ",", STR(?lon2), " ", STR(?lat2), ")") AS ?str)
  BIND(STRDT(?str, geo:wktLiteral) AS ?line)
  ?subwayLine wdt:P465 ?rgb .
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?subwayLine rdfs:label ?layer.
    ?station rdfs:label ?stationLabel . 
  } }   
GROUP BY ?station ?stationLabel ?coords ?line ?layer ?rgb
Try it!

Map of Hefei subway[edit]

Map of Hefei Metro (query)

Carte des métros de la Chine v2[edit]

#title: Carte des métros de Chine/China subways v2
#defaultView:Map{"hide":["?coords", "?searchlines", "?termini","?rgb", "?line_draw"]}
SELECT distinct ?stationLabel ?linesLabel ?searchlines ?lignes ?line_draw ?termini ?station ?coords ?pred ?rgb WHERE {
?searchlines wdt:P17 wd:Q148;wdt:P31/wdt:P279* wd:Q728937; wdt:P559 ?termini#quels sont les terminus de ce métro, what are the ends of these lines
  ; wdt:P465 ?rgb   .
 VALUES ?stations_type { 
               wd:Q928830 #station de métro
               wd:Q2175765 # tramway
             }
  ?station wdt:P31/wdt:P279* ?stations_type;  
    wdt:P81 ?searchlines;
    wdt:P625 ?coords  ;
    wdt:P197 ?pred.
   ?pred wdt:P625 ?coords_pred;
    wdt:P81 ?subwayLine_pred.
  ?station p:P197 _:b1.
  _:b1 ps:P197 ?pred ;
    pq:P5051 ?towards;
    pq:P81 ?line_pq.
  FILTER(?subwayLine_pred = ?searchlines)#on ne prend les LINES que si la correspondance est sur la même ligne
  FILTER(?towards = ?termini) 
  FILTER(?station != ?termini)
  MINUS { ?station (wdt:P576|wdt:P582|wdt:P3999) ?dispar. }
  MINUS {
    ?station wdt:P5817 ?interdit.
    VALUES ?interdit { 
      wd:Q811683
      wd:Q63065035 
      wd:Q12377751
      wd:Q55653430
      wd:Q30108381
      wd:Q55570340
      wd:Q11639308
    }
  }
  ?pred (p:P625/psv:P625/wikibase:geoLatitude) ?lat1   ;
    (p:P625/psv:P625/wikibase:geoLongitude) ?lon1  .
  ?station (p:P625/psv:P625/wikibase:geoLatitude) ?lat2 ;
    (p:P625/psv:P625/wikibase:geoLongitude) ?lon2.
  BIND(CONCAT("LINESTRING(", STR(?lon1), " ", STR(?lat1),  ",", STR(?lon2), " ", STR(?lat2), ")") AS ?str)
  BIND(STRDT(?str, geo:wktLiteral) AS ?line_draw  )
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr,en,zh".
    ?searchlines rdfs:label ?layer .
    ?searchlines rdfs:label ?linesLabel.
    ?station rdfs:label ?stationLabel.
  }  }
Carte des métros de Chine/China subways v2

Carte des métros/tramways de France[edit]

#title: Cartes des métros et tramways de France
#defaultView:Map{"hide":["?coords", "?line","?rgb"]}
SELECT ?station ?stationLabel ?subwayLine ?systemLabel ?coords ?line  ?rgb WHERE {
  VALUES ?searchpays {
    wd:Q142  #critère de recherche de pays
  } 
  ?system wdt:P31/wdt:P279* wd:Q3491904;wdt:P17 ?searchpays.
      ?system wdt:P527 ?lignes.#quelles sont les lignes de ces métros
      ?lignes wdt:P559 ?termini.#quels sont les terminus de ces métros
  ?station wdt:P31/wdt:P279*  wd:Q548662;  #station de métro ou de tramway
           wdt:P361 ?system;#qui font partie du réseau recherché
    wdt:P625 ?coords;
    wdt:P81|wdt:P1192 ?subwayLine;
    wdt:P197 ?pred.
  ?pred wdt:P625 ?coords_pred;
    wdt:P81|wdt:P1192 ?subwayLine_pred.
  ?station p:P197 _:b1.
  _:b1 ps:P197 ?pred ;
    pq:P5051 ?towards;
    pq:P81|pq:P1192 ?line_pq.
  FILTER(?subwayLine_pred = ?lignes)#on ne prend les LIGNES que si la correspondance est sur la même ligne
  FILTER(?subwayLine = ?lignes)
  FILTER(?towards = ?termini) 
  MINUS { ?station (wdt:P576|wdt:P582|wdt:P3999) ?dispar. }#on ne veut pas les stations disparues
  MINUS {
    ?station wdt:P5817 ?interdit.
    VALUES ?interdit {
      wd:Q811683
      wd:Q63065035 
      wd:Q12377751
      wd:Q97317113
      wd:Q55653430
      wd:Q30108381
      wd:Q55570340
      wd:Q11639308
    }
  }#on ne veut pas les cas particuliers, en construction etc
 ?pred  p:P625 ?node_pred .
  ?node_pred psv:P625/wikibase:geoLatitude ?lat1 ;
        psv:P625/wikibase:geoLongitude ?lon1 .
  ?node_pred a wikibase:BestRank.
  ?station p:P625 ?node_station.
 ?node_station psv:P625/wikibase:geoLatitude ?lat2 ;
   psv:P625/wikibase:geoLongitude ?lon2. 
 ?node_station a wikibase:BestRank.
  BIND(CONCAT("LINESTRING(", STR(?lon1), " ", STR(?lat1),  ",", STR(?lon2), " ", STR(?lat2), ")") AS ?str)
  BIND(STRDT(?str, geo:wktLiteral) AS ?line  )
  ?subwayLine wdt:P465 ?rgb   . 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".
    ?subwayLine rdfs:label ?layer0 .
     ?system rdfs:label ?systemLabel.
    ?pred rdfs:label ?predLabel.
    ?station rdfs:label ?stationLabel. 
  }   
bind(   Concat(?layer0," ",?systemLabel) as ?layer)
}  
GROUP BY ?station ?stationLabel  ?subwayLine ?rgb ?predLabel ?systemLabel ?layer  ?coords ?line
Cartes des métros et tramways de France

Labels fr à rajouter[edit]

select  ?item (group_concat(?partieLabel;separator=", ") as ?partieLabelFr) (group_concat(?ligneLabel;separator=", ") as ?ligneLabelFr)
where {SELECT ?item ?ligne ?ligneLabel ?partieLabel ?partie WHERE { 
  ?item wdt:P31 wd:Q928830.
  OPTIONAL { ?item wdt:P361 ?partie. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  FILTER(NOT EXISTS {
    ?item schema:description ?itemdesc.
    FILTER((LANG(?itemdesc)) = "fr")  })
  OPTIONAL { ?item wdt:P81 ?ligne. }   MINUS { ?item (wdt:P576|wdt:P582|wdt:P3999) ?dispar. }
  MINUS { 
    ?item wdt:P5817 ?interdit.    VALUES ?interdit {
      wd:Q811683
      wd:Q63065035 
      wd:Q12377751 
      wd:Q55653430  
      wd:Q30108381 
      wd:Q55570340 
      wd:Q11639308    }
  } }  } group by ?item
Try it!

Ambassades[edit]

Essais nucléaires[edit]

SELECT ?essai_nucl_aire ?essai_nucl_aireLabel ?date ?op_rateur ?op_rateurLabel ?tnt ?equivalent_nergie_kT ?partie_de ?partie_deLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?essai_nucl_aire (wdt:P31 /(wdt:P279*)) wd:Q210112.
  MINUS { ?essai_nucl_aire (wdt:P31/(wdt:P279*)) wd:Q98391050. }
  OPTIONAL { ?essai_nucl_aire wdt:P585 ?date. }
  OPTIONAL { ?essai_nucl_aire wdt:P137 ?op_rateur. }
  OPTIONAL { ?essai_nucl_aire wdt:P2145 ?tnt. }
  OPTIONAL {
    ?essai_nucl_aire p:P2145 ?yield_statement.
    ?yield_statement rdf:type wikibase:BestRank;
      (psn:P2145/wikibase:quantityAmount) ?joule.
    BIND((?joule / 4184000000 ) / "1000.0"^^xsd:decimal AS ?equivalent_nergie_kT)
 }
  OPTIONAL { ?essai_nucl_aire wdt:P361 ?partie_de.  }
 }
Try it!

==>à finir https://w.wiki/avZ (france) ==>résultat final ? https://w.wiki/bXH

guerres à faire[edit]

https://w.wiki/dEY

Coups d'États[edit]

SELECT DISTINCT ?coup_d__tat ?coup_d__tatLabel ?date ?pays ?paysLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?coup_d__tat wdt:P31/wdt:P279* wd:Q45382.
  OPTIONAL { ?coup_d__tat wdt:P585 ?date. }
  OPTIONAL { ?coup_d__tat wdt:P17 ?pays. }
}order by ?date
Try it!

dates et processus temporels[edit]

SELECT ?item ?start ?start_prc ?end ?end_prc ?nature_de_l__l_ment ?nature_de_l__l_mentLabel WHERE {
  VALUES ?start_prc {
    9 
    10 
    11 
  }
  ?item (p:P580/psv:P580) _:b12.
  _:b12 wikibase:timePrecision ?start_prc;
    wikibase:timeValue ?start.
  VALUES ?end_prc {
    9 
    10 
    11 
  }
  ?item (p:P582/psv:P582) _:b13.
  _:b13 wikibase:timePrecision ?end_prc;
    wikibase:timeValue ?end.
  MINUS { ?item p:P585 _:b14. }
  FILTER((YEAR(?start)) = (YEAR(?end)))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  OPTIONAL { ?item wdt:P31 ?nature_de_l__l_ment. }
}
LIMIT 1000
Try it!

éclipses[edit]

SELECT ?_clipse ?_clipseLabel ?date WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?_clipse wdt:P31/wdt:P279* wd:Q141022.
  ?_clipse wdt:P585 ?date. 
}
order by asc(?date)
Try it!

saros solaires[edit]

SELECT ?item ?itemLabel ?corps ?rang ?date_de_d_but ?date_de_fin
WHERE
{
?item  wdt:P31/wdt:P279* wd:Q220397 .
?item  p:P31 [ pq:P376 ?qualifier ].
?item  p:P31 [ pq:P376 ?corps ].
?item  p:P31 [ pq:P1545 ?rang].

     OPTIONAL { ?item wdt:P580 ?date_de_d_but. }
  OPTIONAL { ?item wdt:P582 ?date_de_fin. }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
ORDER BY xsd:integer(?rang)
Try it!

air catastrophes[edit]

SELECT ?accidents ?accidentsLabel ?date ?operateurLabel ?flight_num (sample(?perpetrateurLabel) as ?perpetrateur)  (max(?victime) as ?victimes) (sample(?ASN_ids) as ?ASN_ids ) WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  VALUES ?what {
    wd:Q744913
    wd:Q898712
    wd:Q3149875
    wd:Q15931405
    wd:Q1863435
    wd:Q3002150
    wd:Q12051532
    wd:Q104776655
  }
  ?accidents (wdt:P31/wdt:P279) ?what.  
  OPTIONAL { ?accidents wdt:P585 ?date. }
  OPTIONAL { ?accidents wdt:P137 ?operateur. } 
  OPTIONAL { ?accidents wdt:P8031 ?perpetrateur. } 
  OPTIONAL { ?accidents wdt:P1590|wdt:P1120 ?victime. } 
  OPTIONAL { ?accidents wdt:P1755|wdt:P1760 ?ASN_ids. } 
  OPTIONAL { ?accidents wdt:P3090 ?flight_num. }    
} 
group by ?accidents ?accidentsLabel ?flight_num ?date ?operateurLabel
order by ?victimes ?date
Try it!

banknotes[edit]

SELECT ?item ?itemLabel ?valeur_faciale WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
  OPTIONAL { ?item wdt:P3934 ?valeur_faciale. }
} order by ?valeur_faciale
Try it!

killed by the nazis[edit]

https://w.wiki/3FHa

test[edit]

Map of Tokyo Metro (query)

Graphs on cywiki[edit]

Hi there. Jura1 mentioned you on Wikidata:Project chat as we allow, on cywiki (Welsh language) direct WD flow, even in the automated text of articles. I wonder if you could help me get this bad attempt! to work? I'm a Beurocrat on cywiki, and we edit straight on the articles, rather than in sand boxes. Just revert if it doesn't work! If your too busy, then I apologise for wasting your time! Llywelyn2000 (talk) 16:48, 23 November 2021 (UTC)

Google-refine-logo.svgThis user loves OpenRefine.
Wikidata WikiProject france.svgThis user is a member of the WikiProject France.