Topic on User talk:VIGNERON

Salut, Est-ce possible pour toi de me produire une liste des auteurs canadiens de langue françaises, avec les dates de naissance et de décès, triable par une des 2 dates ?

Est-ce possible d'exporter cette liste dans Excel. (Si oui alors je pourrai faire les tris moi-même) ?

Mon objectif est de vérifier si ces auteurs ont des œuvres dans Wikisource et de publier dans Twitter Projet Québec/Canada selon leurs dates de naissance ou décès. Cela me permettra d'être plus pro-actif et de préparer les tweets d'avance. Merci pour ton aide.

Bonjour,

Excellente idée ! Et, oui, tout est possible avec SPARQL, le problème c'est en général plutôt au niveau des informations présentes/absentes dans Wikidata

Pour répondre à ta question, voilà la requête :

SELECT * WHERE {
  ?q wdt:P31 wd:Q5 ;
     wdt:P27 wd:Q16 ;
     wdt:P1412 wd:Q150 ;
     wdt:P569 ?dateN ;
     wdt:P570 ?dateM .
}

Try it!

Mais vu ton besoin, j'ai fait la requête plus avancée suivante pour ceux mort avant 1950 et sans texte sur la Wikisource francophone :

SELECT * WHERE {
  ?q wdt:P31 wd:Q5 ;
     wdt:P27 wd:Q16 ;
     wdt:P1412 wd:Q150 ;
     wdt:P569 ?dateN ;
     wdt:P570 ?dateM .
  FILTER ( year(?dateM) < 1950 ) #mort avant 1950
  MINUS { ?texte wdt:P50 ?q . ?page schema:about ?texte ; schema:isPartOf <https://fr.wikisource.org/> } #sans texte sur fr.ws
}

Try it!

Et oui, tu peux exporter les résultats au format CSV qui sera compris par Excel.

Wow merci, tu est rapide ! comment j'obtiens le nom de l'auteur ?

Ooups, pardon, j'ai oublié cette partie (j'en ai profité pour ajouter la description du coup), voilà :

SELECT ?q ?qLabel ?qDescription ?dateN ?dateM WHERE {
  ?q wdt:P31 wd:Q5 ;
     wdt:P27 wd:Q16 ;
     wdt:P1412 wd:Q150 ;
     wdt:P569 ?dateN ;
     wdt:P570 ?dateM .
  FILTER ( year(?dateM) < 1950 ) #mort avant 1950
  MINUS { ?texte wdt:P50 ?q . ?page schema:about ?texte ; schema:isPartOf <https://fr.wikisource.org/> } #sans texte sur fr.ws
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!