Wikidata:WikiProject Knowledge Organization Systems/Mappings
Jump to navigation
Jump to search
Try it!
Try it!
Try it!
Try it!
Tasks[edit]
- Extract Mappings from Wikidata
- Simplify editing mappings into Wikidata
- Define appropriate qualifiers for concept mappings
- For Dewey Decimal Classification (P1036) uses has edition or translation (P747) to specificy an edition of DDC but what about KOSs without editions?
- How to differentiate exact/close equivalence, broader mappings and related mappings? See thesaurus (Q17152639) for an example that has a more specific meaning than mapped DDC number 025.47. Maybe qualify with has use (P366) and hypernym (Q609507)?
Queries[edit]
KOS with Mapping properties[edit]
SELECT DISTINCT ?bartoc ?kos ?de ?en ?prop ?propLabel
WHERE
{
?kos wdt:P31/wdt:P279* wd:Q6423319 .
{
{ ?kos wdt:P1687 ?prop } UNION { ?prop wdt:P1629 ?kos }
}
OPTIONAL { ?kos rdfs:label ?en . FILTER (lang(?en) = 'en') }
OPTIONAL { ?kos rdfs:label ?de . FILTER (lang(?de) = 'de') }
OPTIONAL { ?kos wdt:P2689 ?id }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
BIND(IRI(CONCAT("http://bartoc.org/en/",?id)) as ?bartoc)
} ORDER BY ?kos
Dewey Decimal Classification[edit]
Makes use of property Dewey Decimal Classification (P1036) (see for nice analysis)
# Number of distinct Wikidata items with DDC number
SELECT (COUNT(DISTINCT ?item) AS ?items) WHERE {
?item p:P1036 ?ddc
}
# Number of distinct DDC numbers found in Wikidata
SELECT (COUNT(DISTINCT ?ddc) AS ?numbers) WHERE {
?item p:P1036 ?ddc
}
# Get DDC numbers from Wikidata for a given Wikipedia article
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT ?item ?itemLabel ?ddc ?edition ?editionLabel WHERE {
<https://no.wikipedia.org/wiki/Fisk> schema:about ?item .
# Replace three lines with "?item wdt:P1036 ?ddc" if edition don't matter
?item p:P1036 ?statement .
?statement ps:P1036 ?ddc .
OPTIONAL { ?statement pq:P747 ?edition . }
SERVICE wikibase:label {
bd:serviceParam wikibase:language "no,en" .
}
}