Wikidata:WikiProject France/Sport

Installations sportives

« L'installation sportive est un lieu caractérisé par une adresse, où sont implantés un ou plusieurs équipements sportifs, avec ou sans enceinte limitative. »

# Liste des 135824 installations sportives en France enregistrées au Recensement des équipements sportifs
SELECT ?item ?itemLabel ?numéro ?nomRES WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?item p:P11840 [ps:P11840 ?numéro; # numéro de l'installation
                        pq:P1810 ?nomRES; # nom de l'installation
                        prov:wasDerivedFrom [ pr:P248 wd:Q115755558 ] # enregistrement au Recensement des équipements sportifs
                ].   
}

Try it!

Par type d'équipement sportif

# Liste des 163 types d'équipements sportifs dans la nomenclature du Recensement des équipements sportifs
SELECT ?item ?itemLabel ?code WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?item p:P528 [ps:P528 ?code; # code de l'équipement
                        pq:P2868 wd:Q121252873; # type d'équipement sportif
                        prov:wasDerivedFrom [ pr:P248 wd:Q115755558 ] # enregistrement au Recensement des équipements sportifs
                ].   
}
ORDER BY ?code

Try it!

Bowlings

Pour Wikidata, bowling = bowling alley (Q27106471)

# Liste des 302 installations comprenant un bowling en France
SELECT ?installation ?installationLabel ?numéro ?nominstallation
(GROUP_CONCAT(?typeéquipementLabel; separator=", ") AS ?typeéquipements) # liste des types d'équipements de l'installation, séparés par des virgules
(GROUP_CONCAT(?noméquipement; separator=", ") AS ?nomséquipements) # iste des noms des équipements, séparés par des virgules
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
                          ?installation rdfs:label ?installationLabel .
                          wd:Q27106471 rdfs:label ?typeéquipementLabel .
  }
  ?installation p:P11840 [ps:P11840 ?numéro; # numéro de l'installation dans le Recensement des équipements sportifs
                        pq:P1810 ?nominstallation; # nom de l'installation dans le Recensement des équipements sportifs
                        prov:wasDerivedFrom [ pr:P248 wd:Q115755558; pr:P5017 ?miseàjour ] # date de mise à jour dans le Recensement des équipements sportifs
                ].  
  ?installation p:P912 [ps:P912 wd:Q27106471; # présence d'un bowling   
                                pq:P2561 ?noméquipement; # nom de l'équipement
                ].

}GROUP BY ?installation ?installationLabel ?numéro ?nominstallation
ORDER BY ?installationLabel

Try it!

# Liste des 314 bowlings en France
SELECT ?numéroéquipement ?noméquipement ?typeéquipementLabel ?installation ?installationLabel ?longueur ?largeur ?nombrepistes ?surfaceLabel ?datecréation WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?installation p:P912 [ps:P912 ?typeéquipement; # présence d'un bowling
                                pq:P217 ?numéroéquipement; # numéro d'équipement
                                pq:P2561 ?noméquipement; # nom de l'équipement
                                pq:P2043 ?longueur;
                                pq:P2049 ?largeur;
                                pq:P1114 ?nombrepistes;
                                pq:P765 ?surface; 
                                pq:P571 ?datecréation; 
                ]. 
  VALUES ?typeéquipement { wd:Q27106471 }. # équipement bowling
}ORDER BY ?installation

Try it!

Patinoires

Pour Wikidata, aire de sports de glace = ice rink (Q1282870)

# Liste des 178 installations comprenant une aire de sports de glace en France
SELECT ?installation ?installationLabel
(GROUP_CONCAT(?typedaireLabel; separator=", ") AS ?aires)
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
                          ?installation rdfs:label ?installationLabel .
                          ?typedaire rdfs:label ?typedaireLabel .
  }
  
  ?installation p:P912 [ps:P912 ?typedaire; # présence d'une aire de sports de glace                     
                ].
  ?typedaire wdt:P279 wd:Q1282870; # sous-classe d'aire de sports de glace
                p:P528 [pq:P972 wd:Q115755558]. # type d'équipement au Recensement des équipements sportifs
}GROUP BY ?installation ?installationLabel
ORDER BY ?installationLabel

Try it!

# Liste des 199 aires de sports de glace en France
SELECT ?numéroéquipement ?noméquipement ?typeéquipementLabel ?installation ?installationLabel ?longueur ?largeur ?hauteur ?superficie ?surfaceLabel ?datecréation WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?installation p:P912 [ps:P912 ?typeéquipement; # présence d'une aire de sports de glace
                                pq:P217 ?numéroéquipement; # numéro d'équipement de l'aire
                                pq:P2561 ?noméquipement; # nom de l'aire
                                pq:P2043 ?longueur;
                                pq:P2049 ?largeur;
                                pq:P2048 ?hauteur;
                                pq:P2046 ?superficie;
                                pq:P765 ?surface; 
                                pq:P571 ?datecréation; 
                ].
  ?typeéquipement wdt:P279 wd:Q1282870; # sous-classe d'aire de sports de glace
                p:P528 [pq:P972 wd:Q115755558]. # type d'équipement au Recensement des équipements sportifs
}ORDER BY ?installation

Try it!

Piscines

Pour Wikidata, bassin de natation = swimming pool (Q1501)

# Liste des 3782 installations sportives comprenant un bassin de natation en France
SELECT ?installation ?installationLabel
(GROUP_CONCAT(?typedebassinLabel; separator=", ") AS ?bassins)
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
                          ?installation rdfs:label ?installationLabel .
                          ?typedebassin rdfs:label ?typedebassinLabel .
  }
  
  ?installation p:P912 [ps:P912 ?typedebassin; # présence d'un bassin                            
                ].
  ?typedebassin wdt:P279 wd:Q1501; # sous-classe de bassin de natation
                p:P528 [pq:P972 wd:Q115755558]. # type d'équipement au Recensement des équipements sportifs
}GROUP BY ?installation ?installationLabel
ORDER BY ?installationLabel

Try it!

# Liste des 6381 bassins de natation en France
SELECT ?numérobassin ?nombassin ?typedebassinLabel ?installation ?installationLabel ?formeLabel ?longueur ?largeur ?profondeur WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?installation p:P912 [ps:P912 ?typedebassin; # présence d'un bassin
                                pq:P217 ?numérobassin; # numéro d'équipement du bassin
                                pq:P2561 ?nombassin; # nom du bassin
                                pq:P1419 ?forme; # forme du bassin
                                pq:P2043 ?longueur;
                                pq:P2049 ?largeur;
                                pq:P4511 ?profondeur;                               
                ].
  ?typedebassin wdt:P279 wd:Q1501; # sous-classe de bassin de natation
                p:P528 [pq:P972 wd:Q115755558]. # type d'équipement au Recensement des équipements sportifs
}ORDER BY ?installation

Try it!