Wikidata:WikiProject Cycling/SPARQL

Riders who have no english Wikipedia article

The following query uses these:

• Items: human (Q5)   , sport cyclist (Q2309784)   

• Properties: instance of (P31)   , occupation (P106)   

  SELECT DISTINCT ?item WHERE {
  ?item wdt:P31 wd:Q5. 
  ?item wdt:P106 wd:Q2309784  
  Minus {
  ?article schema:about ?item. 
  ?article schema:inLanguage "en". 
  FILTER (SUBSTR(str(?article), 1, 25) = "https://en.wikipedia.org/")
  }
  }
  

Try it!

lists of all riders that have no english Wikipedia article

Cycling teams who have no english Wikipedia article

The following query uses these:

• Properties: UCI code of cycling team (P1998)   , part of (P361)   

  SELECT DISTINCT ?item WHERE {
  ?item wdt:P1998 ?obj1 
  Minus {
  ?item wdt:P361 ?obj2 
  }
  Minus {
  ?article schema:about ?item. 
  ?article schema:inLanguage "en". 
  FILTER (SUBSTR(str(?article), 1, 25) = "https://en.wikipedia.org/")
  }
  }
  

Try it!

lists all cycling teams that have no english Wikipedia article

All races

The following query uses these:

• Items: road bicycle racing (Q3609)   

• Properties: sport (P641)   

  SELECT ?sport ?sportLabel WHERE {
  ?sport wdt:P641 wd:Q3609. 
  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr", "en", "it"}   
  } ORDER BY ?sportLabel  LIMIT 1000
  

Try it!

lists all races.

Races that have a distance (P2043) with the rank deprecated

The following query uses these:

• Items: road bicycle racing (Q3609)   

• Properties: sport (P641)   , length (P2043)   

  PREFIX p: <http://www.wikidata.org/prop/>
  PREFIX ps: <http://www.wikidata.org/prop/statement/>
  SELECT ?sportLabel ?sport ?vLabel ?v WHERE {
  ?sport wdt:P641 wd:Q3609.# all races
  ?wds wikibase:rank wikibase:DeprecatedRank.
  ?sport p:P2043 ?wds.
  ?wds ps:P2043 ?v.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en".}     
  }
  

Try it!

list all races that have a distance (P2043) with the rank deprecated

Items that use qualifier P1642 (acquisition transaction)

The following query uses these:

• Items: death (Q4)   , died during training (Q23498247)   , died during competition (Q23498248)   , end of sports career (Q3428243)   , change of team (Q23498196)   , fired for doping (Q23531302)   , suspended by the UCI for doping (Q23531338)   

• Properties: acquisition transaction (P1642)   

  SELECT ?name ?z1Label WHERE {
  # values for P1642 (acquisition transaction)   
  VALUES ?z1 {wd:Q4 wd:Q23498247 wd:Q23498248 wd:Q3428243 wd:Q23498196 wd:Q23531302 wd:Q23531338}
  ?name pq:P1642 ?z1
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en", "fr"}   
  } ORDER BY ?z1Label
  

Try it!

find all items that use qualifier P1642 (acquisition transaction)

Season-items, no team-items

The following query uses these:

• Items: cycling team (Q1785271)   , professional cycling team (Q20639847)   , UCI Trade Team I (Q20653563)   , UCI ProTeam (Q20638319)   , UCI WorldTeam (Q6154783)   , UCI Professional Continental Team (Q382927)   , UCI Trade Team II (Q20653564)   , UCI Continental Team (Q1756006)   , UCI Trade Team III (Q20653566)   , club cycling team (Q20639848)   , amateur cycling team (Q20652655)   

• Properties: instance of (P31)   , part of (P361)   

  SELECT DISTINCT ?x ?xLabel ?teamLabel ?gLabel WHERE {
  VALUES ?team {wd:Q1785271 wd:Q20639847 wd:Q20653563 wd:Q20638319 wd:Q6154783 wd:Q382927 
                            wd:Q20653564 wd:Q1756006 wd:Q20653566 wd:Q20639848 wd:Q20652655} 
  ?x wdt:P31 ?team. 
  ?x wdt:P361 ?g. 
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en,fr,nl"}      
  } ORDER BY DESC(?g)
  

Try it!

Team-items, no season-items

The following query uses these:

• Items: cycling team (Q1785271)   , professional cycling team (Q20639847)   , UCI Trade Team I (Q20653563)   , UCI ProTeam (Q20638319)   , UCI WorldTeam (Q6154783)   , UCI Professional Continental Team (Q382927)   , UCI Trade Team II (Q20653564)   , UCI Continental Team (Q1756006)   , UCI Trade Team III (Q20653566)   , club cycling team (Q20639848)   , amateur cycling team (Q20652655)   

• Properties: instance of (P31)   , part of (P361)   

  SELECT DISTINCT ?x ?xLabel WHERE {
  VALUES ?team {wd:Q1785271 wd:Q20639847 wd:Q20653563 wd:Q20638319 wd:Q6154783 wd:Q382927 
                            wd:Q20653564 wd:Q1756006 wd:Q20653566 wd:Q20639848 wd:Q20652655} 
  ?x wdt:P31 ?team. 
  FILTER NOT EXISTS {?x wdt:P361 ?g}
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en,fr,es,nl,ca"}
  } ORDER BY DESC(?x)
  

Try it!

Team-items, with de article

The following query uses these:

• Items: cycling team (Q1785271)   , professional cycling team (Q20639847)   , UCI Trade Team I (Q20653563)   , UCI ProTeam (Q20638319)   , UCI WorldTeam (Q6154783)   , UCI Professional Continental Team (Q382927)   , UCI Trade Team II (Q20653564)   , UCI Continental Team (Q1756006)   , UCI Trade Team III (Q20653566)   , club cycling team (Q20639848)   , amateur cycling team (Q20652655)   

• Properties: instance of (P31)   , part of (P361)   , dissolved, abolished or demolished date (P576)   

  SELECT DISTINCT ?x ?xLabel WHERE {
  # find team-items, no season-items
  VALUES ?team {wd:Q1785271 wd:Q20639847 wd:Q20653563 wd:Q20638319 wd:Q6154783 wd:Q382927 wd:Q20653564 wd:Q1756006 wd:Q20653566 wd:Q20639848 wd:Q20652655} 
  ?x wdt:P31 ?team.
  ?article schema:about ?x .
  ?article schema:isPartOf <https://de.wikipedia.org/>.
  FILTER NOT EXISTS {?x wdt:P361 ?g}.
  FILTER NOT EXISTS {?x wdt:P576 ?gg}  
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en,fr,es,nl,ca,pl,pt,it"}
  } ORDER BY ASC(?xLabel)
  

Try it!

Items with sport (P641) only

• Wikidata:WikiProject Cycling/reports/P641 only

List of Tour de France's stage winners with country of citizenship

• Documented query : Wikidata:WikiProject Cycling/SPARQL/List of all tour de France's stage winners

National Road Cycling Championships Tree

The following query uses these:

• Items: Italy (Q38)   , national road cycling championship (Q2306612)   , season (Q27020041)   

• Properties: instance of (P31)   , country (P17)   , flag image (P41)   , sports season of league or competition (P3450)   , part of (P361)   , has part(s) (P527)   

  #defaultView:Tree
  SELECT ?country ?countryLabel ?countryFlag ?championship ?championshipLabel ?year ?yearLabel ?race ?raceLabel
  WHERE {
    #BIND(wd:Q38 as ?country)
    ?championship wdt:P31 wd:Q2306612;
                  wdt:P17 ?country.
    ?country wdt:P41 ?countryFlag.
    
    {
      ?year wdt:P31 ?championship.
    } UNION {
      ?year wdt:P31 wd:Q27020041.
      { 
        ?year wdt:P3450 ?championship.
  #     } UNION {
  #       ?year rdfs:label ?itLabel.
  #       FILTER(LANG(?itLabel) = "it" && STRSTARTS(?itLabel, "Campionato italiano di ciclismo su strada")).
      }
    }
    
    OPTIONAL { { ?race wdt:P361 ?year. } UNION { ?year wdt:P527 ?race. } }
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
  }
  ORDER BY ?countryLabel ?championshipLabel ?yearLabel
  

Try it!