Wikidata:WikiProject Coding da Vinci/Querys

Back to the overview of WikiProjects / Cultural WikiProjects / GLAM WikiProjects
 Work in progress - last updated 2022-09

 Welcome to CdV CdV querys & data visualization CdV events CdV datasets CdV projects CdV awards 

Querys (data tables)

Events

All Coding da Vinci events

All items which are part of the series (P179)Coding da Vinci (Q51845238)

• The following data can currently be compared with the query:
  • start time (P580), end time (P582), maintained by WikiProject (P6104), edition number (P393), follows (P155), followed by (P156), official website (P856), logo image (P154), country (P17), organizer (P664), participant (P710)

Show query result (Wikidata Query Service link)

Collapse to show the query

SELECT 
  ?item ?itemLabel ?startTime ?endTime ?maintainedByWikiProjectLabel ?editionNr ?followsLabel ?followedByLabel ?officialWebsite ?logoImage
  (GROUP_CONCAT(DISTINCT ?countryLabel; SEPARATOR = " | ") AS ?countries) 
  (GROUP_CONCAT(DISTINCT ?organizerLabel; SEPARATOR = " | ") AS ?organizers)
  (GROUP_CONCAT(DISTINCT ?participantLabel; SEPARATOR = " | ") AS ?participants)  
WHERE {
  ?item wdt:P179 wd:Q51845238.
  OPTIONAL { ?item wdt:P580 ?startTime. }
  OPTIONAL { ?item wdt:P582 ?endTime. }
  OPTIONAL { ?item wdt:P6104 ?maintainedByWikiProject. }
  OPTIONAL { ?item wdt:P393 ?editionNr. }
  OPTIONAL { ?item wdt:P155 ?follows. }
  OPTIONAL { ?item wdt:P156 ?followedBy. }
  OPTIONAL { ?item wdt:P856 ?officialWebsite. }
  OPTIONAL { ?item wdt:P154 ?logoImage. }
  OPTIONAL { ?item wdt:P17 ?country. }
  OPTIONAL { ?item wdt:P664 ?organizer. }
  OPTIONAL { ?item wdt:P710 ?participant. }  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de,en".
    ?item rdfs:label ?itemLabel.
    ?maintainedByWikiProject rdfs:label ?maintainedByWikiProjectLabel.
    ?follows rdfs:label ?followsLabel.
    ?followedBy rdfs:label ?followedByLabel.
    ?country rdfs:label ?countryLabel.
    ?organizer rdfs:label ?organizerLabel.
    ?participant rdfs:label ?participantLabel.    
  }
}
GROUP BY ?item ?itemLabel ?startTime ?endTime ?maintainedByWikiProjectLabel ?editionNr ?followsLabel ?followedByLabel ?officialWebsite ?logoImage
ORDER BY DESC(?startTime)

Try it!

Datasets

Get all datasets for Coding da Vinci Baden-Württemberg 2022 (v1)

Collapse to show the query

SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P1535 ?statement0.
      ?statement0 (ps:P1535/(wdt:P279*)) wd:Q110553382.
    }
    LIMIT 100
  }
}

Try it!

Get all datasets and their creators for Coding da Vinci Baden-Württemberg 2022 (v2)

• Get all datasets used by (P1535)Coding da Vinci Baden-Württemberg 2022 (Q110553382) and their image (P18), creator (P170)

Show query result (Wikidata Query Service link)

Collapse to show the query

SELECT 
  ?item 
  ?itemLabel 
  ?image 
  (GROUP_CONCAT(DISTINCT ?creator; SEPARATOR = " | ") AS ?creatorIds) 
  (GROUP_CONCAT(DISTINCT ?creatorLabel; SEPARATOR = " | ") AS ?creatorLabels) 
WHERE {
  ?item wdt:P1535 wd:Q110553382.
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL { ?item wdt:P170 ?creator. }
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "de,en". 
    ?item rdfs:label ?itemLabel.
    ?creator rdfs:label ?creatorLabel. 
  }
}
GROUP BY ?item ?itemLabel ?image

Try it!

Projects

Get all CdV-BW-22 projects

• Get all projects created for (P9883)Coding da Vinci Baden-Württemberg 2022 (Q110553382)

Show query result (Wikidata Query Service link)

Collapse to show the query

SELECT 
  ?item 
  ?itemLabel 
  ?image 
  (GROUP_CONCAT(DISTINCT ?usedDataset; SEPARATOR = " | ") AS ?usedDatasetIds) 
  (GROUP_CONCAT(DISTINCT ?usedDatasetLabel; SEPARATOR = " | ") AS ?usedDatasetLabels) 
WHERE {
  ?item wdt:P9883 wd:Q110553382.
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL { ?item wdt:P973 ?describedAtUrl. }
  OPTIONAL { ?item wdt:P2283 ?usedDataset. }    
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de,en".
    ?item rdfs:label ?itemLabel.
    ?usedDataset rdfs:label ?usedDatasetLabel.
  }
}
GROUP BY ?item ?itemLabel ?image

Try it!

Awards

Get all CdV-BW-22 awards and winners

• Get all awards conferred by (P1027)Coding da Vinci Baden-Württemberg 2022 (Q110553382) and projects award received (P166)CdV-BW-22-award

Show query result (Wikidata Query Service link)

Collapse to show the query

SELECT ?item ?itemLabel ?project ?projectLabel WHERE {
  ?item wdt:P1027 wd:Q110553382.
  ?project wdt:P166 ?item.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Try it!

Querys with data visualization

Visualize as a graph

Show linked projects, datasets and their creators for Coding da Vinci Baden-Württemberg 2022

Show query result (Wikidata Query Service link)

Collapse to show the query

#defaultView:Graph
SELECT ?nodeFrom ?nodeFromLabel ?nodeFromImage ?rgb ?nodeTo ?nodeToLabel ?nodeToImage WHERE {
  {
    SELECT (?project AS ?nodeFrom) (?projectImage AS ?nodeFromImage) ("2e86c1" AS ?rgb) (wd:Q110553382 AS ?nodeTo) (?cvdImage AS ?nodeToImage) WHERE {
      ?project wdt:P9883 wd:Q110553382.
      OPTIONAL { ?project wdt:P18 ?projectImage. }
      OPTIONAL { wd:Q110553382 wdt:P18 ?cvdImage. }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
    }
  }
  UNION
  {
    SELECT (?project AS ?nodeFrom) (?projectImage AS ?nodeFromImage) ("2e86c1" AS ?rgb) (?dataset AS ?nodeTo) (?datasetImage AS ?nodeToImage) WHERE {
      ?project wdt:P9883 wd:Q110553382;
        wdt:P2283 ?dataset.
      OPTIONAL { ?project wdt:P18 ?projectImage. }
      OPTIONAL { ?dataset wdt:P18 ?datasetImage. }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
    }
  }
  UNION
  {
    SELECT (?dataset AS ?nodeFrom) (?datasetImage AS ?nodeFromImage) ("2e86c1" AS ?rgb) (?creator AS ?nodeTo) (?creatorImage AS ?nodeToImage) WHERE {
      ?project wdt:P9883 wd:Q110553382;
        wdt:P2283 ?dataset.
      ?dataset wdt:P170 ?creator.
      OPTIONAL { ?creator wdt:P18 ?creatorImage. }
      OPTIONAL { ?dataset wdt:P18 ?datasetImage. }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!

Visualize as an image grid

View project images of Coding da Vinci Baden-Württemberg 2022

• View image (P18) of projects created for (P9883)Coding da Vinci Baden-Württemberg 2022 (Q110553382)

Show query result (Wikidata Query Service link)

Collapse to show the query

#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image WHERE {
  ?item wdt:P9883 wd:Q110553382.
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Try it!

View dataset images of Coding da Vinci Baden-Württemberg 2022

• View image (P18) of datasets used by (P1535)Coding da Vinci Baden-Württemberg 2022 (Q110553382)

Show query result (Wikidata Query Service link)

Collapse to show the query

#defaultView:ImageGrid
SELECT ?dataset ?datasetLabel ?image WHERE {
  ?dataset wdt:P1535 wd:Q110553382.
  OPTIONAL { ?dataset wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Try it!

View images of dataset creators for the Coding da Vinci Baden-Württemberg 2022 event

• View image (P18) of dataset creator (P170) used by (P1535)Coding da Vinci Baden-Württemberg 2022 (Q110553382)

Show query result (Wikidata Query Service link)

Collapse to show the query

#defaultView:ImageGrid
SELECT ?creator ?creatorLabel ?image WHERE {
  ?dataset wdt:P1535 wd:Q110553382;
    wdt:P170 ?creator.
  OPTIONAL { ?creator wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Try it!

Visualize as a map

View dataset creators and images for Coding da Vinci Baden-Württemberg 2022 on map

• View image (P18) of datasets and dataset creator (P170)s used by (P1535)Coding da Vinci Baden-Württemberg 2022 (Q110553382)

Show query result (Wikidata Query Service link)

Collapse to show the query

#defaultView:Map
SELECT ?dataset ?datasetLabel ?datasetImage ?creator ?creatorLabel ?creatorGeo ?creatorImage WHERE {
  ?dataset wdt:P1535 wd:Q110553382.
  OPTIONAL { ?dataset wdt:P18 ?datasetImage. }
  OPTIONAL { ?dataset wdt:P170 ?creator. }
  OPTIONAL { ?creator wdt:P625 ?creatorGeo. }
  OPTIONAL { ?creator wdt:P18 ?creatorImage. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Try it!

[WikiShootMe] Show available and missing images of the creator of the dataset

Show on map (WikiShootMe link)

Visualize as a bubble chart

View instances of which CdV-BW-22 projects are a particular example

Show query result (Wikidata Query Service link)

Collapse to show the query

#defaultView:BubbleChart 
#title:View instances of which CdV-BW-22 projects are a particular example
SELECT ?instance ?instanceLabel (COUNT(?instance) AS ?count) WHERE {
  ?project wdt:P9883 wd:Q110553382;
    wdt:P31 ?instance.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
GROUP BY ?instance ?instanceLabel
ORDER BY DESC (?count)

View instances of which CdV-BW-22 projects are a particular example

More querys

Which Wikidata items are linked to Coding da Vinci via which property?

All items and their properties, with which they are linked with Coding da Vinci (Q51845238)

Show query result (Wikidata Query Service link)

Collapse to show the query

SELECT ?item ?itemLabel ?property ?propertyLabel ?targetLabel WHERE {
  {
    SELECT ?item ?property WHERE {
      ?property wikibase:claim ?p;
        wikibase:statementProperty ?ps.
      ?st ?ps wd:Q51845238.
      ?item ?p ?st.
    }
  }
  BIND(wd:Q51845238 AS ?target)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
ORDER BY (?property)

Try it!

Which Wikidata items are linked to recurrent Coding da Vinci event editions via which property?

Get all items and their properties, with which they are linked to all events that are part of the series (P179)Coding da Vinci (Q51845238)

Show query result (Wikidata Query Service link)

Collapse to show the query

SELECT ?item ?itemLabel ?property ?propertyLabel ?targetLabel WHERE {
  {
    SELECT ?item ?property ?target WHERE {          
      ?property wikibase:claim ?p;
        wikibase:statementProperty ?ps.
      ?st ?ps ?target.
      ?target wdt:P179 wd:Q51845238.
      ?item ?p ?st.
      FILTER(?p NOT IN (p:P155, p:P156, p:P527)) # exclude properties follows, followed by and has part(s)
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de". }
}
ORDER BY (?property)

Try it!