Wikidata:WikiProject Antiquity

Administration

Home

Discussion

Participants

Subjects

WikiProject Antiquity

Aim and scope

The WikiProject Antiquity aims to gather all contributors working in an aspect or another of Antiquity, including its reception and study.

Historically, the term 'Antiquity' has been used to cover the period from around 3000 BC to around 500 AD in the regions of the ancient Mediterranean and the Near East, i.e. from the invention of writing in the Mesopotamian region to the collapse of the Roman empire. Nowadays, the end-limit is pushed forward and includes as well the following centuries and the states that were the successors of the Roman Empire. It is within this space-time framework that the heart of this project lies, but we welcome contributors working on other areas with similar timeframe.

With such a wide scope, we are active in a number of areas, including but not limited to:

By civilization

By discipline

archaeology (Q23498) = Wikidata:WikiProject Archaeology
philology (Q40634), especially classical philology (Q495527)
epigraphy (Q181260) => Wikidata:WikiProject Epigraphy
...

Transversal

Paulys Realenzyklopädie der klassischen Altertumswissenschaft (Q1138524) = see on German Wikisource de:s:Paulys Realencyclopädie der classischen Altertumswissenschaft
Dura-Europos (Q464266) = Wikidata:WikiProject IDEA
...

Showcase queries and graph

Authors of antiquity

#Authors of antiquity and slightly beyond
SELECT DISTINCT ?item ?itemLabel
  (GROUP_CONCAT(DISTINCT ?chap; separator=", ") as ?CHAP)
  (GROUP_CONCAT(DISTINCT ?ciris; separator=", ") as ?Ciris)
  (GROUP_CONCAT(DISTINCT ?clavisclavium; separator=", ") as ?ClavisClavium)
  (GROUP_CONCAT(DISTINCT ?corpuscorporum; separator=", ") as ?CorpusCorporum)
  (GROUP_CONCAT(DISTINCT ?dco; separator=", ") as ?DCO)
  (GROUP_CONCAT(DISTINCT ?dielskranz; separator=", ") as ?DielsKranz)
  (GROUP_CONCAT(DISTINCT ?digiliblt; separator=", ") as ?Digiliblt)
  (GROUP_CONCAT(DISTINCT ?dll; separator=", ") as ?DLL)
  (GROUP_CONCAT(DISTINCT ?fgrh; separator=", ") as ?FGRH)
  (GROUP_CONCAT(DISTINCT ?mqdq; separator=", ") as ?MQDQ)
  (GROUP_CONCAT(DISTINCT ?perseus; separator=", ") as ?Perseus)
  (GROUP_CONCAT(DISTINCT ?pinakes; separator=", ") as ?Pinakes)
  (GROUP_CONCAT(DISTINCT ?phi; separator=", ") as ?PHI)
  (GROUP_CONCAT(DISTINCT ?rspa; separator=", ") as ?RSPA)
  (GROUP_CONCAT(DISTINCT ?tlg; separator=", ") as ?TLG)
  (GROUP_CONCAT(DISTINCT ?tll; separator=", ") as ?TLL)
  (GROUP_CONCAT(DISTINCT ?tmauthor; separator=", ") as ?TMAuthor)
# (GROUP_CONCAT(DISTINCT ?viaf; separator=", ") as ?VIAF)

WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],la". }
  { ?item wdt:P11790 ?chap } UNION
  { ?item wdt:P8065 ?ciris } UNION
  { ?item wdt:P8163 ?dielskranz } UNION  
  { ?item wdt:P6862 ?digiliblt } UNION
  { ?item wdt:P7168 ?fgrh } UNION
  { ?item wdt:P6999 ?mqdq } UNION
  { ?item wdt:P6831 ?pinakes } UNION
  { ?item wdt:P6941 ?phi } UNION
  { ?item wdt:P10536 ?rspa }  UNION 
  { ?item wdt:P3576 ?tlg } UNION
  { ?item wdt:P7042 ?tll } UNION
  { ?item wdt:P11252 ?tmauthor }
  OPTIONAL { ?item wdt:P7908 ?clavisclavium }
  OPTIONAL { ?item wdt:P7935 ?corpuscorporum }
  OPTIONAL { ?item wdt:P7038 ?dco }
  OPTIONAL { ?item wdt:P8122 ?dll }
  OPTIONAL { ?item wdt:P7041 ?perseus }
# OPTIONAL { ?item wdt:P214 ?viaf } UNION
  
}

GROUP BY ?item ?itemLabel

Try it!

Works of antiquity

# Works of antiquity and slightly beyond
SELECT DISTINCT ?item ?itemLabel
  (GROUP_CONCAT(DISTINCT ?bekker; separator=", ") as ?Bekker)
  (GROUP_CONCAT(DISTINCT ?bhg; separator=", ") as ?BHG)
  (GROUP_CONCAT(DISTINCT ?bhl; separator=", ") as ?BHL)
  (GROUP_CONCAT(DISTINCT ?chap; separator=", ") as ?CHAP)
  (GROUP_CONCAT(DISTINCT ?cpg; separator=", ") as ?CPG)
  (GROUP_CONCAT(DISTINCT ?cpl; separator=", ") as ?CPL)
  (GROUP_CONCAT(DISTINCT ?digiliblt; separator=", ") as ?Digiliblt)
  (GROUP_CONCAT(DISTINCT ?dll; separator=", ") as ?DLL)
  (GROUP_CONCAT(DISTINCT ?icl; separator=", ") as ?ICL)
  (GROUP_CONCAT(DISTINCT ?mqdq; separator=", ") as ?MQDQ)
  (GROUP_CONCAT(DISTINCT ?perry; separator=", ") as ?Perry)
  (GROUP_CONCAT(DISTINCT ?pinakes; separator=", ") as ?Pinakes)
  (GROUP_CONCAT(DISTINCT ?phi; separator=", ") as ?PHI)
  (GROUP_CONCAT(DISTINCT ?topos; separator=", ") as ?Topos)
  (GROUP_CONCAT(DISTINCT ?walther; separator=", ") as ?Waltger)
# (GROUP_CONCAT(DISTINCT ?viaf; separator=", ") as ?VIAF)

WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],la". }
  { ?item wdt:P2683 ?bekker } UNION
  { ?item wdt:P7987 ?bhg } UNION
  { ?item wdt:P7924 ?bhl } UNION
  { ?item wdt:P11861 ?chap } UNION
  { ?item wdt:P7988 ?cpg } UNION
  { ?item wdt:P7980 ?cpl } UNION
  { ?item wdt:P8310 ?digiliblt } UNION
  { ?item wdt:P10934 ?icl } UNION  
  { ?item wdt:P8312 ?mqdq } UNION
  { ?item wdt:P1852 ?perry } UNION
  { ?item wdt:P12200 ?pinakes } UNION
  { ?item wdt:P8311 ?phi } UNION
  { ?item wdt:P8070 ?topos } UNION
  { ?item wdt:P10973 ?walther }
  OPTIONAL { ?item wdt:P8123 ?dll }
# OPTIONAL { ?item wdt:P214 ?viaf } UNION
  
}

GROUP BY ?item ?itemLabel

Try it!

Ancient philosophers tree

Ancient philosophers tree, adapted from Alexander Doria's Ancient philosophers

Ancient philosophers tree

#defaultView:Graph
SELECT DISTINCT ?philosopher ?philosopherLabel ?rgb ?student ?studentLabel 
WHERE {
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.BFS";
    gas:in wd:Q913;
    gas:linkType wdt:P802;
    gas:traversalDirection "Undirected";
    gas:out ?philosopher ;
    gas:out1 ?depth ;
    gas:out2 ?student . 
  }
   ?philosopher wdt:P106 wd:Q4964182 . #restricts the query to students that ended up philosophers themselves
   ?philosopher wdt:P135 ?school .
        BIND (
        COALESCE(
          IF(?school = wd:Q193589, "FF1700", 1/0),     # platonism
          IF(?school = wd:Q194414, "33FF3B", 1/0),     # peripatetician
          IF(?school = wd:Q1126340, "BEFAFF", 1/0),    # pyrrhonism
          IF(?school = wd:Q179541, "C2CFFF", 1/0),     # epicurism
          IF(?school = wd:Q1395219, "134d83", 1/0),    # scepticism
          IF(?school = wd:Q48235, "57FFD2", 1/0),      # stoicism
          IF(?school = wd:Q1145454, "19A2A2", 1/0),    # megarism
          IF(?school = wd:Q750192, "F5FE66", 1/0),     # cyrenaism
          IF(?school = wd:Q485459, "D69A00", 1/0),     # cynism
          IF(?school = wd:Q1350056, "35A219", 1/0),    # eretrian school
          IF(?school = wd:Q191359, "976031", 1/0),     # pythagorism
          IF(?school = wd:Q214577, "913194", 1/0),     # eleatics
          IF(?school = wd:Q178540, "140714", 1/0),     # presocratics (same as pluralists)
          IF(?school = wd:Q1275113, "140714", 1/0),    # pluralists (same as presocratics
          IF(?school = wd:Q178668, "d8a31c", 1/0),     # atomists
          IF(?school = wd:Q3345153, "1c51d8", 1/0),    # New Academy
          "FFFFFF"
        ) AS ?rgb 
      )
  
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Participants +/−

Jahl de Vautban
Tolanor
JASHough
Jonathan Groß
Ahc84
Carbidfischer
Epìdosis
JBradyK
Joan Gené
DerMaxdorfer
Falten-Jura
DerHexer
Alexmar983
Demadrend
Liber008
Rybesh
ELexikon
Digitalphilologist

paregorios

Wikidata:WikiProject Antiquity

Authors of antiquity

Works of antiquity

Ancient philosophers tree

Navigation menu

Search