Wikidata:Synia:visualartist
Jump to navigation
Jump to search
Synia: Visual artist
[edit]PREFIX target: <http://www.wikidata.org/entity/Q827752>
SELECT
?description ?descriptionLabel ?descriptionUrl
?value ?valueLabel ?valueUrl ?valueDescription
?wikidata ?wikidataUrl
WHERE {
{
BIND(1 AS ?order)
BIND(wd:Q3391743 AS ?description)
BIND("#visualartist" AS ?descriptionUrl)
BIND(target: AS ?value)
BIND(CONCAT(SUBSTR(STR(target:), 32), " ↗") AS ?wikidata)
BIND(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(target:), 32)) AS ?wikidataUrl)
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,cz,da,de,fr,nb,nn,sv". }
}
ORDER BY ?order
Artworks
[edit]PREFIX target: <http://www.wikidata.org/entity/Q365068>
SELECT
?artwork ?artworkLabel
(CONCAT("#artwork/", SUBSTR(STR(?artwork), 32)) AS ?artworkUrl)
?artworkDescription
WHERE {
?artwork wdt:P170 target: .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en,cz,da,de,fr,sv". }
}
Images
[edit]#defaultView:ImageGrid
PREFIX target: <http://www.wikidata.org/entity/Q365068>
SELECT
?artwork ?artworkLabel
?image
WHERE {
?artwork wdt:P170 target: ;
wdt:P18 ?image
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Collections
[edit]PREFIX target: <http://www.wikidata.org/entity/Q365068>
SELECT
?artworks
?collection ?collectionLabel
(CONCAT("#gallery/", SUBSTR(STR(?collection), 32)) AS ?collectionUrl)
?collectionDescription
?example_artwork ?example_artworkLabel
(CONCAT("#artwork/", SUBSTR(STR(?example_artwork), 32)) AS ?example_artworkUrl)
WITH {
SELECT
(COUNT(?artwork) AS ?artworks)
?collection
(SAMPLE(?artwork) AS ?example_artwork)
WHERE {
?artwork wdt:P170 target: ;
wdt:P195 ?collection .
}
GROUP BY ?collection
} AS %collections
WHERE {
INCLUDE %collections
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en,cz,da,de,fr,sv". }
}
ORDER BY DESC(?artworks)
Exhibitions
[edit]PREFIX target: <http://www.wikidata.org/entity/Q454670>
SELECT
?artworks
?exhibition ?exhibitionLabel
(CONCAT("#exhibition/", SUBSTR(STR(?exhibition), 32)) AS ?exhibitionUrl)
?exhibitionDescription
?example_artwork ?example_artworkLabel
(CONCAT("#artwork/", SUBSTR(STR(?example_artwork), 32)) AS ?example_artworkUrl)
WITH {
SELECT
(COUNT(?artwork) AS ?artworks)
?exhibition
(SAMPLE(?artwork) AS ?example_artwork)
WHERE {
?artwork wdt:P170 target: ;
wdt:P608 ?exhibition .
}
GROUP BY ?exhibition
} AS %exhibitions
WHERE {
INCLUDE %exhibitions
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en,cz,da,de,fr,nb,nn,sv". }
}
ORDER BY DESC(?artworks)