Wikidata:Synia:scientificevent-index

Synia: Scientific events

Coming deadlines

SELECT
  ?date
  ?deadline ?deadlineLabel
  ?short_name
  ?event ?eventLabel (CONCAT("#scientificevent/", SUBSTR(STR(?event), 32)) AS ?eventUrl)
  ?location ?locationLabel (CONCAT("#location/", SUBSTR(STR(?location), 32)) AS ?locationUrl)
WITH {
  SELECT
    ?datetime ?deadline ?event
    (SAMPLE(?location_) AS ?location) 
    (SAMPLE(?short_name_) AS ?short_name)
  WHERE {
    ?event p:P793 ?key_event_statement . 
    ?key_event_statement ps:P793 ?deadline ; 
                         pq:P585 ?datetime . 
    ?deadline wdt:P279* wd:Q2404808 .
    
    # Subtract a day from now to get events on the now date
    FILTER (NOW() - "P1DT0H0M0.000S"^^xsd:duration < ?datetime)
    OPTIONAL { ?event wdt:P276 ?location_ }
    OPTIONAL { ?event wdt:P1813 ?short_name_ }
  }
  GROUP BY ?datetime ?deadline ?event
  ORDER BY(?datetime)
  LIMIT 200  
} AS %events
WHERE {
  INCLUDE %events
  
  BIND(xsd:date(?datetime) AS ?date)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY(?date)

Try it!

Number of participants

SELECT 
  ?participants

  ?event ?eventLabel
  (CONCAT("#scientificevent/", SUBSTR(STR(?event), 32)) AS ?eventUrl)
  ?eventDescription
WHERE {
  ?event wdt:P31 / wdt:P279* wd:Q52260246 ;
         wdt:P1132 ?participants .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?participants)
LIMIT 500

Try it!

Number of accepted contributions

SELECT 
  ?accepted

  ?track ?trackLabel

  ?event ?eventLabel
  (CONCAT("#scientificevent/", SUBSTR(STR(?event), 32)) AS ?eventUrl)
  ?eventDescription
WHERE {
  ?event wdt:P31 / wdt:P279* wd:Q52260246 ;
         p:P12649 ?accepted_statement .
  ?accepted_statement ps:P12649 ?accepted .
  OPTIONAL { ?accepted_statement pq:P518 ?track_ }
  BIND(COALESCE(?track_, "-") AS ?track)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?accepted)
LIMIT 500

Try it!

Acceptance rate

SELECT 
  ?acceptance_rate 
  ?track ?trackLabel
  ?event ?eventLabel
  (CONCAT("#scientificevent/", SUBSTR(STR(?event), 32)) AS ?eventUrl)
  ?eventDescription
WHERE {
  ?event wdt:P31 / wdt:P279* wd:Q52260246 ;
         p:P5822 ?acceptance_rate_statement .
  ?acceptance_rate_statement ps:P5822 ?acceptance_rate .
  OPTIONAL { ?acceptance_rate_statement pq:P518 ?track_ . }
  BIND(COALESCE(?track_, "-") AS ?track)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?acceptance_rate

Try it!