Wikidata:Synia:lexicalcategory
Jump to navigation
Jump to search
Synia: Lexical category
[edit]PREFIX target: <http://www.wikidata.org/entity/Q24905>
SELECT
?description ?descriptionLabel
("#lexicalcategory" AS ?descriptionUrl)
?value ?valueLabel
?wikidata ?wikidataUrl
?ordia ?ordiaUrl
WHERE {
BIND(1 AS ?order)
BIND(wd:Q82042 AS ?description)
BIND(target: AS ?value)
BIND(CONCAT(SUBSTR(STR(target:), 32), " ↗") AS ?wikidata)
BIND(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(target:), 32)) AS ?wikidataUrl)
BIND("Ordia ↗" AS ?ordia)
BIND(CONCAT("https://ordia.toolforge.org/lexical-category/", SUBSTR(STR(target:), 32)) AS ?ordiaUrl)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?order
Lexemes per language
[edit]PREFIX target: <http://www.wikidata.org/entity/Q1084>
# Count of number of lexemes used for a specified lexical category
# wrt. language
SELECT
?count
(CONCAT("#lexicalcategory/", SUBSTR(STR(target:), 32), "/language/", SUBSTR(STR(?language), 32)) AS ?countUrl)
# (CONCAT("#language/", SUBSTR(STR(?language), 32), "/lexicalcategory/", SUBSTR(STR(target:), 32)) AS ?countUrl)
?language ?languageLabel
(CONCAT("#language/", SUBSTR(STR(?language), 32)) AS ?languageUrl)
?languageDescription
{
{
SELECT (COUNT(*) AS ?count) ?language {
[] wikibase:lexicalCategory target: ;
dct:language ?language .
}
GROUP BY ?language
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?count)
Newest lexemes in lexical category
[edit]PREFIX target: <http://www.wikidata.org/entity/Q24905>
SELECT
(xsd:date(?earliest_publication_datetime) AS ?publication_date)
?lexeme
(?lemma AS ?lexemeLabel)
(CONCAT("#lexeme/", SUBSTR(STR(?lexeme), 32)) AS ?lexemeUrl)
?language ?languageLabel
(CONCAT("#language/", SUBSTR(STR(?language), 32)) AS ?languageUrl)
WITH {
SELECT
(MIN(?publication_datetime) AS ?earliest_publication_datetime)
?lexeme
WHERE {
?lexeme dct:language [] ;
wikibase:lexicalCategory target: ;
(wdt:P5323 / wdt:P577)| (p:P5323 / pq:P577) ?publication_datetime .
}
GROUP BY ?lexeme
ORDER BY DESC(?earliest_publication_datetime)
LIMIT 100
} AS %lexemes
WHERE {
INCLUDE %lexemes
?lexeme dct:language ?language ;
wikibase:lemma ?lemma .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?publication_date)