Wikidata:Synia:lexeme-index

Synia: lexemes

Newest words

SELECT 
  (xsd:date(?earliest_publication_datetime) AS ?publication_date)

  ?lexeme 
  (?lemma AS ?lexemeLabel)
  (CONCAT("#lexeme/", SUBSTR(STR(?lexeme), 32)) AS ?lexemeUrl)

  ?lexical_category ?lexical_categoryLabel
  (CONCAT("#lexicalcategory/", SUBSTR(STR(?lexical_category), 32)) AS ?lexical_categoryUrl)

  ?language ?languageLabel
  (CONCAT("#language/", SUBSTR(STR(?language), 32)) AS ?languageUrl)
WITH {
  SELECT
    (MIN(?publication_datetime) AS ?earliest_publication_datetime)
    ?lexeme
  WHERE {
    ?lexeme dct:language [] ;
            (wdt:P5323 / wdt:P577) | (p:P5323 / pq:P577) ?publication_datetime .
  }
  GROUP BY ?lexeme
  ORDER BY DESC(?earliest_publication_datetime)
  LIMIT 100
} AS %lexemes
WHERE {
  INCLUDE %lexemes
  ?lexeme dct:language ?language ;
          wikibase:lexicalCategory ?lexical_category ;
          wikibase:lemma ?lemma .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }        
}
ORDER BY DESC(?publication_date)

Try it!

Lexeme creators

SELECT
  ?count
  ?creator ?creatorLabel
  ?lemmas
WITH {
  SELECT
    (COUNT(?lexeme) AS ?count)
    ?creator 
    (GROUP_CONCAT(?lemma) AS ?lemmas)
  WHERE {
    ?lexeme wikibase:lemma ?lemma ;
            wdt:P170 ?creator .
  }
  GROUP BY ?creator
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?count)

Try it!

Identifier statistics

SELECT
  ?count
  ?identifier ?identifierLabel ?identifierDescription
WITH {
  SELECT 
    (COUNT(*) AS ?count)
    ?property 
  WHERE {
    ?property ^wikibase:directClaim / wdt:P31 wd:Q56216056 .
    [] ?property [] .
  }
  GROUP BY ?property
} AS %properties
WHERE {
  INCLUDE %properties
  ?identifier wikibase:directClaim ?property .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?count)

Try it!