Wikidata:Synia:language-lexemedescriptor-index

Synia: lexeme descriptors for language

PREFIX target: <http://www.wikidata.org/entity/Q9035>

SELECT DISTINCT
  ?description ?descriptionLabel ?descriptionUrl
  ?value ?valueLabel ?valueUrl
  ?wikidata ?wikidataUrl
  ?ordia ?ordiaUrl
  ?scholia ?scholiaUrl
WHERE {
  {
    BIND(1 AS ?order)
    BIND(wd:Q34770 AS ?description)
    BIND("#language/" AS ?descriptionUrl)
    
    BIND(target: AS ?value)
    BIND(CONCAT("#language/", SUBSTR(STR(target:), 32)) AS ?valueUrl)

    BIND(CONCAT(SUBSTR(STR(target:), 32), "&nbsp;↗") AS ?wikidata)
    BIND(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(target:), 32)) AS ?wikidataUrl)

    BIND("Ordia&nbsp;↗" AS ?ordia)
    BIND(CONCAT("https://ordia.toolforge.org/language/", SUBSTR(STR(target:), 32)) AS ?ordiaUrl)

    BIND("Scholia&nbsp;↗" AS ?scholia)
    BIND(CONCAT("https://scholia.toolforge.org/language/", SUBSTR(STR(target:), 32)) AS ?scholiaUrl)
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 
ORDER BY ?order

Try it!

Lexeme descriptors

PREFIX target: <http://www.wikidata.org/entity/Q9035> 

SELECT 
  ?lexemes

  ?descriptor ?descriptorLabel
  (CONCAT("#lexemedescriptor/", SUBSTR(STR(?descriptor), 32)) AS ?descriptorUrl)
  ?descriptorDescription

  ?example_lexeme
  (SUBSTR(STR(?example_lexeme), 32) AS ?example_lexemeLabel)
  (CONCAT("#lexeme/", SUBSTR(STR(?example_lexeme), 32)) AS ?example_lexemeUrl)
WITH {
  SELECT 
    (COUNT(?lexeme) AS ?lexemes)
    ?descriptor
    (SAMPLE(?lexeme) AS ?example_lexeme)
  WHERE {
    ?lexeme wdt:P1343 ?descriptor ;
            dct:language target: .
  }
  GROUP BY ?descriptor
} AS %descriptors
WHERE{
  INCLUDE %descriptors
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?lexemes)

Try it!

Most described lexemes for language

PREFIX target: <http://www.wikidata.org/entity/Q9035>

SELECT
  ?number_of_descriptors

  ?lexeme (?lemma AS ?lexemeLabel)
  (CONCAT("#lexeme/", SUBSTR(STR(?lexeme), 32)) AS ?lexemeUrl)

  ?example_descriptor ?example_descriptorLabel
  (CONCAT("#lexemedescriptor/", SUBSTR(STR(?example_descriptor), 32)) AS ?example_descriptorUrl)
   
WITH {
  SELECT 
    ?lexeme
    (COUNT(?descriptor) AS ?number_of_descriptors)
    (SAMPLE(?descriptor) AS ?example_descriptor)
  WHERE {
    ?lexeme dct:language target: ;
            wdt:P1343 ?descriptor .
  }
  GROUP BY ?lexeme
  ORDER BY DESC(?number_of_descriptors)
  LIMIT 200
} AS %result
WHERE {
  INCLUDE %result
  ?lexeme wikibase:lemma ?lemma
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?number_of_descriptors)

Try it!

Authors describing lexeme in the language

PREFIX target: <http://www.wikidata.org/entity/Q9035> 

SELECT 
  ?lexemes

  ?author ?authorLabel
  (CONCAT("#author/", SUBSTR(STR(?author), 32)) AS ?authorUrl)
  ?authorDescription

  ?example_lexeme
  (SUBSTR(STR(?example_lexeme), 32) AS ?example_lexemeLabel)
  (CONCAT("#lexeme/", SUBSTR(STR(?example_lexeme), 32)) AS ?example_lexemeUrl)
WITH {
  SELECT 
    (COUNT(?lexeme) AS ?lexemes)
    ?author
    (SAMPLE(?lexeme) AS ?example_lexeme)
  WHERE {
    ?lexeme wdt:P1343 ?descriptor ;
            dct:language target: .
    ?descriptor wdt:P50 ?author
  }
  GROUP BY ?author
} AS %descriptors
WHERE{
  INCLUDE %descriptors
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?lexemes)

Try it!