Wikidata:Synia:depictedfeature

Synia: Depicted feature

PREFIX target: <http://www.wikidata.org/entity/Q1144593>

SELECT
  ?depicted_feature ?depicted_featureLabel
  ?depicted_featureDescription

  ("Wikidata&nbsp;↗" AS ?wikidata)
  (CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(target:), 32)) AS ?wikidataUrl)
WHERE {
  BIND(target: AS ?depicted_feature)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Images

#defaultView:ImageGrid

PREFIX target: <http://www.wikidata.org/entity/Q1144593>

SELECT
  ?artwork ?artworkLabel
  ?image
WHERE {
  ?artwork p:P180 ?depicted_statement ;
           wdt:P18 ?image .
  ?depicted_statement pq:P1354 target: .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Depicted

PREFIX target: <http://www.wikidata.org/entity/Q1144593>

SELECT
  ?artworks

  ?depicted ?depictedLabel
  (CONCAT("#depicted/", SUBSTR(STR(?depicted), 32)) AS ?depictedUrl)

  ?example_artwork ?example_artworkLabel
  (CONCAT("#artwork/", SUBSTR(STR(?example_artwork), 32)) AS ?example_artworkUrl)
WITH {
  SELECT 
    (COUNT(?artwork) AS ?artworks)
    ?depicted
    (SAMPLE(?artwork) AS ?example_artwork)
  WHERE {
    ?artwork p:P180 ?depicted_statement .
    ?depicted_statement ps:P180 ?depicted ;
                        pq:P1354 target: .
  }
  GROUP BY ?depicted
} AS %depicteds
WHERE {
  INCLUDE %depicteds
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?artworks)

Try it!