Wikidata:Synia:cor-index
Jump to navigation
Jump to search
Synia: Det Centrale Ordregister (COR)
[edit]Lexical categories
[edit]#defaultView:BubbleChart
SELECT
?lexical_category ?lexical_categoryLabel
?lexemes
WITH {
SELECT
(COUNT(?lexeme) AS ?lexemes)
?lexical_category
WHERE {
?lexeme wikibase:lexicalCategory ?lexical_category ;
wdt:P10831 ?cor_lemma .
}
GROUP BY ?lexical_category
} AS %lexical_categories
WHERE {
INCLUDE %lexical_categories
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?lexemes)
SELECT
?lexemes
(CONCAT("#lexicalcategory/", SUBSTR(STR(?lexical_category), 32), "/cor") AS ?lexemesUrl)
?lexical_category ?lexical_categoryLabel
(CONCAT("#lexicalcategory/", SUBSTR(STR(?lexical_category), 32)) AS ?lexical_categoryUrl)
?lexical_categoryDescription
WITH {
SELECT
(COUNT(?lexeme) AS ?lexemes)
?lexical_category
WHERE {
?lexeme wikibase:lexicalCategory ?lexical_category ;
wdt:P10831 ?cor_lemma .
}
GROUP BY ?lexical_category
} AS %lexical_categories
WHERE {
INCLUDE %lexical_categories
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?lexemes)
Lexeme senses
[edit]SELECT
?sense
(SUBSTR(STR(?sense), 32) AS ?senseLabel)
?gloss
?lexeme ?lexemeLabel
(CONCAT("#lexeme/", SUBSTR(STR(?lexeme), 32)) AS ?lexemeUrl)
?lexical_category ?lexical_categoryLabel
?corsem
(CONCAT(?corsem, " ↗") AS ?corsemLabel)
(CONCAT("https://ordregister.dk/id/", ?corsem) AS ?corsemUrl)
WHERE {
?lexeme wikibase:lemma ?lexemeLabel ;
wikibase:lexicalCategory ?lexical_category;
ontolex:sense ?sense .
?sense wdt:P12202 ?corsem .
OPTIONAL {
?sense skos:definition ?gloss .
FILTER (LANG(?gloss) = "da")
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Sense with explicitly specified no COR.SEM
[edit]SELECT
?sense
(SUBSTR(STR(?sense), 32) AS ?senseLabel)
?gloss
?lexeme (?lemma AS ?lexemeLabel)
(CONCAT("#lexeme/", SUBSTR(STR(?lexeme), 32)) AS ?lexemeUrl)
?lexical_category ?lexical_categoryLabel
(CONCAT("#lexicalcategory/", SUBSTR(STR(?lexical_category), 32)) AS ?lexical_categoryUrl)
# ?lexical_categoryDescription
(?lexeme AS ?wikidata)
(CONCAT(SUBSTR(STR(?lexeme), 32), " ↗") AS ?wikidataLabel)
(CONCAT("https://www.wikidata.org/wiki/Lexeme:", SUBSTR(STR(?lexeme), 32)) AS ?wikidataUrl)
(?lexeme AS ?ordia)
("Ordia ↗" AS ?ordiaLabel)
(CONCAT("https://ordia.toolforge.org/", SUBSTR(STR(?lexeme), 32)) AS ?ordiaUrl)
WHERE {
?lexeme wikibase:lexicalCategory ?lexical_category ;
wikibase:lemma ?lemma ;
ontolex:sense ?sense .
?sense rdf:type wdno:P12202 .
OPTIONAL {
?sense skos:definition ?gloss .
FILTER (LANG(?gloss) = "da")
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}