Wikidata:Synia:collection
Jump to navigation
Jump to search
Synia: Collection
[edit]PREFIX target: <http://www.wikidata.org/entity/Q648166>
SELECT
?description ?descriptionLabel ?descriptionUrl
?value ?valueLabel ?valueUrl ?valueDescription
?wikidata ?wikidataUrl
WHERE {
{
BIND(1 AS ?order)
BIND(wd:Q2668072 AS ?description)
BIND(target: AS ?value)
BIND("Wikidata ↗" AS ?wikidata)
BIND(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(?value), 32)) AS ?wikidataUrl)
}
UNION
{
BIND(2 AS ?order)
BIND(wd:Q6256 AS ?description)
BIND("#country/" AS ?descriptionUrl)
target: wdt:P17 ?value .
BIND(CONCAT("#country/", SUBSTR(STR(?value), 32)) AS ?valueUrl)
BIND("Wikidata ↗" AS ?wikidata)
BIND(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(?value), 32)) AS ?wikidataUrl)
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?order
Items with pictures
[edit]#defaultView:ImageGrid
PREFIX target: <http://www.wikidata.org/entity/Q2982867>
SELECT
?artwork ?artworkLabel
?image
WHERE {
?artwork wdt:P195 target: ;
wdt:P18 ?image .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Publications about items
[edit]PREFIX target: <http://www.wikidata.org/entity/Q648166>
SELECT
?publication_date
?publication ?publicationLabel
?publicationDescription
?item ?itemLabel
WHERE {
?item wdt:P195 target: .
?publication wdt:P921| ^wdt:P1343 ?item ;
wdt:P577 ?publication_datetime .
BIND(xsd:date(?publication_datetime) AS ?publication_date)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?publication_date)