Wikidata:Synia:antonym-index

Synia: Antonyms

Senses with antonyms by language

SELECT
  ?number_of_senses

  ?language ?languageLabel
  (CONCAT("#language/", SUBSTR(STR(?language), 32)) AS ?languageUrl)

  ?example_lexeme ?example_lexemeLabel
  (CONCAT("#lexeme/", SUBSTR(STR(?example_lexeme), 32)) AS ?example_lexemeUrl)

WITH {
  SELECT
    (COUNT(DISTINCT ?sense) AS ?number_of_senses)
    ?language
    (SAMPLE(?sense) as ?example_sense)
  WHERE {
    [] dct:language ?language ;
       ontolex:sense ?sense .
    ?sense wdt:P5974 [] .
  }
  GROUP BY ?language
} AS %result
WHERE {
  INCLUDE %result
  ?example_lexeme ontolex:sense ?example_sense .
  ?example_lexeme wikibase:lemma ?example_lexemeLabel .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?number_of_senses)

Try it!

Sense with antonyms by lexical category

SELECT
  ?number_of_senses
  (CONCAT("#lexicalcategory/", SUBSTR(STR(?lexical_category), 32), "/antonym") AS ?number_of_sensesUrl)

  ?lexical_category ?lexical_categoryLabel
  (CONCAT("#lexicalcategory/", SUBSTR(STR(?lexical_category), 32)) AS ?lexical_categoryUrl)

  ?example_lexeme ?example_lexemeLabel
  (CONCAT("#lexeme/", SUBSTR(STR(?example_lexeme), 32)) AS ?example_lexemeUrl)
WITH {
  SELECT
    (COUNT(DISTINCT ?sense) AS ?number_of_senses)
    ?lexical_category
    (SAMPLE(?sense) as ?example_sense)
  WHERE {
    [] wikibase:lexicalCategory ?lexical_category ;
       ontolex:sense ?sense .
    ?sense wdt:P5974 [] .
  }
  GROUP BY ?lexical_category
} AS %result
WHERE {
  INCLUDE %result
  ?example_lexeme ontolex:sense ?example_sense .
  ?example_lexeme wikibase:lemma ?example_lexemeLabel .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?number_of_senses)

Try it!