Wikidata:ScienceSource project/Main subject queries
Jump to navigation
Jump to search
Try it!
Try it!
Try it!
Try it!
Try it!
#Main subject is an academic journal
SELECT ?item ?subjectLabel
WHERE {?item wdt:P921 ?subject.
?subject wdt:P31 wd:Q737498.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
#Main subject is a protein without P486 statement
SELECT DISTINCT ?subjectLabel
WHERE {?item wdt:P921 ?subject.
?subject wdt:P31 wd:Q8054.
MINUS {?subject wdt:P486 [ ]}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 50
#Article items, reviews with license, lacking main subject
SELECT ?item ?itemLabel
WHERE {?item wdt:P31 wd:Q7318358;
wdt:P275 [ ].
MINUS{?item wdt:P921 [ ]}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
#Article items, reviews with license, lacking main subject, ordered by date
SELECT ?item ?itemLabel ?date
WHERE {?item wdt:P31 wd:Q7318358;
wdt:P577 ?date;
wdt:P275 [ ].
MINUS{?item wdt:P921 [ ]}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?date)
#Locating particular P921 statements referenced to PubMed
SELECT DISTINCT ?statement
WHERE {
?reference pr:P248 wd:Q180686.
?statement prov:wasDerivedFrom ?reference.
?statement ps:P921 wd:Q15326.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}