Wikidata:Open Science Fellows Program

From Wikidata
Jump to navigation Jump to search

This page summarizes efforts to use Wikidata in projects and organization of the Open Science Fellows Program (Q42092479) View with Reasonator View with SQID.

About the fellowship[edit]

List of fellows[edit]

This SPARQL query lists all fellows as included in Wikidata.

SELECT
  ?year ?fellow ?fellowLabel ?fellowDescription ?image ?orcid ?twitter ?github
WHERE {
  ?fellow p:P166 ?award_statement .  
  ?award_statement ps:P166 wd:Q42092479 .
  OPTIONAL {
    ?award_statement pq:P580 ?time 
    BIND(YEAR(?time) AS ?year)
  }
  OPTIONAL { ?fellow wdt:P18 ?image }
  OPTIONAL {
    ?fellow wdt:P496 ?orcid_id
    BIND(URI(CONCAT("https://orcid.org/",?orcid_id)) AS ?orcid)
  } 
  OPTIONAL {
    ?fellow wdt:P2037 ?github_name
    BIND(URI(CONCAT("https://github.com/",?github_name)) AS ?github)
  } 
  OPTIONAL {
    ?fellow wdt:P2002 ?twitter_name
    BIND(URI(CONCAT("https://twitter.com/",?twitter_name)) AS ?twitter)            
  }
  # TODO: GitLab etc.?   
  # TODO: Wikimedia-Account-Name
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,no,ru,sv,zh" . }
}
ORDER BY DESC(?year)

Try it!

List of mentors[edit]

SELECT
  ?mentor ?mentorLabel ?from ?until ?image ?orcid ?wikimedia ?twitter
WHERE {
  ?mentor p:P39 ?position_statement .  
  ?position_statement ps:P39 wd:Q967647 .    # mentoring
  ?position_statement pq:P642 wd:Q42092479 . # Open Science Fellows Program
  
  ?position_statement pq:P580 ?fromDate .
  BIND(YEAR(?fromDate) AS ?from)
  
  OPTIONAL {
    ?position_statement pq:P582 ?untilDate .
    BIND(YEAR(?untilDate) AS ?until)
  }  
  OPTIONAL { ?mentor wdt:P18 ?image }
  OPTIONAL {
    ?mentor wdt:P496 ?orcid_id
    BIND(URI(CONCAT("https://orcid.org/",?orcid_id)) AS ?orcid)
  } 
  OPTIONAL {
    ?mentor wdt:P2002 ?twitter_name
    BIND(URI(CONCAT("https://twitter.com/",?twitter_name)) AS ?twitter)            
  }
  OPTIONAL {
    ?mentor wdt:P4174 ?wikimedia_name
    BIND(URI(CONCAT("https://www.wikidata.org/w/index.php?title=Special%3ACentralAuth&target=",?wikimedia_name)) AS ?wikimedia)
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,no,ru,sv,zh" . }
} ORDER BY DESC (?year)

Try it!

Projects[edit]

Some fellowship projects have a wiki page of their own with more information about connection of the project with Wikidata.

2018/2017[edit]

  • ...

2017/2018[edit]