Wikidata:Gruppo Wikidata per Musei, Archivi e Biblioteche/Edit16

From Wikidata
Jump to navigation Jump to search

"Il Censimento nazionale delle edizioni italiane del XVI secolo (EDIT16) ha lo scopo di documentare la produzione a stampa del XVI secolo. La base dati descrive edizioni stampate tra il 1501 e il 1600 in Italia, in qualsiasi lingua, e all'estero in lingua italiana. Contiene inoltre voci di autorità relative a nomi personali e collettivi, titoli uniformi, editori, marche tipografiche e luoghi di stampa, e due archivi riservati alle dediche e alle fonti bibliografiche."

Obiettivi[edit]

Il progetto mira ad avere in Wikidata tutti i tipografi e le tipografe presenti nel Censimento nazionale delle edizioni italiane del XVI secolo. Il sito del censimento raccoglie 2677 identificativi di tipografi/editori (Dati test Api ICCU aprile 2023), alcuni identificativi corrispondono a più persone fisiche (es. società ed eredi).

All'inizio del progetto (marzo 2023) esistono in wikidata 140 elementi con EDIT16 catalogue printer ID (P5493).

Al 23 giugno 2023 esistono in wikidata 500 elementi con EDIT16 catalogue printer ID (P5493).

Modelli di elementi[edit]

Singolo tipografo
Società/gruppi di tipografi
Buone pratiche
  • Aggiungere sempre tutte le varianti del nome nell'Alias
  • Aggiungere il nome latino nell'Etichetta in latino
Proprietà specifiche per i tipografi
Proprietà specifiche per le società e imprese famigliari

Utenti[edit]

Query[edit]

#title:Tipograf* con Id Edit16
SELECT ?edit16 ?item ?itemLabel ?itemDescription # ?luogolav ?inizioatt ?fineatt
WHERE 
{
  ?item wdt:P5493 ?edit16. 
  # Optional {?item wdt:P937 ?luogolav}
  # Optional {?item wdt:P2031 ?inizioatt}
  # Optional {?item wdt:P2032 ?fineatt}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". } 
  
}

ORDER BY ASC (xsd:integer(?edit16))
Tipograf* con Id Edit16

Controllo[edit]

#title:Tipograf* con Id SBN ma senza Id Edit16
SELECT DISTINCT ?item ?itemLabel ?itemdesc (URI(CONCAT("https://opac.sbn.it/risultati-autori/-/opac-autori/detail/",?sbnid,"?core=autoriall"))as ?sbnurl) #?datainizio ?datafine
WHERE 
{ ?item wdt:P396 ?sbnid; wdt:P106 ?activity; schema:description ?itemdesc.
        {?item wdt:P2031 ?datainizio} UNION {?item wdt:P569 ?datainizio}
        {?item wdt:P2032 ?datafine} UNION {?item wdt:P570 ?datafine}
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }

      FILTER ("1620-01-01"^^xsd:dateTime > ?datafine) 
      FILTER ("1480-01-01"^^xsd:dateTime < ?datainizio)

        FILTER((LANG(?itemdesc)) = "it")
        FILTER(CONTAINS(STR(?itemdesc), "italiano"))

  MINUS {{ ?item wdt:P5493 ?edit16} UNION {?item wdt:P5492 ?edit16. }}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". } 
}
Tipograf* con Id SBN ma senza Id Edit16 
#title:Tipograf* con Id Cerl ma senza Id Edit16
SELECT DISTINCT ?item ?itemLabel ?itemdesc (URI(CONCAT("https://data.cerl.org/thesaurus/",?cerlid))as ?cerlurl) #?datainizio ?datafine
WHERE 
{ ?item wdt:P1871 ?cerlid; wdt:P106 ?activity; schema:description ?itemdesc.
        {?item wdt:P2031 ?datainizio} UNION {?item wdt:P569 ?datainizio}
        {?item wdt:P2032 ?datafine} UNION {?item wdt:P570 ?datafine}
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }

      FILTER ("1620-01-01"^^xsd:dateTime > ?datafine) 
      FILTER ("1480-01-01"^^xsd:dateTime < ?datainizio)

        FILTER((LANG(?itemdesc)) = "it")
        FILTER(CONTAINS(STR(?itemdesc), "italiano"))

  MINUS {{ ?item wdt:P5493 ?edit16} UNION {?item wdt:P5492 ?edit16. }}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it". } 
}
Tipograf* con Id Cerl ma senza Id Edit16 
#title:Completamento elementi tipograf* con Id Edit16
SELECT ?type (COUNT(DISTINCT ?item) AS ?count) WHERE {
  hint:Query hint:optimizer "Runtime".
  ?item wdt:P5493 ?edit16. 
  OPTIONAL { ?item wdt:P106 ?occup . }
  OPTIONAL { ?item wdt:P2031 ?inizio }
  OPTIONAL { ?item wdt:P2032 ?fine . }
  OPTIONAL { ?item wdt:P937  ?luogo . }
  BIND(IF(BOUND(?occup) && BOUND(?inizio) && BOUND(?fine) && BOUND(?luogo),"all",
       IF(BOUND(?occup) && BOUND(?inizio)&& BOUND(?fine),"senza luogo",
       IF(BOUND(?occup) && BOUND(?inizio)&& BOUND(?luogo),"senza fine",
       IF(BOUND(?occup) && BOUND(?fine)&& BOUND(?luogo),"senza inizio",   
       IF(BOUND(?inizio) && BOUND(?fine)&& BOUND(?luogo),"senza occup",     
       IF(BOUND(?occup) && BOUND(?fine),"senza luogo e inizio",
       IF(BOUND(?inizio) && BOUND(?luogo),"senza occup e fine",
       IF(BOUND(?occup) && BOUND(?inizio),"senza fine e luogo",
       IF(BOUND(?occup) && BOUND(?luogo),"senza fine e inizio",
       IF(BOUND(?inizio) && BOUND(?fine),"senza occup e luogo",   
       IF(BOUND(?luogo) && BOUND(?fine),"senza occup e inizio",    
       IF(BOUND(?occup),"solo occup",
       IF(BOUND(?inizio),"solo inizio",
       IF(BOUND(?fine),"solo fine",
       IF(BOUND(?luogo),"solo luogo",
       "none"))))))))))))))) AS ?type)
}
GROUP BY ?type
ORDER BY DESC (?count)
Completamento elementi tipograf* con Id Edit16 
#title:tipografi con dbi ma pochi statements/identifiers
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?edit16 ?number
WHERE {
  ?item wdt:P31 wd:Q5; wdt:P5493 ?edit16; wikibase:identifiers ?number . # wikibase:statements
  FILTER(?number < 10)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
tipografi con dbi ma pochi statements/identifiers

Progetti correlati[edit]

Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata:Gruppo_Wikidata_per_Musei,_Archivi_e_Biblioteche/Edit16&oldid=2057516349"