User talk:Thekidpossum

Requête plus propre des lauréats de l'Acfas

SELECT ?item ?itemLabel ?genderLabel ?itemDescription ?awardLabel (YEAR(?date) AS ?year) {
  VALUES ?award { wd:Q3404296 wd:Q2365303 wd:Q28869834 wd:Q3404842 wd:Q3404891 wd:Q3404993 
                  wd:Q3405049 wd:Q24928963 wd:Q3405011 wd:Q21658579 wd:Q3405354 } . #award: 10 Acfas awards
  ?item wdt:P31 wd:Q5;
        wdt:P21 ?gender;
        p:P166 ?awardStatement.
  ?awardStatement ps:P166 ?award.
  OPTIONAL { ?awardStatement pq:P585 ?date. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?item ?itemLabel ?genderLabel ?itemDescription ?award ?awardLabel ?date
ORDER BY ?genderLabel ?awardLabel

Try it!

Requête des lauréats de l'Acfas incluant les articles Wikipédia

SELECT ?item ?itemLabel ?genderLabel ?itemDescription ?awardLabel (YEAR(?date) AS ?year) (GROUP_CONCAT(DISTINCT ?language; separator=", ") AS ?languages) {
  VALUES ?award { wd:Q3404296 wd:Q2365303 wd:Q28869834 wd:Q3404842 wd:Q3404891 wd:Q3404993 
                  wd:Q3405049 wd:Q24928963 wd:Q3405011 wd:Q21658579 wd:Q3405354 } . #award: 10 Acfas awards
  ?item wdt:P31 wd:Q5;
        wdt:P21 ?gender;
        p:P166 ?awardStatement.
  ?awardStatement ps:P166 ?award.
  OPTIONAL { ?awardStatement pq:P585 ?date. }
  OPTIONAL {
    ?article a schema:Article;
               schema:about ?item;
               schema:inLanguage ?language.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?item ?itemLabel ?genderLabel ?itemDescription ?award ?awardLabel ?date
ORDER BY ?genderLabel ?awardLabel

Try it!

Wikidata training

Cliquer ici