User : YULdigitalpreservation/SPARQL2

#Drivers
SELECT ?item ?itemLabel WHERE {
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q1033951.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

News

Software that has been connected to NYT topic ID

The following query uses these:

Items: software (Q7397)

Properties: instance of (P31)  

, New York Times topic ID (P3221)  

SELECT DISTINCT ?item ?itemLabel ?value 
{
    ?item wdt:P31/wdt:P279* wd:Q7397.
	?item wdt:P3221 ?value .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Fonts

Instances of typeface

The following query uses these:

Items: typeface (Q17451)

Properties: subclass of (P279)  

SELECT ?item ?itemLabel 
WHERE {
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q17451.
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Graph of subclasses of typeface

The following query uses these:

Items: typeface (Q17451)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q17451 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

File Systems

Return a list of file systems and subclasses of file system

The following query uses these:

Items: file system (Q174989)

Properties: subclass of (P279)  

SELECT ?item ?itemLabel 
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q174989.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a list of file systems with information about the developer and the publication date, if available

The following query uses these:

Items: file system (Q174989)

Properties: subclass of (P279)  

, developer (P178)  

SELECT ?item ?itemLabel ?devLabel ?date
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q174989.
  
  OPTIONAL {?item wdt:P178 ?dev}
  OPTIONAL {?item wdt:P577 ?date} 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a list of file systems, their developers, publication date, and operating system if available

The following query uses these:

Items: file system (Q174989)

Properties: subclass of (P279)  

, developer (P178)  

, operating system (P306)  

SELECT DISTINCT ?item ?itemLabel ?devLabel ?date ?osLabel
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q174989.
  
  OPTIONAL {?item wdt:P178 ?dev}
  OPTIONAL {?item wdt:P577 ?date} 
  OPTIONAL {?item wdt:P306 ?os}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File systems developed by Apple

The following query uses these:

Items: file system (Q174989)   , Apple (Q312)

Properties: subclass of (P279)  

, developer (P178)  

, operating system (P306)  

SELECT ?item ?itemLabel ?osLabel
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q174989.
  ?item wdt:P178 wd:Q312.
  OPTIONAL {?item wdt:P306 ?os}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Bubble chart of developers by number of file systems created

The following query uses these:

Items: file system (Q174989)

Properties: subclass of (P279)   , developer (P178)   , instance of (P31)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?developer ?developerLabel (COUNT(?software) AS ?count) WHERE {
  ?software (p:P31/ps:P31/wdt:P279*) wd:Q174989.
  ?software wdt:P178 ?developer.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?developer ?developerLabel
ORDER BY DESC(?count)

Programming Languages

Languages influenced by Lisp

The following query uses these:

Items: Lisp (Q132874)

Properties: influenced by (P737)  

SELECT DISTINCT ?lang  ?langLabel 

WHERE {
  ?lang wdt:P737 wd:Q132874 .
  
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Programming Languages created before 1970

The following query uses these:

Items: programming language (Q9143)

Properties: instance of (P31)  

, inception (P571)  

#defaultView:Timeline
SELECT ?lang ?langLabel ?time
{
  ?lang wdt:P31 wd:Q9143 .
  ?lang wdt:P571 ?time .
FILTER((?time) < "1970-01-01"^^xsd:dateTime)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Programming Languages created between 2007-2017

The following query uses these:

Items: programming language (Q9143)

Properties: instance of (P31)  

, inception (P571)  

#defaultView:Timeline
SELECT ?lang ?langLabel ?time
{
  ?lang wdt:P31 wd:Q9143 .
  ?lang wdt:P571 ?time .
FILTER((?time) > "2007-01-01"^^xsd:dateTime)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Subclasses of Programming Language

The following query uses these:

Items: programming language (Q9143)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?class ?classabel ?subclassOf WHERE {
  ?class wdt:P279* wd:Q9143.
  OPTIONAL { ?class wdt:P279 ?subclassOf. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?classLabel

Return a list of software written in the Fortran programming language and their uses

The following query uses these:

Items: Fortran (Q83303)

Properties: programmed in (P277)  

, has use (P366)  

SELECT ?software ?softwareLabel ?useLabel
WHERE 
{
  ?software wdt:P277 wd:Q83303.
   ?software wdt:P366 ?use
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a list of software written in Perl along with the Wikidata class for the software

The following query uses these:

Items: Perl (Q42478)

Properties: programmed in (P277)  

SELECT ?soft ?softLabel ?classLabel WHERE {
 
  ?soft wdt:P277 wd:Q42478.
  ?soft wdt:P31 ?class .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of software written in Go along with the Wikidata class for the software

The following query uses these:

Items: Go (Q37227)

Properties: programmed in (P277)  

SELECT ?soft ?softLabel ?classLabel WHERE {
  ?soft wdt:P277 wd:Q37227.
  ?soft wdt:P31 ?class.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of software written in PHP along with the use of the software

The following query uses these:

Items: PHP (Q59)

Properties: programmed in (P277)  

, has use (P366)  

SELECT ?software ?softwareLabel ?useLabel  WHERE {
  ?software wdt:P277 wd:Q59.
  ?software wdt:P366 ?use.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Software written in Ruby along with use and logo image

The following query uses these:

Items: Ruby (Q161053)

Properties: programmed in (P277)  

, has use (P366)  

SELECT DISTINCT ?software ?softwareLabel ?image ?useLabel  WHERE {
  ?software wdt:P277 wd:Q161053.
  OPTIONAL { ?software wdt:P366 ?use. }
  OPTIONAL {?software wdt:P154 ?image.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Bubble chart of women who have developed programming languages

The following query uses these:

Items: programming language (Q9143)   , human (Q5)   , female (Q6581072)

Properties: subclass of (P279)  

, developer (P178)  

, sex or gender (P21)  

SELECT ?developer ?developerLabel (COUNT(?software) AS ?count) WHERE {
  ?software (p:P31/ps:P31/wdt:P279*) wd:Q9143.
  ?software wdt:P178 ?developer.
  ?developer wdt:P31 wd:Q5.
  ?developer wdt:P21 wd:Q6581072.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?developer ?developerLabel
ORDER BY DESC(?count)

software written in rust

SELECT DISTINCT ?software ?softwareLabel ?image ?useLabel WHERE {
  ?software wdt:P277 wd:Q575650.
  OPTIONAL { ?software wdt:P366 ?use. }
  OPTIONAL { ?software wdt:P154 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Software written in Rust by license

The following query uses these:

Items: Rust (Q575650)

Properties: programmed in (P277)  

, copyright license (P275)  

SELECT DISTINCT ?software ?softwareLabel ?licenseLabel ?image  WHERE {
  ?software wdt:P277 wd:Q575650.
  OPTIONAL { ?software wdt:P275 ?license. }
  OPTIONAL { ?software wdt:P154 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Programming Languages and images of what they are named after

The following query uses these:

Items: programming language (Q9143)

Properties: instance of (P31)  

, named after (P138)  

, image (P18)  

SELECT DISTINCT ?plang ?plangLabel ?image
WHERE 
{
  ?plang wdt:P31/wdt:P279* wd:Q9143.
  ?plang wdt:P138 ?namesake.
  ?namesake wdt:P18 ?image. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Implementations of Python

The following query uses these:

Items: Python (Q28865)

Properties: implementation of (P4428)  

SELECT ?item ?itemLabel ?logo  WHERE {
  ?item wdt:P4428 wd:Q28865.
  OPTIONAL {?item wdt:P154 ?logo.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File Formats

Return the names of all of the writable file formats that have been described for instances of software applications in Wikidata

The following query uses these:

Items: application (Q166142)

Properties: instance of (P31)  

, writable file format (P1073)  

SELECT ?software ?softwareLabel ?writableffLabel
WHERE {
  ?software wdt:P31/P279*  wd:Q166142 .
  ?software wdt:P1073 ?writableff .
  
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return the names of all of the readable file formats that have been described for instances of software applications in Wikidata

The following query uses these:

Items: application (Q166142)

Properties: instance of (P31)  

SELECT ?software ?softwareLabel ?readableffLabel
WHERE {
  ?software wdt:P31/wdt:P279*  wd:Q166142 .
  ?software wdt:P1072 ?readableff .
  
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of software applications ranked in descending order by the number of writable file formats that have been listed in Wikidata

The following query uses these:

Items: software (Q7397)

Properties: subclass of (P279)  

, writable file format (P1073)  

SELECT ?app ?appLabel (COUNT(?format) AS ?count)
WHERE {
  ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397 .
  ?app wdt:P1073 ?format .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

GROUP BY ?app ?appLabel
ORDER BY DESC(?count)

Return a list of software applications ranked in descending order by the number of readable file formats that have been listed in Wikidata

The following query uses these:

Items: software (Q7397)

Properties: subclass of (P279)   , readable file format (P1072)   , instance of (P31)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart 
SELECT ?app ?appLabel (COUNT(?format) AS ?count)
WHERE {
  ?app (p:P31/ps:P31/wdt:P279) wd:Q7397 .
  ?app wdt:P1072 ?format .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

GROUP BY ?app ?appLabel
ORDER BY DESC(?count)

Return a list of all software applications known to read MXF file formats

The following query uses these:

Items: software (Q7397)   , Material Exchange Format (Q1893311)

Properties: subclass of (P279)  

SELECT ?app ?appLabel 

WHERE {
  ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397 .
  ?app wdt:P1072 wd:Q1893311.
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all software known to read .dxf files

The following query uses these:

Items: software (Q7397)   , Drawing Interchange File Format Family (Q691652)

Properties: instance of (P31)  

SELECT DISTINCT ?app ?appLabel WHERE {
  ?app  wdt:P31/wdt:P279*  wd:Q7397.
  ?app wdt:P1072 wd:Q691652.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of all subclasses of Windows

The following query uses these:

Items: Microsoft Windows (Q1406)

Properties: subclass of (P279)  

SELECT ?app ?appLabel 
WHERE {
  ?app (wdt:P279*) wd:Q1406.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of digital container formats

The following query uses these:

Items: digital container format (Q167772)

Properties: subclass of (P279)  

SELECT ?format ?formatLabel 
WHERE {
  ?format  (p:P31/ps:P31/wdt:P279*) wd:Q167772.
 
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all file formats with file format identification patterns

The following query uses these:

Properties: file format identification pattern (P4152)  

SELECT ?item ?itemLabel ?valueLabel
{
	?item wdt:P4152 ?value .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
}

Return a list of file formats and the ISO standards that define them

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)  

, ISO standard (P503)  

SELECT ?format ?formatLabel ?standardLabel 
WHERE 
{
  
  ?format  (p:P31/ps:P31/wdt:P279*) wd:Q235557 .
  ?format wdt:P503 ?standard.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return list ff and ISO standards- distinct and date

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)  

, ISO standard (P503)  

SELECT DISTINCT ?format ?formatLabel ?standardLabel ?date
WHERE 
{
  
  ?format  (p:P31/ps:P31/wdt:P279*) wd:Q235557 .
  ?format wdt:P503 ?standard.
  OPTIONAL {?format wdt:P577 ?date.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats described by other standards

The following query uses these:

Items: file format (Q235557)   , technical standard (Q317623)

Properties: subclass of (P279)  

, described by source (P1343)  

, standards body (P1462)  

SELECT ?format ?formatLabel ?source ?sourceLabel ?bodyLabel
WHERE 
{
  
  ?format  (p:P31/ps:P31/wdt:P279*) wd:Q235557 .
  ?format wdt:P1343 ?source.
  ?source wdt:P31 wd:Q317623.
  ?source wdt:P1462 ?body.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a list of file formats and info about endianness

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)  

, endianness (P3374)  

SELECT ?format ?formatLabel ?endianLabel

WHERE {
  
  ?format  (p:P31/ps:P31/wdt:P279*) wd:Q235557 .
  ?format wdt:P3374 ?endian .
  
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of file formats that have magic number identification patterns and provide the source

The following query uses these:

Properties: file format identification pattern (P4152)  

, stated in (P248)  

SELECT ?item ?itemLabel ?valueLabel ?detail ?source ?prov ?nameLabel
{
   ?item wdt:P4152 ?value .
   ?item p:P4152 ?detail .
   ?detail prov:wasDerivedFrom      ?source .
      OPTIONAL { 
   ?source pr:P248 ?name      
 }
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
}
LIMIT 1000

File Formats by extension and media type

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)  

SELECT DISTINCT ?idExtension ?extension ?mediaType ?idExtensionLabel 
WHERE
{
	?idExtension (p:P31/ps:P31/wdt:P279*) wd:Q235557
	; wdt:P1195 ?extension .
	OPTIONAL { ?idExtension wdt:P1163 ?mediaType }
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} 
ORDER BY ?extension ?mediaType

File formats developed by AutoDesk

The following query uses these:

Items: file format (Q235557)   , Autodesk (Q628051)

Properties: subclass of (P279)  

, developer (P178)  

SELECT ?item ?itemLabel 
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q235557.
  ?item wdt:P178 wd:Q628051.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats developed by Autodesk with file extension and mediatype information

The following query uses these:

Items: file format (Q235557)   , Autodesk (Q628051)

Properties: subclass of (P279)  

, developer (P178)  

SELECT ?item ?itemLabel ?ext ?media
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q235557.
  ?item wdt:P178 wd:Q628051.
  OPTIONAL {?item wdt:P1195 ?ext.}
  OPTIONAL {?item wdt:P1163 ?media.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats dev by Autodesk with file extension, media type, PUID, and Just Solve wiki page

The following query uses these:

Items: file format (Q235557)   , Autodesk (Q628051)

Properties: subclass of (P279)  

, developer (P178)  

SELECT ?item ?itemLabel ?ext ?media ?pro ?solve 
WHERE 
{
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q235557.
  ?item wdt:P178 wd:Q628051.
  OPTIONAL {?item wdt:P1195 ?ext.}
  OPTIONAL {?item wdt:P1163 ?media.}
  OPTIONAL {?item wdt:P2748 ?pro.}
  OPTIONAL {?item wdt:P3381 ?solve.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats with a PUID link

The following query uses these:

Properties: PRONOM file format ID (P2748)  

SELECT DISTINCT ?format ?formatLabel ?puid

WHERE {
  
  ?format wdt:P2748 ?puid .
   
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

File formats developed by Microsoft

The following query uses these:

Items: file format (Q235557)   , Microsoft (Q2283)

Properties: subclass of (P279)  

, developer (P178)  

SELECT ?item ?itemLabel WHERE {
  ?item (p:P31/ps:P31/wdt:P279) wd:Q235557.
  ?item wdt:P178 wd:Q2283.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Software known to read .PLY files

The following query uses these:

Items: software (Q7397)   , Polygon File Format (Q3077345)

Properties: subclass of (P279)  

SELECT ?app ?appLabel WHERE {
  ?app (p:P31/ps:P31/wdt:P279) wd:Q7397.
  ?app wdt:P1072 wd:Q3077345.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

File formats for 3D computer graphics

The following query uses these:

Items: file format (Q235557)   , 3D computer graphics (Q189177)

Properties: instance of (P31)  

, has use (P366)  

SELECT ?item ?label  WHERE {
  ?item  wdt:P31 wd:Q235557.
  ?item wdt:P366 wd:Q189177.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

File formats for 3D graphics and mimetypes

The following query uses these:

Items: file format (Q235557)   , 3D computer graphics (Q189177)

Properties: instance of (P31)  

, has use (P366)  

SELECT ?item ?label ?media WHERE {
  ?item  wdt:P31 wd:Q235557.
  ?item wdt:P366 wd:Q189177.
  ?item wdt:P1163 ?media.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

Count of # of file formats that have same file extension string

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)  

SELECT DISTINCT ?extension ?extensionLabel (COUNT(?format) AS ?count)
WHERE
{
 ?format (p:P31/ps:P31/wdt:P279*) wd:Q235557
 ; wdt:P1195 ?extension .
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
group by ?extension ?extensionLabel
ORDER BY DESC (?count)

Bubble chart of file formats by developer

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)   , subclass of (P279)   , developer (P178)

Features: BubbleChart (Q24515280)  

##defaultView:BubbleChart
SELECT ?developer ?developerLabel (COUNT(?ff) AS ?count) WHERE {
  ?ff wdt:P31/wdt:P279* wd:Q235557.
  ?ff wdt:P178 ?developer.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?developer ?developerLabel
ORDER BY DESC(?count)

(Gas) graph of subclasses of file format

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q235557 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Return a list of file formats that have information about their MIME type

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

SELECT DISTINCT ?ff ?ffLabel ?mediaType 
WHERE
{
	?ff wdt:P31/wdt:P279* wd:Q235557.
	?ff wdt:P1163 ?mediaType.
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Return a list of file formats developed by Adobe

The following query uses these:

Items: file format (Q235557)   , Adobe (Q11463)

Properties: subclass of (P279)  

, developer (P178)  

SELECT ?item ?itemLabel WHERE {
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q235557.
  ?item wdt:P178 wd:Q11463.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a bubble chart of mediatypes by count of file formats

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

SELECT DISTINCT ?mediaType (COUNT (?ff) as ?count)
WHERE
{
	?ff wdt:P31/wdt:P279* wd:Q235557.
	?ff wdt:P1163 ?mediaType.
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

GROUP BY ?mediaType 
ORDER BY DESC (?count)

File formats that have PUID, LOC FDD, and Just Solve ids

The following query uses these:

Properties: PRONOM file format ID (P2748)  

, Library of Congress Format Description Document ID (P3266)  

SELECT DISTINCT ?format ?formatLabel ?puid ?fdd ?solve

WHERE {
  
  ?format wdt:P2748 ?puid .
  ?format wdt:P3266 ?fdd .
  ?format wdt:P3381 ?solve .         
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

File formats developed by Adobe with file extension, media type, PUID, and Just Solve IDs

The following query uses these:

Items: file format (Q235557)   , Adobe (Q11463)

Properties: instance of (P31)  

, developer (P178)  

SELECT ?item ?itemLabel ?ext ?media ?pro ?solve WHERE {
  ?item wdt:P31/wdt:P279* wd:Q235557.
  ?item wdt:P178 wd:Q11463.
    OPTIONAL {?item wdt:P1195 ?ext.}
  OPTIONAL {?item wdt:P1163 ?media.}
  OPTIONAL {?item wdt:P2748 ?pro.}
  OPTIONAL {?item wdt:P3381 ?solve.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Software available under a free software license that can open .OBJ files with logo images

The following query uses these:

Items: software (Q7397)   , Wavefront .obj file (Q2119595)   , free software license (Q3943414)

Properties: instance of (P31)  

, copyright license (P275)  

SELECT DISTINCT ?app ?appLabel ?logo WHERE {
  ?app (wdt:P31/wdt:P279*) wd:Q7397.
  ?app wdt:P1072 wd:Q2119595.
  ?app wdt:P275 ?lic.
  ?lic (wdt:P31/wdt:P279*) wd:Q3943414.
  ?app wdt:P154 ?logo.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Executable file formats

The following query uses these:

Items: executable file format (Q17560478)

Properties: instance of (P31)  

, Uniform Type Identifier (P3641)  

SELECT ?ff ?ffLabel ?mime ?pronom ?uti
WHERE {
  ?ff wdt:P31/wdt:P279* wd:Q17560478.
  OPTIONAL {?ff wdt:P1163 ?mime.}
  OPTIONAL {?ff wdt:P2748 ?pronom.}
  OPTIONAL {?ff wdt:P3641 ?uti.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

The Netpbm file format family

The following query uses these:

Items: Netpbm formats (Q17154458)

Properties: subclass of (P279)  

, described at URL (P973)  

SELECT ?item ?itemLabel ?ext ?media ?pro ?solve ?url WHERE {
  ?item wdt:P279 wd:Q17154458.
  ?item wdt:P1195 ?ext.
  ?item wdt:P1163 ?media.
  OPTIONAL {?item wdt:P2748 ?pro.}
  OPTIONAL {?item wdt:P3381 ?solve.}
  OPTIONAL {?item wdt:P973 ?url.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Audio File Formats by extension

The following query uses these:

Items: audio file format (Q682626)   , audio coding format (Q758871)

Properties: instance of (P31)  

SELECT DISTINCT ?item ?itemLabel ?ext WHERE {
  {?item wdt:P31 wd:Q682626.}
  UNION {?item wdt:P31 wd:Q758871}.
  ?item wdt:P1195 ?ext.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Audio File Formats by ext, media type, and PUID

The following query uses these:

Items: audio file format (Q682626)   , audio coding format (Q758871)

Properties: instance of (P31)  

SELECT DISTINCT ?item ?itemLabel ?ext ?media ?puid WHERE {
  {?item wdt:P31 wd:Q682626.}
  UNION {?item wdt:P31 wd:Q758871}.
  ?item wdt:P1195 ?ext.
  OPTIONAL {?item wdt:P1163 ?media.}
  OPTIONAL {?item wdt:P2748 ?puid.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Video File formats by ext, media type, and PUID

The following query uses these:

Items: video file format (Q18359031)   , video format (Q10715094)

Properties: instance of (P31)  

SELECT DISTINCT ?item ?itemLabel ?ext ?media ?puid WHERE {
  { ?item wdt:P31 wd:Q18359031. }
  UNION
  { ?item wdt:P31 wd:Q10715094. }
  ?item wdt:P1195 ?ext.
  OPTIONAL { ?item wdt:P1163 ?media. }
  OPTIONAL { ?item wdt:P2748 ?puid. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File Formats with PUID external ID and mime type

The following query uses these:

Properties: PRONOM file format ID (P2748)  

SELECT DISTINCT ?format ?formatLabel ?puid ?mime

WHERE {
  
  ?format wdt:P2748 ?puid .
  OPTIONAL {?format wdt:P1163 ?mime .}
   
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

File formats ranked in order of the largest number of software titles known to be able to read them

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

SELECT ?format ?formatLabel (COUNT(?app) AS ?count)
WHERE {
  ?format wdt:P31/wdt:P279* wd:Q235557.
  ?app wdt:P1072 ?format.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

GROUP BY ?format ?formatLabel

ORDER BY DESC(?count)

LIMIT 50

File formats by length of extension

The following query uses these:

Properties: file extension (P1195)  

SELECT  ?format ?formatLabel ?ext
WHERE {
  ?format wdt:P1195 ?ext.
  
  
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

ORDER BY(STRLEN(?ext))

File formats that have documentation links

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

, described at URL (P973)  

SELECT ?ff ?ffLabel ?url
WHERE 
{
  ?ff wdt:P31/wdt:P279* wd:Q235557.
  ?ff wdt:P973 ?url
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats that scientific software titles can read

The following query uses these:

Items: file format (Q235557)   , science (Q336)

Properties: instance of (P31)  

, has use (P366)  

SELECT ?format ?formatLabel  (COUNT(?app) AS ?count)
WHERE {
  ?format wdt:P31/wdt:P279* wd:Q235557.
  ?app wdt:P1072 ?format.
   ?app wdt:P366 wd:Q336 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

GROUP BY ?format ?formatLabel

ORDER BY DESC(?count)

LIMIT 50

File formats used in chemistry

The following query uses these:

Items: file format (Q235557)   , chemistry (Q2329)

Properties: instance of (P31)  

, has use (P366)  

SELECT ?item ?label  WHERE {
  ?item wdt:P31/wdt:P279* wd:Q235557.
  ?item wdt:P366 wd:Q2329.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
  

}

Tree map of media types by file formats by developer

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

, developer (P178)  

#defaultView:TreeMap
SELECT ?mimetype  ?developerLabel
WHERE 
{
  ?fileFormat wdt:P31/wdt:P279* wd:Q235557.
  ?fileFormat wdt:P1163 ?mimetype.
  ?fileFormat wdt:P178 ?developer.            
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats and the sources that describe them

The following query uses these:

Items: file format (Q235557)

Properties: subclass of (P279)  

, described by source (P1343)  

SELECT ?format ?formatLabel ?source ?sourceLabel ?classLabel
WHERE 
{
  
  ?format  (p:P31/ps:P31/wdt:P279*) wd:Q235557 .
  ?format wdt:P1343 ?source.
  ?source wdt:P31 ?class
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Publications that have a file format as the main subject

The following query uses these:

Items: file format (Q235557)

Properties: main subject (P921)  

SELECT ?work ?workLabel 
WHERE {
  
  ?work wdt:P921 ?format .
  ?format wdt:P31/wdt:P279* wd:Q235557.          
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    
}

Software titles known to read smiles

The following query uses these:

Items: software (Q7397)   , simplified molecular input line entry specification (Q466769)

Properties: instance of (P31)  

SELECT DISTINCT ?app ?appLabel ?image

WHERE {
  ?app wdt:P31/wdt:P279* wd:Q7397 .
  ?app wdt:P1072 wd:Q466769.
  OPTIONAL {?app wdt:P154 ?image}.          
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }

File format families by count of component parts

The following query uses these:

Items: file format family (Q26085352)

Properties: instance of (P31)   , has part(s) (P527)

Features: BubbleChart (Q24515280)  

#File format families by count of component parts
#defaultView:BubbleChart
SELECT ?item ?itemLabel (COUNT (?part) as ?count)
WHERE 
{
  ?item wdt:P31 wd:Q26085352.
  ?item wdt:P527 ?part.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?item ?itemLabel
ORDER BY DESC (?count)

Developers of file format families

The following query uses these:

Items: file format family (Q26085352)

Properties: instance of (P31)   , has part(s) (P527)   , developer (P178)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?dev ?devLabel (COUNT (?item) as ?count)
WHERE 
{
  ?item wdt:P31 wd:Q26085352.
  ?item wdt:P527 ?part.
  ?item wdt:P178 ?dev.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?dev ?devLabel
ORDER BY DESC (?count)

File formats that have their own identifier in the Getty Art and Architecture Thesaurus

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

, Art & Architecture Thesaurus ID (P1014)  

#File formats that have their own identifier in the Getty Art and Architecture Thesaurus
SELECT ?item ?itemLabel ?AATID
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q235557.
  ?item wdt:P1014 ?AATID.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats by count of scholarly articles

The following query uses these:

Items: file format (Q235557)   , scholarly article (Q13442814)

Properties: instance of (P31)  

SELECT ?item ?itemLabel (COUNT(?article) AS ?count)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q235557.
  ?article wdt:P31 wd:Q13442814.
  ?article wdt:P921 ?item.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?item ?itemLabel
ORDER BY DESC(?count)

File formats used in bioinformatics ranked by the number of software titles known to read them

The following query uses these:

Items: software (Q7397)   , bioinformatics (Q128570)

Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , readable file format (P1072)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?fileFormat ?fileFormatLabel (COUNT(?item) AS ?count)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q7397.
  ?item wdt:P366 wd:Q128570.
  ?item wdt:P1072 ?fileFormat.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?fileFormat ?fileFormatLabel

ORDER BY DESC(?count)

Disk image file formats

The following query uses these:

Items: disk image (Q592312)

Properties: instance of (P31)  

SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q592312.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats developed by religious organizations

The following query uses these:

Items: file format (Q235557)   , religious denomination (Q13414953)

Properties: instance of (P31)  

, developer (P178)  

SELECT ?item ?itemLabel ?dev ?devLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q235557.
  ?item wdt:P178 ?dev.
  ?dev wdt:P31/wdt:P279* wd:Q13414953.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File format families graph

The following query uses these:

Items: file format family (Q26085352)

Properties: instance of (P31)   , media type (P1163)   , part of (P361)   , has part(s) (P527)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT ?char ?charLabel ?group ?groupLabel ("7FFF00" AS ?rgb) WHERE {
  ?group wdt:P31 wd:Q26085352.
  ?group wdt:P1163 ?media.
  #?char wdt:P361 ?group.
  ?group wdt:P527 ?char.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

File formats missing mediatype

The following query uses these:

Items: file format (Q235557)

Properties: instance of (P31)  

SELECT DISTINCT ?fileformat ?fileformatLabel 

WHERE {
  ?fileformat wdt:P31/wdt:P279* wd:Q235557.
  
 FILTER NOT EXISTS { ?fileformat p:P1163 ?mediatype }
  
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }

File formats from Microsoft by ext, ids, mimetype

The following query uses these:

Items: file format (Q235557)   , Microsoft (Q2283)

Properties: instance of (P31)  

, developer (P178)  

SELECT ?item ?itemLabel ?ext ?media ?pro ?solve WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q235557.
  ?item wdt:P178 wd:Q2283.
  OPTIONAL { ?item wdt:P1195 ?ext. }
  OPTIONAL { ?item wdt:P1163 ?media. }
  OPTIONAL { ?item wdt:P2748 ?pro. }
  OPTIONAL { ?item wdt:P3381 ?solve. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Emulators

Return a list of all instances of emulators in Wikidata

The following query uses these:

Items: emulator (Q202871)

Properties: instance of (P31)  

SELECT ?emulator ?emulatorLabel
WHERE {
  
  ?emulator wdt:P31 wd:Q202871 .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all instances of and subclasses of emulator

The following query uses these:

Items: emulator (Q202871)

Properties: instance of (P31)  

SELECT ?emulator ?emulatorLabel
WHERE {
  
  ?emulator wdt:P31/wdt:P279* wd:Q202871 .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of emulators and what they emulate

The following query uses these:

Items: emulator (Q202871)

Properties: subclass of (P279)  

, emulates (P4043)  

SELECT ?emulator ?emulatorLabel ?targetLabel

WHERE {
  
  ?emulator  (p:P31/ps:P31/wdt:P279*) wd:Q202871 .
  ?emulator wdt:P4043 ?target          
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Color-coded graph of emulators and what they emulate

The following query uses these:

Items: emulator (Q202871)

Properties: subclass of (P279)   , emulates (P4043)   , instance of (P31)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT ?emulator ?emulatorLabel ?target ?targetLabel ("00FFFF" AS ?rgb)

WHERE {
  
  ?emulator  (p:P31/ps:P31/wdt:P279*) wd:Q202871 .
  ?emulator wdt:P4043 ?target          
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    
  }

Return list of all emulators that have a logo image

The following query uses these:

Items: emulator (Q202871)

Properties: instance of (P31)  

SELECT ?emulator ?emulatorLabel ?image
WHERE {
  
  ?emulator wdt:P31 wd:Q202871 .
  ?emulator wdt:P154 ?image .          
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

}}

Return a list of all hypervisors in Wikidata

The following query uses these:

Items: hypervisor (Q1077480)

Properties: subclass of (P279)  

SELECT ?item ?label WHERE {
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q1077480.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
  

}
LIMIT 100

Return an image grid of the logos for raster graphics editor software

The following query uses these:

Items: raster graphics editor (Q2351962)

Properties: instance of (P31)   , logo image (P154)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT ?item ?label ?image WHERE {
  ?item wdt:P31 wd:Q2351962.
  ?item wdt:P154 ?image.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

Knowledge bases

The following query uses these:

Items: knowledge base (Q593744)

Properties: instance of (P31)  

SELECT ?item ?label WHERE {
  ?item wdt:P31 wd:Q593744.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

Knowledge bases and subclasses

The following query uses these:

Items: knowledge base (Q593744)

Properties: subclass of (P279)  

SELECT ?item ?label WHERE {
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q593744.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

plugins

The following query uses these:

Items: plug-in (Q184148)

Properties: instance of (P31)  

SELECT ?software ?softwareLabel

WHERE {
  
  ?software wdt:P31/wdt:P279*  wd:Q184148
  
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Operating Systems

Return a list of all instances of operating system in Wikidata

The following query uses these:

Items: operating system (Q9135)

Properties: instance of (P31)  

SELECT ?os ?osLabel 
WHERE {
  
  ?os wdt:P31 wd:Q9135 .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return all operating systems grouped by developer

The following query uses these:

Items: operating system (Q9135)

Properties: subclass of (P279)  

, developer (P178)  

SELECT DISTINCT ?os ?osLabel ?devLabel
WHERE {
  
  ?os (p:P31/ps:P31/wdt:P279*) wd:Q9135 .
  ?os wdt:P178 ?dev.          
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }
ORDER BY ?devLabel

Return a list of os grouped by developer and listing what class they belong to

The following query uses these:

Items: operating system (Q9135)

Properties: subclass of (P279)  

, developer (P178)  

SELECT DISTINCT ?os ?osLabel ?devLabel ?classLabel
WHERE {
  
  ?os (p:P31/ps:P31/wdt:P279*) wd:Q9135 .
  ?os wdt:P178 ?dev.          
  ?os wdt:P279 ?class.
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }
ORDER BY ?devLabel

Return a graph of all class/subclass relationships for operating systems

The following query uses these:

Items: operating system (Q9135)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?os ?osLabel ?subclassOf WHERE {
  ?os wdt:P279* wd:Q9135 .
  OPTIONAL { ?os wdt:P279 ?subclassOf } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?osLabel

Return a list of all software for DOS in Wikidata

The following query uses these:

Items: DOS (Q170434)

Properties: operating system (P306)  

SELECT ?app ?appLabel WHERE {
  ?app wdt:P306 wd:Q170434.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of all software for DOS (union OS and platform)

The following query uses these:

Items: DOS (Q170434)

Properties: operating system (P306)  

, platform (P400)  

SELECT ?app ?appLabel ?classLabel ?logo
WHERE {
  {?app wdt:P306 wd:Q170434}
  UNION {?app wdt:P400 wd:Q170434}.
  ?app wdt:P31 ?class.
  OPTIONAL {?app wdt:P154 ?logo}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return an image grid of all GNU/Linux distributions

The following query uses these:

Items: Linux distribution (Q131669)

Properties: instance of (P31)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT ?dist ?distLabel ?image WHERE {
  ?dist wdt:P31 wd:Q131669.
  ?dist wdt:P18 ?image.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Operating Systems and the kernels that power them

The following query uses these:

Items: kernel (Q9662)

Properties: instance of (P31)  

, part of (P361)  

SELECT ?kernel ?kernelLabel ?osLabel
WHERE {
  ?kernel wdt:P31 wd:Q9662.
  ?kernel wdt:P361 ?os .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a graph of all subclasses of Microsoft Windows

The following query uses these:

Items: Microsoft Windows (Q1406)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?os ?osLabel ?subclassOf WHERE {
  
  ?os wdt:P279* wd:Q1406.
  OPTIONAL { ?os wdt:P279 ?subclassOf. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?osLabel

Alternative version for above to get a few more

The following query uses these:

Items: operating system (Q9135)   , Microsoft (Q2283)   , Microsoft Windows (Q1406)

Properties: subclass of (P279)   , developer (P178)   , instance of (P31)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?os ?osLabel ?subclassOf WHERE {
  ?os (p:P31/ps:P31/wdt:P279*) wd:Q9135.
  ?os wdt:P178 wd:Q2283.
  ?os wdt:P279* wd:Q1406.
  OPTIONAL { ?os wdt:P279 ?subclassOf. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?osLabel

Bubble chart of os by developer

The following query uses these:

Items: operating system (Q9135)

Properties: subclass of (P279)   , developer (P178)   , instance of (P31)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?developer ?developerLabel (COUNT(?os) AS ?count) WHERE {
  ?os (p:P31/ps:P31/wdt:P279) wd:Q9135.
  ?os wdt:P178 ?developer.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?developer ?developerLabel
ORDER BY DESC(?count)

(Gas) GNU/Linux

The following query uses these:

Items: Linux (Q388)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q388 ;
                gas:traversalDirection "Forward" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

(Gas) GNU/Linux and subclasses

The following query uses these:

Items: Linux (Q388)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q388 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Who develops operating systems

The following query uses these:

Items: operating system (Q9135)

Properties: instance of (P31)   , subclass of (P279)   , developer (P178)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?class ?classLabel (COUNT(?developer) AS ?count) WHERE {
  ?os wdt:P31/wdt:P279* wd:Q9135.
  ?os wdt:P178 ?developer.
  ?developer wdt:P31 ?class
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?class ?classLabel
ORDER BY DESC(?count)

Hardware

Return a graph of class/subclass relationships for computer peripheral equipment

The following query uses these:

Items: peripheral (Q178648)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT ?per ?perLabel ?subclassOf 
WHERE {
  ?per wdt:P279* wd:Q178648.
  OPTIONAL { ?per wdt:P279 ?subclassOf. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?perlabel

Return a graph of class/subclass relationships for computer data storage

The following query uses these:

Items: computer data storage device (Q66221)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?storage ?storageLabel ?subclassOf 
WHERE {
  ?storage wdt:P279* wd:Q66221 .
  OPTIONAL { ?storage wdt:P279 ?subclassOf } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?storageLabel

Return a list of virtual reality headsets

The following query uses these:

Items: virtual reality headset (Q22980233)

Properties: instance of (P31)  

SELECT ?item ?label  WHERE {
  ?item wdt:P31 wd:Q22980233.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
  
}

Return a graph of all subclasses of integrated circuit

The following query uses these:

Items: integrated circuit (Q80831)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?ic ?icLabel ?subclassOf WHERE {
  ?ic wdt:P279* wd:Q80831.
  OPTIONAL { ?ic wdt:P279 ?subclassOf. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?icLabel

(Gas) Return a gas graph of peripheral equipment

The following query uses these:

Items: peripheral (Q178648)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q178648 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

(Gas) Return a graph of subclasses of computer hardware

The following query uses these:

Items: computer hardware (Q3966)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q3966 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

(GAS) return a graph of subclasses of computer data storage

The following query uses these:

Items: computer data storage device (Q66221)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q66221 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Intel chipsets

The following query uses these:

Items: chipset (Q182656)   , Intel (Q248)

Properties: instance of (P31)  

, image (P18)  

SELECT ?item ?label ?_image WHERE {
  ?item wdt:P31 wd:Q182656.
  ?item wdt:P176 wd:Q248.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
  
OPTIONAL { ?item wdt:P18 ?_image. }
}
LIMIT 100

Image grid of VR headsets

The following query uses these:

Items: virtual reality headset (Q22980233)

Properties: instance of (P31)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT ?headset ?headsetLabel ?image
WHERE {
  ?headset wdt:P31 wd:Q22980233.
  OPTIONAL {?headset wdt:P18 ?image}.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
}

Image grid of video game consoles with InternetArchiveIDs

The following query uses these:

Items: video game console (Q8076)

Properties: instance of (P31)   , subclass of (P279)   , Internet Archive ID (P724)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT DISTINCT ?comp ?compLabel ?archiveidLabel ?image WHERE {
  ?comp (wdt:P31/wdt:P279*) wd:Q8076.
  ?comp wdt:P724 ?archiveid.
  OPTIONAL { ?comp wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Image grid of models of personal computer with InternetArchiveIDs

The following query uses these:

Items: product model (Q17444171)

Properties: instance of (P31)   , subclass of (P279)   , Internet Archive ID (P724)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT DISTINCT ?comp ?compLabel ?archiveidLabel ?image WHERE {
  ?comp (wdt:P31/wdt:P279*) wd:Q17444171.
  ?comp wdt:P724 ?archiveid.
  OPTIONAL { ?comp wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Image grid of home computers with InternetArchiveIDs

The following query uses these:

Items: home computer (Q473708)

Properties: instance of (P31)   , subclass of (P279)   , Internet Archive ID (P724)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT DISTINCT ?comp ?compLabel ?archiveidLabel ?image WHERE {
  ?comp (wdt:P31/wdt:P279*) wd:Q473708.
  ?comp wdt:P724 ?archiveid.
  OPTIONAL { ?comp wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

One of a Kind Computers

The following query uses these:

Items: one-of-a-kind computer (Q28542014)

Properties: instance of (P31)  

, image (P18)  

SELECT ?computer ?computerLabel ?image WHERE {
  ?computer wdt:P31 wd:Q28542014.
  OPTIONAL {?computer wdt:P18 ?image}.
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }

Bubble chart of sound cards by manufacturer

The following query uses these:

Items: sound card (Q4343)

Properties: instance of (P31)  

SELECT  ?manufacturer ?manufacturerLabel(COUNT(?item) AS ?count)
WHERE 
{
  ?item wdt:P31 wd:Q4343.
  ?item wdt:P176 ?manufacturer
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?manufacturer ?manufacturerLabel

ORDER BY DESC(?count)

Soundcards by manufacturer and date

The following query uses these:

Items: sound card (Q4343)

Properties: instance of (P31)  

, inception (P571)  

SELECT ?item ?itemLabel ?manufacturerLabel ?date
WHERE 
{
  ?item wdt:P31 wd:Q4343.
  OPTIONAL {?item wdt:P176 ?manufacturer.}
  OPTIONAL {?item wdt:P571 ?date}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Soundcards, images, date of publication timeline

The following query uses these:

Items: sound card (Q4343)

Properties: instance of (P31)  

, image (P18)  

, inception (P571)  

SELECT ?item ?itemLabel ?manufacturerLabel ?date ?image
WHERE 
{
  ?item wdt:P31 wd:Q4343.
  ?item wdt:P18 ?image.
  OPTIONAL {?item wdt:P176 ?manufacturer.}
  OPTIONAL {?item wdt:P571 ?date}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Image grid of soundcards

The following query uses these:

Items: sound card (Q4343)

Properties: instance of (P31)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image
WHERE 
{
  ?item wdt:P31 wd:Q4343.
  ?item wdt:P18 ?image.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Commands

Return a list of all of the environment variables that the 'ls' command can read

The following query uses these:

Items: ls (Q283503)

Properties: reads environment variable (P4810)  

SELECT ?var ?varLabel
WHERE 
{
  wd:Q283503 wdt:P4810 ?var
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a list of all command line options for 'make'

The following query uses these:

Items: make (Q300867)

Properties: has command line option (P4837)  

SELECT  ?value 
{
	wd:Q300867 wdt:P4837 ?value.
    
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
}

Return a bubble chart of standard UNIX utilities ranked in the order of the number of environment variables they can read

The following query uses these:

Items: standard UNIX utility or command (Q18343316)

Properties: instance of (P31)   , reads environment variable (P4810)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?itemLabel (COUNT(?item) as ?count)
WHERE 
{
  ?item wdt:P31 wd:Q18343316.
  ?item wdt:P4810 ?var.
  ?item rdfs:label ?itemLabel .
  FILTER (lang(?itemLabel)="en")
  } GROUP BY ?itemLabel
ORDER BY DESC(?count)

Scholarly Communication

Return a list of scientific articles that have metadata about what software was used in the study

The following query uses these:

Items: scholarly article (Q13442814)

Properties: instance of (P31)  

, uses (P2283)  

SELECT ?article ?articleLabel ?softwareLabel

WHERE {
  ?article wdt:P31 wd:Q13442814 .
  ?article wdt:P2283 ?software .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a ranked list of pieces of software used in scientific articles grouped by the numbers of papers that report use of the software

There is a button on WQS labled "Display". Clicking on that button will trigger a drop-down menu of visualization options. To see this as a graph select "Bubble Chart".

The following query uses these:

Items: scholarly article (Q13442814)

Properties: instance of (P31)  

, uses (P2283)  

SELECT ?software ?softwareLabel (COUNT(?article) AS ?count)

WHERE {
  ?article wdt:P31 wd:Q13442814.
  ?article wdt:P2283 ?software .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }
GROUP BY ?software ?softwareLabel 
ORDER BY DESC(?count)

Return a list of all scientific articles that use STATA software and list the version

The following query uses these:

Items: scholarly article (Q13442814)   , Stata (Q1204300)

Properties: instance of (P31)  

, uses (P2283)  

, software version identifier (P348)  

SELECT ?article ?articleLabel ?softwareLabel ?date

WHERE {
  ?article wdt:P31 wd:Q13442814 .
  ?article wdt:P2283 ?software .
  ?software wdt:P279 wd:Q1204300 .
  ?software wdt:P348 ?version .
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all scientific articles that have external data available at URL statements

The following query uses these:

Items: scholarly article (Q13442814)

Properties: instance of (P31)  

, external data available at URL (P1325)  

SELECT ?article ?articleLabel ?link

WHERE {
  ?article wdt:P31 wd:Q13442814 .
  ?article wdt:P1325 ?link
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all scientific articles that have external data available at URL statements from the ISPS collection

The following query uses these:

Items: scholarly article (Q13442814)   , Institution for Social and Policy Studies (Q32968689)

Properties: instance of (P31)  

, external data available at URL (P1325)  

, collection (P195)  

PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT ?article ?articleLabel 

WHERE {
  ?article wdt:P31 wd:Q13442814 .
  ?article  p:P1325 [pq:P195 wd:Q32968689] .
 
          SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all works that have software citation as a main subject

The following query uses these:

Items: software citation (Q33115358)

Properties: main subject (P921)  

SELECT ?work ?workLabel 
WHERE {
  
  ?work wdt:P921 wd:Q33115358 .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all works that have linked data or linked open data as a main subject

The following query uses these:

Items: linked data (Q515701)   , linked open data (Q18692990)

Properties: main subject (P921)  

SELECT ?work ?workLabel 
WHERE {
  
  ?work wdt:P921 wd:Q515701 .
            
OPTIONAL {
  
  ?work wdt:P921 wd:wd:Q18692990.
}
  
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all software that has a DOI

The following query uses these:

Items: software (Q7397)

Properties: subclass of (P279)  

, DOI (P356)  

SELECT ?software ?softwareLabel ?doi
WHERE 
{
  ?software (p:P31/ps:P31/wdt:P279*) wd:Q7397 .
  ?software wdt:P356 ?doi .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Return a list of universities in the U.S. that have their GRID ID listed in Wikidata

The following query uses these:

Items: university (Q3918)   , United States of America (Q30)

Properties: instance of (P31)  

, located in the administrative territorial entity (P131)  

, GRID ID (P2427)  

SELECT ?item ?label ?gridID WHERE {
  ?item wdt:P31 wd:Q3918.
  ?item wdt:P131* wd:Q30.
  ?item wdt:P2427 ?gridID.
  
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
  

}

Return a list of universities in the PRC that have their GRID ID listed in Wikidata and display labels in Chinese

The following query uses these:

Items: university (Q3918)   , People's Republic of China (Q148)

Properties: instance of (P31)  

, located in the administrative territorial entity (P131)  

, GRID ID (P2427)  

SELECT ?item ?label ?gridID WHERE {
  ?item wdt:P31 wd:Q3918.
  ?item wdt:P131* wd:Q148.
  ?item wdt:P2427 ?gridID.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "zh".
    ?item rdfs:label ?label.
  }
}

Scientific articles that have a piece of software as a main subject

The following query uses these:

Items: scholarly article (Q13442814)   , software (Q7397)

Properties: instance of (P31)  

SELECT ?item ?itemLabel ?subjectLabel
WHERE 
{
  ?item wdt:P31 wd:Q13442814.
  ?item wdt:P921 ?subject.
  ?subject wdt:P31/wdt:P279* wd:Q7397.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Scientific articles that have a piece of scientific software as a main subject ranked by # of mentions

The following query uses these:

Items: scholarly article (Q13442814)   , software (Q7397)   , science (Q336)

Properties: instance of (P31)  

, has use (P366)  

SELECT  ?subject ?subjectLabel (COUNT (?item) AS ?count) 
WHERE 
{
  ?item wdt:P31 wd:Q13442814.
  ?item wdt:P921 ?subject.
  ?subject wdt:P31/wdt:P279* wd:Q7397.
  ?subject wdt:P366 wd:Q336.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?subject ?subjectLabel

ORDER BY DESC (?count)

Journals that have published the highest number of articles that have a software title as a main subject

The following query uses these:

Items: scholarly article (Q13442814)   , software (Q7397)   , scientific journal (Q5633421)

Properties: instance of (P31)  

, published in (P1433)  

SELECT ?journal ?journalLabel (COUNT (?item) AS ?count)
WHERE 
{
  ?item wdt:P31 wd:Q13442814.
  ?item wdt:P921 ?subject.
  ?subject wdt:P31/wdt:P279* wd:Q7397.
  ?item wdt:P1433 ?journal.
  ?journal wdt:P31 wd:Q5633421.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?journal ?journalLabel


ORDER BY DESC(?count)

LIMIT 75

Journals that have published the highest number of articles that have a file format as a main subject

The following query uses these:

Items: scholarly article (Q13442814)   , file format (Q235557)   , scientific journal (Q5633421)

Properties: instance of (P31)  

, published in (P1433)  

SELECT ?journal ?journalLabel (COUNT(?item) AS ?count) WHERE {
  ?item wdt:P31 wd:Q13442814.
  ?item wdt:P921 ?subject.
  ?subject (wdt:P31/wdt:P279*) wd:Q235557.
  ?item wdt:P1433 ?journal.
  ?journal wdt:P31 wd:Q5633421.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?journal ?journalLabel
ORDER BY DESC(?count)
LIMIT 75

Institutions w CrossRef Funder ID

The following query uses these:

Properties: Open Funder Registry funder ID (P3153)  

SELECT ?item ?itemLabel ?value 
{
	?item wdt:P3153 ?value .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
}

Video Games

Return a graph of all subclasses of video game

The following query uses these:

Items: video game (Q7889)

Properties: subclass of (P279)

Features: Graph (Q24515287)  

#defaultView:Graph
SELECT DISTINCT ?vid ?vidLabel ?subclassOf 
WHERE {
  ?vid wdt:P279* wd:Q7889 .
  OPTIONAL { ?vid wdt:P279 ?subclassOf } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?vidLabel

Return a list of all Twitter accounts for video games listed in Wikidata

The following query uses these:

Items: video game (Q7889)

Properties: subclass of (P279)  

, X username (P2002)  

SELECT DISTINCT ?appLabel ?twitter 
WHERE {
    ?app (p:P31/ps:P31/wdt:P279*) wd:Q7889.
    ?app wdt:P2002 ?twitter .

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a timeline of all the games in the King's Quest series by date of publication

The following query uses these:

Items: King's Quest (Q1161804)

Properties: part of the series (P179)  

#defaultView:Timeline
SELECT ?game ?gameLabel ?date
WHERE 
{
  ?game wdt:P179 wd:Q1161804.
  ?game wdt:P577 ?date.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

(GAS) return a graph of subclasses of video game

The following query uses these:

Items: video game (Q7889)

Properties: subclass of (P279)   , image (P18)

Features: Graph (Q24515287)  

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q7889 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Video Games Listed in the World of Spectrum (the official world archive for the Sinclair ZX Spectrum) which are available to play in an emulator right now via the Internet Archive

The following query uses these:

Properties: ZXDB ID (P4705)  

, Internet Archive ID (P724)  

SELECT ?item ?itemLabel ?WorldOfSpectrumID ?archiveID
{
	?item wdt:P4705 ?WorldOfSpectrumID.
        ?item wdt:P724 ?archiveID.
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
}

Characters that have GIF sets on Giphy

The following query uses these:

Items: fictional character (Q95074)

Properties: instance of (P31)  

, Giphy username (P4013)  

SELECT DISTINCT ?item ?itemLabel ?giphy WHERE {
  ?item wdt:P31/wdt:P279* wd:Q95074.
  ?item wdt:P4013 ?giphy.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Video games set in the Star Wars Expanded Universe by game mode

The following query uses these:

Items: video game (Q7889)   , Star Wars Legends (Q3551295)

Properties: instance of (P31)  

, takes place in fictional universe (P1434)  

, game mode (P404)  

SELECT ?application ?applicationLabel ?modeLabel WHERE {
  ?application (wdt:P31/wdt:P279*) wd:Q7889.
  ?application wdt:P1434 wd:Q3551295.
  OPTIONAL {?application wdt:P404 ?mode}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Video games dev by people who worked at a national lab

The following query uses these:

Items: video game (Q7889)   , United States national laboratory (Q2624320)

Properties: instance of (P31)  

, developer (P178)  

, employer (P108)  

SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q7889.
  ?item wdt:P178 ?dev.
  ?dev wdt:P108 ?employer.
  ?employer wdt:P31 wd:Q2624320.
  
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

===Video games that have Mobygames group ID and subreddit

The following query uses these:

Items: video game series (Q7058673)

Properties: instance of (P31)  

, MobyGames group ID (former scheme) (P5360)  

, subreddit (P3984)  

, image (P18)  

#Video game series that have Moby games group ID and a subreddit
SELECT ?series ?seriesLabel ?mobyGroup ?subreddit ?image
WHERE 
{
  ?series wdt:P31 wd:Q7058673.
  ?series wdt:P5360 ?mobyGroup.
  ?series wdt:P3984 ?subreddit.
  OPTIONAL {?series wdt:P18 ?image.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Awards

Return an image grid of all winners of the Free Software Foundation's Free Software Awards

The following query uses these:

Items: FSF Award for the Advancement of Free Software (Q1389573)

Properties: award received (P166)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT  ?personLabel  ?image 

WHERE {
  ?person wdt:P166 wd:Q1389573 .
  ?person wdt:P18 ?image .
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return an image grid of winners of FSF free software award with their notable work displayed under the image

The following query uses these:

Items: FSF Award for the Advancement of Free Software (Q1389573)

Properties: award received (P166)   , image (P18)   , notable work (P800)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT  ?personLabel  ?image ?notableLabel

WHERE {
  ?person wdt:P166 wd:Q1389573 .
  ?person wdt:P18 ?image .
  ?person wdt:P800 ?notable
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return a list of all winners of a DPC award

The following query uses these:

Items: Digital Preservation Coalition (Q30256408)

Properties: award received (P166)  

, conferred by (P1027)  

SELECT  ?recLabel  ?awardLabel 

WHERE {
  ?rec wdt:P166 ?award .
  ?award wdt:P1027 wd:Q30256408
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Winners of the Computer Pioneers Award and where they were educated

The following query uses these:

Items: Computer Pioneer Award (Q4363133)

Properties: award received (P166)  

, educated at (P69)  

SELECT ?person ?personLabel ?schoolLabel
WHERE {
   ?person wdt:P166 wd:Q4363133;
          p:P69 [ps:P69 ?school].
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
   }

Return an image grid of people inducted into the Women in Technology International Hall of Fame

The following query uses these:

Items: Women in Technology International (Q55200)

Properties: award received (P166)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT ?awardeeLabel ?image WHERE {
  ?awardee wdt:P166 wd:Q55200.
  ?awardee wdt:P18 ?image.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  
}

Return a list of women who have given oral histories to the Computer History Museum along with their image and list awards they have rec'd

The following query uses these:

Items: Computer History Museum (Q964035)   , female (Q6581072)

Properties: archives at (P485)  

, sex or gender (P21)  

, award received (P166)  

, image (P18)  

SELECT  ?person ?personLabel  ?image ?awardLabel 

WHERE {
  ?person wdt:P485 wd:Q964035.
  ?person wdt:P21 wd:Q6581072.
  OPTIONAL {?person wdt:P166 ?award}.
  OPTIONAL {?person wdt:P18 ?image.}
  
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

People who have been elected into the Internet Hall of Fame

The following query uses these:

Items: Internet Hall of Fame (Q6055547)

Properties: award received (P166)  

, image (P18)  

SELECT ?person ?personLabel ?image WHERE {
  ?person wdt:P166 wd:Q6055547.
  OPTIONAL {?person wdt:P18 ?image}.
    
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Map of birthplaces of people who have been elected to the Internet Hall of Fame

The following query uses these:

Items: Internet Hall of Fame (Q6055547)

Properties: award received (P166)   , image (P18)   , place of birth (P19)   , coordinate location (P625)

Features: map (Q24515275)  

#defaultView:Map
SELECT DISTINCT ?person ?personLabel ?birthplaceLabel ?coord ?lat ?lon ?image WHERE {
  ?person wdt:P166 wd:Q6055547.
  OPTIONAL {?person wdt:P18 ?image}.
     ?person wdt:P19 ?birthplace
  OPTIONAL {?birthplace wdt:P625 ?coord. }
   OPTIONAL {
    ?birthplace p:P625 ?statement.
    ?statement psv:P625 ?node.
    ?node wikibase:geoLatitude ?lat.
    ?node wikibase:geoLongitude ?lon.
   }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

NAS occupation computer sci

The following query uses these:

Items: computer scientist (Q82594)

Properties: National Academy of Sciences member ID (P5380)  

, transport network (P16)  

SELECT ?person ?personLabel ?NASid
WHERE 
{
  ?person wdt:P5380 ?NASid.
  ?person wdt:P16 ?occupation.
  ?occupation wdt:P31/wdt:P279* wd:Q82594.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Orgs Supporting Digital

Return an image grid of all institutions that are members of DLF

The following query uses these:

Items: Digital Library Federation (Q5275906)

Properties: member of (P463)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid 
SELECT ?memberLabel ?image WHERE {
  ?member wdt:P463 wd:Q5275906.
  ?member wdt:P18 ?image.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of all members of DLF

The following query uses these:

Items: Digital Library Federation (Q5275906)

Properties: member of (P463)  

SELECT ?memberLabel WHERE {
  ?member wdt:P463 wd:Q5275906.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of all members of JISC

The following query uses these:

Items: Jisc (Q6269240)

Properties: member of (P463)  

SELECT ?memberLabel WHERE {
  ?member wdt:P463 wd:Q6269240.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Software developed by members of JISC

The following query uses these:

Items: Jisc (Q6269240)

Properties: member of (P463)  

, developer (P178)  

SELECT ?member ?memberLabel ?software ?softwareLabel WHERE {
  ?member wdt:P463 wd:Q6269240.
  ?software wdt:P178 ?member.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a map plotted with the geo coordinates for the locations of JISC member institutions

The following query uses these:

Items: Jisc (Q6269240)

Properties: member of (P463)   , headquarters location (P159)   , coordinate location (P625)

Features: map (Q24515275)  

#defaultView:Map
PREFIX psv: <http://www.wikidata.org/prop/statement/value/>

SELECT ?orgLabel ?hqLabel ?coord ?lat ?lon WHERE {
  ?org wdt:P463 wd:Q6269240.
  ?org wdt:P159 ?hq.
  OPTIONAL { ?hq wdt:P625 ?coord. }
  OPTIONAL {
    ?hq p:P625 ?statement.
    ?statement psv:P625 ?node.
    ?node wikibase:geoLatitude ?lat.
    ?node wikibase:geoLongitude ?lon.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a map plotted with the geocoordinates for the locations of DLF member institutions

The following query uses these:

Items: Digital Library Federation (Q5275906)

Properties: member of (P463)   , headquarters location (P159)   , coordinate location (P625)

Features: map (Q24515275)  

#defaultView:Map
PREFIX psv: <http://www.wikidata.org/prop/statement/value/>
SELECT ?orgLabel ?hqLabel ?coord ?lat ?lon WHERE {
  ?org wdt:P463 wd:Q5275906.
  ?org wdt:P159 ?hq.
  OPTIONAL { ?hq wdt:P625 ?coord. }
  OPTIONAL {
    ?hq p:P625 ?statement.
    ?statement psv:P625 ?node.
    ?node wikibase:geoLatitude ?lat.
    ?node wikibase:geoLongitude ?lon.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a map plotted with the locations of ARL member institutions

The following query uses these:

Items: Association of Research Libraries (Q4810036)

Properties: member of (P463)   , headquarters location (P159)   , coordinate location (P625)

Features: map (Q24515275)  

PREFIX psv: <http://www.wikidata.org/prop/statement/value/>

#defaultView:Map
SELECT ?orgLabel ?hqLabel ?coord ?lat ?lon WHERE {
  ?org wdt:P463 wd:Q4810036.
  ?org wdt:P159 ?hq.
  OPTIONAL { ?hq wdt:P625 ?coord. }
  OPTIONAL {
    ?hq p:P625 ?statement.
    ?statement psv:P625 ?node.
    ?node wikibase:geoLatitude ?lat.
    ?node wikibase:geoLongitude ?lon.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

ARL member institutions that have a Twitter username in Wikidata

The following query uses these:

Items: Association of Research Libraries (Q4810036)

Properties: member of (P463)  

, X username (P2002)  

SELECT DISTINCT ?memberLabel ?twitter WHERE {
  ?member wdt:P463 wd:Q4810036.
  ?member wdt:P2002 ?twitter
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Overlap between ARL and ORCID memberships

The following query uses these:

Items: Association of Research Libraries (Q4810036)   , ORCID, Inc. (Q19861084)

Properties: member of (P463)  

SELECT DISTINCT ?memberLabel  WHERE {
  ?member wdt:P463 wd:Q4810036.
  ?member wdt:P463 wd:Q19861084.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Organizations that are members of ORCID and JISC

The following query uses these:

Items: Jisc (Q6269240)   , ORCID, Inc. (Q19861084)

Properties: member of (P463)  

SELECT DISTINCT ?memberLabel WHERE {
  ?member wdt:P463 wd:Q6269240.
  ?member wdt:P463 wd:Q19861084.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Web archives

The following query uses these:

Items: web archive (Q30047053)

Properties: instance of (P31)  

SELECT ?item ?label  WHERE {
  ?item wdt:P31 wd:Q30047053.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

Organizations and their Name Assigning Authority Numbers

The following query uses these:

Properties: ARK Name Assigning Authority Number (P1870)  

SELECT ?institution ?institutionLabel ?value 
{
	?institution wdt:P1870 ?value .
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
}

Digital Libraries

The following query uses these:

Items: digital library (Q212805)

Properties: subclass of (P279)  

, official website (P856)  

SELECT ?lib ?libLabel ?url
WHERE {
  ?lib (p:P31/ps:P31/wdt:P279*) wd:Q212805.
  ?lib wdt:P856 ?url.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Institutions with memberships to the DPC and other organizations of which they are also members

The following query uses these:

Items: Digital Preservation Coalition (Q5275956)

Properties: member of (P463)  

#defaultView:Dimensions
SELECT ?memberLabel ?othersLabel

WHERE {
   	?member	wdt:P463 wd:Q5275956 .
    ?member	wdt:P463 ?others .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Institutions with memberships to the OPF and other organizations of which they are also members

The following query uses these:

Items: Open Preservation Foundation (Q27981723)

Properties: member of (P463)  

#defaultView:Dimensions
SELECT ?memberLabel ?othersLabel

WHERE {
   	?member	wdt:P463 wd:Q27981723.
    ?member	wdt:P463 ?others .
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Institutions that are members of the OPF and images

The following query uses these:

Items: Open Preservation Foundation (Q27981723)

Properties: member of (P463)  

, image (P18)  

SELECT ?member ?memberLabel ?image

WHERE {
   	?member	wdt:P463 wd:Q27981723 .
    ?member wdt:P18 ?image.
            
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Return an image grid of organizations that are members of the International Internet Preservation Consortium

The following query uses these:

Items: International Internet Preservation Consortium (Q697497)

Properties: member of (P463)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT DISTINCT ?memberLabel ?image WHERE {
  ?member wdt:P463 wd:Q697497.
  ?member wdt:P18 ?image
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of all metadata registries and their websites

The following query uses these:

Items: metadata registry (Q3423635)

Properties: subclass of (P279)  

, official website (P856)  

SELECT ?lib ?libLabel ?url WHERE {
  ?lib (p:P31/ps:P31/wdt:P279*) wd:Q3423635.
  ?lib wdt:P856 ?url.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Return a list of software titles developed by people/orgs that have archival material at the Computer History Museum

The following query uses these:

Items: Computer History Museum (Q964035)

Properties: archives at (P485)  

, developer (P178)  

SELECT  ?person ?personLabel   ?software ?softwareLabel

WHERE {
  ?person wdt:P485 wd:Q964035 .
  ?software wdt:P178 ?person.
 
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

Supporters of IOC

The following query uses these:

Items: Initiative for Open Citations (Q29188397)

Properties: P1962, logo image (P154)  

SELECT ?supporter ?supporterLabel ?logo WHERE {
  wd:Q29188397 wdt:P1962 ?supporter.
  OPTIONAL {?supporter wdt:P154 ?logo.}
 SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
}
  }

Software titles developed by members of OPF

The following query uses these:

Items: Open Preservation Foundation (Q27981723)

Properties: member of (P463)  

, developer (P178)  

SELECT ?member ?memberLabel ?software ?softwareLabel WHERE {
  ?member wdt:P463 wd:Q27981723.
  ?software wdt:P178 ?member.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

IIIF

Return a list of all members of the IIIF Consortium

The following query uses these:

Items: IIIF Consortium (Q35677307)

Properties: member of (P463)  

SELECT ?memberLabel  WHERE {
  ?member wdt:P463 wd:Q35677307.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Create a map with the coordinates of all orgs that are members of IIIF Consortium

YCBA

Female Printmakers

Female Printmakers 1700s

FRBR in Wikidata

Works and their editions

Document Typesetting

Applications that depend on TeX

Commands for Tex and Latex

Digital Preservation

Wikidata

Return a list of people who have accounts on Wikidata listed in Wikidata

Architecture

Return a list of CT buildings for which we know the architect

Return an image grid of CT buildings for which we know the architect

Return an image grid of IL buildings for which we know the architect

Return an image grid of PA buildings for which we know the architect

Return a list of architects and the institutions that hold their papers

Return a map of the architecture firms w/ geocoodinates of their headquarters in Wikidata

Return an image grid of ICAM members

Return a list of all members of ICAM

Computer Network Protocol

Return a list of computer network protocol

Return a list of all protocols that have data about the associated RFC

Return a list of protocols and the ports they use

Standards

Return a list of standards from the W3C along with what type of thing they govern

Return a bubble chart visualization of standards bodies by the number of standards they are connected to in Wikidata

Algorithms

Return a list of algorithms and the tasks they are used to solve

GAS graph of the subclasses of algorithm

Items with an entry in the Dictionary of Data Structures and Alogrithms

Platforms

Return a list of all software that runs on the Amiga platform

X as a Service

All Subclasses of "as a Service"

Instances of software as a service

Programming Languages

Langs influenced by smalltalk

Graph of subclasses of programming language

Unmanned vehicles

GAS graph of the subclasses of unmanned vehicle

Drones

Subclasses of unmanned aerial vehicle

Graph of the subclasses of unmanned aerial vehicle

Cryptocurrencies

What cryptocurrencies are described in Wikidata

Cryptocurrencies named after people or things

Cryptocurrencies and the type of proof they use

Return an image grid of the people or things after which cryptocurrencies are named

Image grid of logos for cryptocurrencies

Malware

(GAS) graph of subclasses of malware

Computer worms and pictures of what they are named after

Knowledge Organization

Transatlantic communications cables

Return a map plotted with the terminus coordinates of transatlantic cables

Robots

Return an image grid of robots

Return a (GAS) graph of the subclasses of robot

Bots

Chatbots

Chatbots by dev and date

Smart Speakers

Return a list of smart speakers

Smart Speakers and the virtual assistants they employ

Digital Art

Return an image grid of people who are in the compArt database Digital Art (daDA) of the University of Bremen

TO FIX

federated

YCBA

IDEs and programming languages

It is unclear to me if we are all using these props consistently. Does programming language here mean the lang the IDE is written in, or does it mean the lang the IDE can be used to support? Template:SPARQL2

Bridges

Plot a map of covered bridges

Romanian settlement with wrong diacritics in non-ro and non-tr labels

Forests

Return a graph of subclasses of forest

Bibliographies

Instances of bibliography

Instances of bibliography and the topics they cover

Computer Science

GAS graph of subclasses of computer science

Named After

Cycling teams named after software

Yale

Genes named after fictional characters and the scientific articles in which these names were established

Airports that "have facility" wifi