User:Tsaorin/TallerCongreso

From Wikidata
Jump to navigation Jump to search

TALLER DE FORMACIÓN SOBRE WIKIDATA · Abril 2019

Guión de la sesión[edit]

Taller intenstivo Verificabilidad[edit]

Mañana
  • Wikipedia y actualidad. Verificabilidad.
  • Crowdsourced Open Data y Vandalismo de datos.
  • Diferencia entre muchas Wikipedias (textos) y un único bando de datos factuales central (desde el cual se pretende unificar las fichas infobox típicas de los artículos, como resultado tangible primario)
  • Cómo introducir datos, entender la estructura de declaraciones, items y propiedades. Ver la realización de referencias de verificabilidad y cualificaciones sobre los datos.
  • Acceso y consumo de datos : API y SPARQL. Aplicaciones.
Tarde
  • Ejemplos paso a paso de interrogación SPARQL para "descubrir" información no visible a primera vista (¿Qué actrices que participaron en películas de Chaplin estaban casadas con actores que habían rodado bajo la órdenes de Cecil B. deMille?
  • Wikidata como ontología colaborativa, estructura de clases y modelado abierto de datos.
  • Wikibase como plataforma de datos: Periodismo, Acción cívica, ciencia ciudadana, …

Otros formatos[edit]

Seminario[edit]

  • Wikidata, Wikipedia y Commons.
  • Qué es un dato: hechos, factoids, valores y vínculos
Publicación de datos
  • La estructura de datos de Wikidata:
    • ítems
    • propiedades
    • Labels, Identificadores y wikienlaces
    • declaraciones: cualificadores, referencias y ranks
  • Publicación y enriquecimiento de datos
  • Vinculación con catálogos y registros de autoridad
  • La ontología de Wikidata: jerarquía de clases, jerarquía de propiedades
    • P31 vs. P279
    • RDF, Dbpedia, Schema
Consumo de datos
  • Wikidata Query Service y SPARQL
  • Uso de Wikidata en proyectos Wikimedia: interwiki, infoboxes, listados, Commons
  • Herramientas experimentales con Wikidata
  • Proyectos GLAM powered by Wikidata
  • Presentación piloto de infoLAB Wikidata RM, “descripción de contenido de literatura de ficción”

Curso de formación[edit]

Sesión 1

  • Wikidata, Wikipedia y Commons
  • Wikidata y DBpedia
  • Qué es un dato: hechos, factoids, valores y vínculos
  • La estructura de datos de Wikidaat: ítems, propiedades, declaraciones, cualificadores, referencias y ranks
  • Publicación y enriquecimiento de datos
  • Vinculación con catálogos y registros de autoridad
  • La ontología de Wikidata: jerarquía de clases, jerarquía de propiedades

Sesión 2

  • Wikidata Query Service y SPARQL
  • Uso de Wikidata en proyectos Wikimedia: interwiki, infoboxes, listados, Commons

Sesión 3

  • Herramientas experimentales con Wikidata
  • Proyectos GLAM powered by Wikidata
  • Presentación piloto de infoLAB Wikidata RM, “descripción de contenido de literatura de ficción”

Materiales guía[edit]

Esquemas en-una-página
infoLAB BRMU para describir contenido de ficción literaria

Enlaces prácticos[edit]

Materiales y referencias[edit]

Ejemplos de consultas[edit]

Personas nacidas en el País Vasco[edit]

Búsqueda recursiva por pertenencia a entidad territorial administrativa P131. 

SELECT ?persona ?personaLabel ?lugar
WHERE {
?persona wdt:P19 ?lugar . # lugar de nacimiento
?lugar wdt:P131* wd:Q3995 # situado en la entidad territorial administrativa (recursiva) País Vasco
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}

Primeras líneas de obras en español[edit]

SELECT ?item ?itemLabel ?inicio ?autorLabel
WHERE 
{
  ?item wdt:P407 wd:Q1321 . #idioma español
  ?item wdt:P50 ?autor . # autor
  ?item wdt:P1922 ?inicio .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}

Capitales de todos los países de la UE[edit]

SELECT ?country ?countryLabel ?capitalLabel ?population 
WHERE 
{
  ?country wdt:P463 wd:Q458.
  ?country wdt:P36 ?capital.
  ?capital wdt:P1082 ?population.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "   [AUTO_LANGUAGE],en". }
}

Cuadrícula con foto de los premios nobel de física[edit]

#defaultView:ImageGrid
SELECT ?person ?personLabel ?image
WHERE 
{
  ?person wdt:P18 ?image;
          wdt:P166 wd:Q38104.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Mapa de países que usan el teléfono 112 de emergencias[edit]

#defaultView:Map
SELECT ?country ?countryLabel ?location
WHERE {
 ?country wdt:P2852 wd:Q1061257;
           wdt:P625 ?location.
  
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}


Campos de actividad de Alan Turing[edit]

SELECT ?campo ?campoLabel {
wd:Q7251 wdt:P101 ?campo
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Personas muertas[edit]

SELECT ?entity (year(?date) as ?year) WHERE {
?entity wdt:P570 ?date .
FILTER (datatype(?date) = xsd:dateTime)
FILTER (year(?date) = year(now()))
}
 LIMIT 100

Personas fallecidas en 1937[edit]

SELECT ?autor ?autorLabel (year(?date) as ?year) WHERE {
  ?autor wdt:P570 ?date .
  ?autor wdt:P27 wd:Q29 .
  FILTER (datatype(?date) = xsd:dateTime)
  FILTER (year(?date) = 1937)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Autores españoles que entran en el dominio público este año[edit]

SELECT ?autor ?autorLabel (year(?date) as ?year) WHERE {
  ?autor wdt:P570 ?date .
  ?autor wdt:P27 wd:Q29 .
  ?autor wdt:P106 ?ocupacion .
  ?ocupacion wdt:P279* wd:Q36180 .
         FILTER (datatype(?date) = xsd:dateTime)
         FILTER (year(?date) = 1937)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Creadores españoles que entran en el dominio público[edit]

SELECT ?autor ?autorLabel ?ocupacionLabel (year(?date) as ?year) WHERE {
  ?autor wdt:P570 ?date .
  ?autor wdt:P27 wd:Q29 .
  ?autor wdt:P106 ?ocupacion .
  ?ocupacion wdt:P279* wd:Q482980 .
         FILTER (datatype(?date) = xsd:dateTime)
         FILTER (year(?date) = 1937)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Directores de películas inspiradas en Hamlet[edit]

SELECT ?obra ?obraLabel ?directorLabel ?generoLabel ?year 
WHERE {
?obra wdt:P144 wd:Q41567 .
  ?obra wdt:P577 ?year .
  ?obra wdt:P57 ?director .
  OPTIONAL {?obra wdt:P136 ?genero }
         SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Personajes de obras literarias asesinados y su asesino[edit]

select ?personaje ?personajeLabel ?asesinoLabel Where {
?personaje wdt:P31 wd:Q3658341 .
  ?personaje wdt:P1441 wd:Q8337 .
  ?personaje wdt:P157 ?asesino
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Año de creación de La libertad guiando al pueblo[edit]

SELECT (year(?DateCrea) as ?AnneeCrea) WHERE {
wd:Q29530 wdt:P571 ?DateCrea 
}

Cuadros pintados el mismo año que La Libertad guiando al pueblo[edit]

SELECT ?cuadroLabel ?autorLabel (year(?DateCrea) as ?AnneeCrea)
WHERE {
  wd:Q29530 wdt:P571 ?DateCrea .
  ?cuadro wdt:P571 ?DateCrea .
  ?cuadro wdt:P31 wd:Q3305213 .
  ?cuadro wdt:P170 ?autor .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Cuadros que representan caballos en el barroco[edit]

SELECT ?cuadro ?cuadroLabel ?autorLabel (year(?DateCrea) as ?AnneeCrea)
WHERE {
  ?cuadro wdt:P31 wd:Q3305213 .
       ?cuadro wdt:P571 ?DateCrea .
       ?cuadro wdt:P180 wd:Q726 .
?cuadro wdt:P135 wd:Q37853 .
       ?cuadro wdt:P170 ?autor 
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
}

Personas relevantes nacidas en Londres[edit]

SELECT (COUNT(DISTINCT ?item) AS ?total)
WHERE {
  ?item wdt:P19 wd:Q84
      }

Obras de Vermeer por año de creación[edit]

SELECT ?obra ?obraLabel (year(?DateCrea) as ?AnneeCrea)
WHERE {
  ?obra wdt:P170 wd:Q41264 ;
                  wdt:P571 ?DateCrea.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"  }
} ORDER BY ?AnneeCrea

Gráfico de área de libros por año de publicación y genero en narrativa, desde el año 2000[edit]

Incluye datos de cualificadores 

#Libros escritos por año y genero desde 2000
#defaultView:AreaChart
SELECT ?cid (STR(SAMPLE(?year)) AS ?year) (COUNT(*) AS ?count) ?genero WHERE {
   ?pid wdt:P31 wd:Q571;  # libro   
        wdt:P50 ?autor; # autor 
       wdt:P136 ?cid;  # genero
       wdt:P577 ?_date_of_pub. # fecha de publicación
  ?cid wdt:P279* wd:Q1318295.  # tipo de genero narrativo
  ?autor wdt:P27 wd:Q29 # nacionalidad autor España
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
                         ?cid rdfs:label ?genero. }
  BIND ( YEAR(?_date_of_pub) AS ?year )
  FILTER( ?year >= 2000 )
}
GROUP BY ?cid ?genero ?year

Premios recibidos por Muñoz Molina cada año[edit]

Incluye datos de cualificadores 

SELECT ?item ?itemLabel (year(?edicion) as ?year) WHERE {
wd:Q450335 p:P166 ?statement .
?statement ps:P166 ?item.
  ?statement pq:P585 ?edicion
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}

Partes de catedrales registradas en Wikidata[edit]

SELECT ?cosaLabel (COUNT(?item) as ?partes)
WHERE 
{
  ?item wdt:P361 ?cosa . #Parte de catedral Notre Dame
  ?cosa wdt:P31 ?catedral .
  ?catedral wdt:P279* wd:Q2977
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
GROUP BY ?cosaLabel
ORDER BY ?partes

Premios ganados por vascos[edit]

Recursiva por P131 entidad territorial y obtención de cualificador P585 Fecha. Premio y año 

SELECT ?persona ?personaLabel ?item ?itemLabel (year(?edicion) as ?year) WHERE {
?persona wdt:P19 ?lugar . # lugar de nacimiento
?lugar wdt:P131* wd:Q3995 . # situado en la entidad territorial administrativa (recursiva) País Vasco
  ?persona p:P166 ?statement . #existencia de statement P166 premio recibido
?statement ps:P166 ?item. # Obtención desde el statement del premio recibido
  ?statement pq:P585 ?edicion # Obtención del cualificador P585 Fecha
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en,eu". }
}
ORDER BY ?personaLabel

¿En qué paises hay más puentes?[edit]

Gráfico de barras para los 20 países con más puentes. Recursiva por P279 subclase. 

#defaultView:BarChart
SELECT ?paisLabel (COUNT(?item) as ?num)
WHERE {
  ?item wdt:P17 ?pais .
  ?item wdt:P31 ?tipo . # Tipo del item
  ?tipo wdt:P279* wd:Q12280 . # tipo subclase recursiva de PUENTE
  
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en,eu". }
}
GROUP BY ?paisLabel
ORDER BY DESC(?num)
LIMIT 20

Grafo de organizaciones y periodistas[edit]

#Periodistas agrupados por pertenencia de grupos/colectivos/organizaciones
#defaultView:Graph
SELECT ?char ?charLabel ?group ?groupLabel ("7FFF00" as ?rgb)
WHERE {
 ?char wdt:P106 wd:Q1930187 . # ocupación periodista
  ?char wdt:P27 wd:Q29 . # nacionalidad española
  ?char wdt:P463 ?group # member de una organización
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".}
}

Consultas sobre clases y esquemas[edit]

Wikidata como ontología o vocabulario de clases

Propiedades para describir cosas de un "dominio"[edit]

Podemos obtener el esquema de descripción (Propiedades) que se usan al describir cosas en el universo de ficción de Star Trek (Q18043309) 

SELECT DISTINCT ?propiedadLabel ?p ?dominioLabel (COUNT(?sujeto) AS ?num) WHERE
{
VALUES ?dominio {wd:Q18043309}
?sujeto ?propiedad_dominio ?dominio;
?p ?objeto.
?propiedad wikibase:directClaim ?p.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
GROUP BY ?propiedadLabel ?p ?dominioLabel

Clases de un dominio[edit]

Consulta para sabre los elementos que son usados como clases para organizar el dominio "Star Trek" 

SELECT DISTINCT ?clase ?claseLabel ?propiedad_clase_subclase ?superclase ?superclaseLabel (COUNT(?sujeto) AS ?num) WHERE
{
VALUES ?dominio {wd:Q18043309}
VALUES ?propiedad_clase_subclase {
wdt:P279 wdt:P31 wdt:P361 wdt:P1269
}
?sujeto ?propiedad_dominio ?dominio;
wdt:P31 ?clase.
?clase ?propiedad_clase_subclase ?superclase.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en,eu". }
}
GROUP BY ?clase ?claseLabel ?propiedad_clase_subclase
?superclase ?superclaseLabel

Propiedades más usadas en un dominio[edit]

Conteo del uso de clases en elementos del universo de Star Trek. 

SELECT DISTINCT ?propiedadLabel ?p ?dominioLabel (COUNT(?sujeto) AS ?num) WHERE
{
VALUES ?dominio {wd:Q18043309}
?sujeto ?propiedad_dominio ?dominio;
?p ?objeto.
?propiedad wikibase:directClaim ?p.
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en"}
}
GROUP BY ?propiedadLabel ?p ?dominioLabel
ORDER BY DESC(?num)
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Tsaorin/TallerCongreso&oldid=1570884791"