User:SAPA bdc/SPARQL

From Wikidata
Jump to navigation Jump to search

SPARQL Wikidata

[edit]

Archives en Suisse

[edit]
#ensemble des institutions d'archives en Suisse, emcore en activité, qui ne sont ni des archives commnunales ou cantonales, ou des archives d'entreprise.
SELECT DISTINCT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q166118 ;
        wdt:P17 wd:Q39.
  MINUS {?item wdt:P31 wd:Q604177}.
  MINUS {?item wdt:P31 wd:Q2860410}.
  MINUS {?item wdt:P31 wd:Q10605195}.
  MINUS {?item wdt:P576 ?dissolution}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de, it, en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
Try it!

SAPA

[edit]
#Elément disposant d'une corrrespondance dans la platefomre SAPA
SELECT ?item ?itemLabel ?ID_SAPA 
WHERE {
  ?item wdt:P8974 ?ID_SAPA.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 20.09.2021 : 21'350 résultats
#les éléments dans Wikidata disposant d'une ID SAPA par type
SELECT ?type ?typeLabel (COUNT(?type) AS ?count)
WHERE 
{
  ?item wdt:P8974 [];
        wdt:P31 ?type.#
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
GROUP BY ?type ?typeLabel ?count
ORDER BY DESC (?count)
Try it!

Scènes en Suisse

[edit]
# Liste des scène dans lesquelles se sont produites les productions des arts de la scène (Q43099500) (ou l'une de ses sous-classes) qui a eu lieu (P276) dans une salle de spectacle établit en Suisse (qui n'est pas contenu dans le Schauspielhaus de Zurich).
SELECT DISTINCT ?salle ?salleLabel?naturesalle ?naturesalleLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P31 ?nature2;
        wdt:P276 ?salle.
  VALUES ?nature {wd:Q43099500}.       
  ?salle wdt:P17 wd:Q39;
         wdt:P31 ?naturesalle
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en". }
}
Try it!

Personnes

[edit]
#Personne connue de Wikidata disposant d'un ID et d'un dossier documentaire chez SAPA, morte avant 1952 et pour laquelle aucune image n'est diposnible dans Wikdiata.
SELECT DISTINCT ?person ?personLabel ?mort ?naissanceLabel
WHERE 
{
  ?person wdt:P8974 [];# élément avec un ID SAPA
        wdt:P10527 wd:Q50920401; #un dossier documentaire chez nous
        wdt:P570 ?mort;
  FILTER (?mort < "1952-01-01T00:00:00Z"^^xsd:dateTime).
  MINUS {?person wdt:P18 ?image}.
  OPTIONAL {?person wdt:P19 ?naissance}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
Try it!
  • 183 (06.10.2022)

Productions

[edit]

Voir modèle de données.

Oeuvres

[edit]

instance of (P31) : 

# nombre des éléments dans Wikidata étant une oeuvre scénique.
SELECT (COUNT(?item) AS ?count) 
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q17538722.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 17'009 (28.09.2021)

Productions

[edit]
# nombre des éléments dans Wikidata étant une production des arts de la scène.
SELECT (COUNT(?item) AS ?count) 
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q43099500.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 19'993 (28.09.2021)
#les différents types d'éléments de Wikidata étant une production des arts de la scène par type
SELECT ?type ?typeLabel (COUNT(?type) AS ?count) 
WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q43099500;
                              wdt:P31 ?type.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?typeLabel ?type ?count
ORDER BY DESC (?count)
Try it!

Productions en Suisse

[edit]

Productions définies par la société de production suisse

Attention : il existe une erreur parmi les résultats par une confusion entre Théâtre de la Ville (Q29948033) (Genève) et Théâtre de la Ville (Q111658694) (Paris). À corriger. 

# Liste des productions des arts de la scène (Q43099500) (ou l'une de ses sous-classes) dont l'une des société de production est suisse.
SELECT ?item ?itemLabel ?periodeLabel ?production
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P272 ?production.
  VALUES ?nature {wd:Q43099500}.#qui est une production des arts de la scène
  ?production wdt:P17 wd:Q39.#la société de production est située en Suisse.
  MINUS {?item wdt:P31 ?nature2}.
  VALUES ?nature2 {wd:Q182832}.#qui n'est pas un concert 
  OPTIONAL {?item wdt:P2348 ?periode}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en". }
}
Try it!

Résultats:

  • 1'639 (19.04.2022)
# Liste des productions des arts de la scène (Q43099500) (ou l'une de ses sous-classes) dont l'une des société de production est suisse (moins celles qui ont déjà une salle de représentation)
SELECT ?item ?itemLabel ?periodeLabel ?production ?productionLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P272 ?production.
  VALUES ?nature {wd:Q43099500}.#qui est une production des arts de la scène
  ?production wdt:P17 wd:Q39.#la société de production est située en Suisse.
  MINUS {?item wdt:P31 ?nature2}.
  VALUES ?nature2 {wd:Q182832}.#qui n'est pas un concert
  MINUS {?item wdt:P276 ?salle}.#moins ceux qui ont déjà une salle de représentation
  OPTIONAL {?item wdt:P2348 ?periode}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en". }
}
Try it!

Résultats:

  • 943 (19.04.2022)

Questions : 


# Liste des productions des arts de la scène (Q43099500) (ou l'une de ses sous-classes) dont l'une des société de production est suisse (sauf Schauspielhaus ZH).
SELECT ?item ?itemLabel ?periodeLabel ?production ?productionLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P272 ?production.
  VALUES ?nature {wd:Q43099500}.#qui est une production des arts de la scène
  ?production wdt:P17 wd:Q39.#la société de production est située en Suisse.
  VALUES ?minus {wd:Q40313234}.
  MINUS {?item wdt:P272 ?minus}.#la société de production n'est pas le Schauspielhaus ZH
  MINUS {?item wdt:P31 ?nature2}.
  VALUES ?nature2 {wd:Q182832}.#qui n'est pas un concert 
  OPTIONAL {?item wdt:P2348 ?periode}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en". }
}
Try it!

Résultats:

  • 630 (19.04.2022)

Productions définies par le lieu de représentation 

# Liste des productions des arts de la scène (Q43099500) (ou l'une de ses sous-classes) qui a eu lieu (P276) dans une salle de spectacle établit en Suisse
SELECT ?item ?itemLabel ?periodeLabel ?salleLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P276 ?salle.
  VALUES ?nature {wd:Q43099500}.#qui est une production des arts de la scène
   ?salle wdt:P17 wd:Q39.#la salle est situé en Suisse.
  MINUS {?item wdt:P31 ?nature2}.
  VALUES ?nature2 {wd:Q182832}.#qui n'est pas un concert 
  OPTIONAL {?item wdt:P2348 ?periode}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en". }
}
Try it!
  • 716 résultats (19.04.2022)
# Liste des productions des arts de la scène (Q43099500) (ou l'une de ses sous-classes) qui a eu lieu (P276) dans une salle de spectacle établit en Suisse (qui n'est pas le Schauspielhaus)
SELECT ?item ?itemLabel ?periodeLabel ?salleLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P276 ?salle.
  VALUES ?nature {wd:Q43099500}.#qui est une production des arts de la scène
   ?salle wdt:P17 wd:Q39.#la salle est situé en Suisse.
  MINUS {?salle wdt:P361 wd:Q675022}.#la salle ne fait pas partie du Schauspielhaus ZH
  MINUS {?item wdt:P31 ?nature2}.
  VALUES ?nature2 {wd:Q182832}.#qui n'est pas un concert 
  OPTIONAL {?item wdt:P2348 ?periode}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en". }
}
Try it!
  • 113 (19.04.2022)

Personnes (distribution) des productions en Suisse

[edit]
# Liste des acteurs et actrices appartenant à une distribution d'une production des arts de la scène (Q43099500) (ou l'une de ses sous-classes) qui a eu lieu (P276) dans une salle de spectacle établit en Suisse
SELECT ?acteurs ?acteursLabel (GROUP_CONCAT(DISTINCT ?salle;separator=", ") AS ?salles)
WHERE 
{
  ?item wdt:P31/wdt:P279* ?nature;
        wdt:P276 ?salle;
        wdt:P161 ?acteurs.
  VALUES ?nature {wd:Q43099500}.       
  ?salle wdt:P17 wd:Q39.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,it,en".
                         ?salle rdfs:label ?salleLabel .
                         ?acteurs rdfs:label ?acteursLabel .} 
}
GROUP BY ?acteurs ?acteursLabel
Try it!

Représentation

[edit]
# nombre des éléments dans Wikidata disposant d'une ID SAPA et étant une oeuvre scénique.
SELECT DISTINCT (COUNT(?item) AS ?count)
WHERE 
{
  ?item wdt:P8974 [];
        wdt:P31/wdt:P279* wd:Q17538722.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 1 élément (28.09.2021)

Organisations

[edit]

instance of (P31) : 

#les éléments dans Wikidata disposant d'une ID SAPA et étant une organisation par type
SELECT ?type ?typeLabel (COUNT(?type) AS ?count) 
WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q43229.
  hint:Prior hint:gearing "forward".
  ?item wdt:P8974 [].
  hint:Prior hint:runFirst true.
  ?item wdt:P31 ?type.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?typeLabel ?type ?count
ORDER BY DESC (?count)
Try it!

Unités territoriales

[edit]
#les éléments dans Wikidata disposant d'une ID SAPA et étant une entité territoriale administrative par type
SELECT ?type ?typeLabel (COUNT(?type) AS ?count)
WHERE 
{
  ?item wdt:P8974 [];
        wdt:P31/wdt:P279* wd:Q56061;
        wdt:P31 ?type.#
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
GROUP BY ?type ?typeLabel ?count
ORDER BY DESC (?count)
Try it!

Etres humains

[edit]
#Personnes dans SAPA et TLS mort avant juin 1952 (70 ans)
SELECT ?item ?itemLabel ?died ?SAPA ?wde ?wfr
WHERE 
{
  ?item wdt:P8974 ?SAPA;
        wdt:P1362 []; # doit avoir comme nature chat
   wdt:P570 ?died.
  filter (?died < "1952-06-30T00:00:00Z"^^xsd:dateTime). 
  OPTIONAL {?wde schema:about ?item.
    ?wde schema:isPartOf <https://de.wikipedia.org/>.}
    OPTIONAL {?wfr schema:about ?item.
    ?wfr schema:isPartOf <https://fr.wikipedia.org/>.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
LIMIT 100
Try it! 
#Personne humaine connue de Wikidata disposant d'une corrrespondance dans la platefomre SAPA
SELECT ?item ?itemLabel ?ID_SAPA 
WHERE {
  ?item wdt:P31 wd:Q5;
        wdt:P8974 ?ID_SAPA.  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 20.09.2021 : 13'909 résultats

Avec ID SAPA et ID DHS 

#Personne humaine connue de Wikidata disposant d'un ID externe SAPA et d'une ID externe DHS
SELECT DISTINCT ?item ?itemLabel ?ID_SAPA
WHERE {
  ?item wdt:P31 wd:Q5;
        wdt:P8974 ?ID_SAPA;
        wdt:P902 []
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 11.10.2021 : 852 résultats

Avec une déclaration archivé par 

#Personne humaine connue de Wikidata disposant d'une corrrespondance dans la platefomre SAPA et d'une déclaration "archivé par"
SELECT DISTINCT ?item ?itemLabel ?ID_SAPA
WHERE {
  ?item wdt:P31 wd:Q5;
        wdt:P8974 ?ID_SAPA;
        wdt:P485 [].
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 11.10.2021 : 800

Nées à Berne 

#Personnes humaines connues de Wikidata disposant d'une corrrespondance dans la platefomre SAPA et nées à Berne
SELECT ?item ?itemLabel ?ID_SAPA 
WHERE {
  ?item wdt:P31 wd:Q5;
        wdt:P8974 ?ID_SAPA;
        wdt:P19 wd:Q70.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • 20.09.2021 : 163 résultats
#Personnes physique productrice d'un fonds d'archives conservés par SAPA et connues de Wikdiata (avec mention de leur page Wfr et Wde)
SELECT DISTINCT ?item ?itemLabel ?died ?SAPA ?wde ?wfr
WHERE 
{
  ?item wdt:P8974 ?SAPA;
 VALUES ?item {wd:Q785199 wd:Q47296823 wd:Q4882922 wd:Q1685480 wd:Q124430 wd:Q3289044 wd:Q3089824 wd:Q52557157 wd:Q217764 wd:Q11922266 wd:Q30835773 wd:Q560909 wd:Q560909 wd:Q560909 wd:Q1454003 wd:Q52602044 wd:Q28502575 wd:Q52826981 wd:Q52914956 wd:Q94743727 wd:Q547547 wd:Q95236254 wd:Q23125156 wd:Q15079033 wd:Q44742300 wd:Q3122177 wd:Q3106311 wd:Q588942 wd:Q1574103 wd:Q5460503 wd:Q95238711 wd:Q106017345 wd:Q3290059 wd:Q94891650 wd:Q1904942 wd:Q17038206 wd:Q42749581 wd:Q3380683 wd:Q3297750 wd:Q18816375 wd:Q51163556 wd:Q19606849 wd:Q19840794 wd:Q953586 wd:Q17325931 wd:Q69026970 }. 
  OPTIONAL {?wde schema:about ?item.
    ?wde schema:isPartOf <https://de.wikipedia.org/>.}
    OPTIONAL {?wfr schema:about ?item.
    ?wfr schema:isPartOf <https://fr.wikipedia.org/>.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
Try it! 
#Personnes physique productrice d'un fonds d'archives conservés par SAPA et connues de Wikdiata avec une page Wde et la mention de leur page Wfr si existante.
SELECT DISTINCT ?item ?itemLabel ?SAPA ?archives ?archivesLabel ?wde ?wfr
WHERE 
{
  ?item wdt:P8974 ?SAPA;
 VALUES ?item {wd:Q785199 wd:Q47296823 wd:Q4882922 wd:Q1685480 wd:Q124430 wd:Q3289044 wd:Q3089824 wd:Q52557157 wd:Q217764 wd:Q11922266 wd:Q30835773 wd:Q560909 wd:Q560909 wd:Q560909 wd:Q1454003 wd:Q52602044 wd:Q28502575 wd:Q52826981 wd:Q52914956 wd:Q94743727 wd:Q547547 wd:Q95236254 wd:Q23125156 wd:Q15079033 wd:Q44742300 wd:Q3122177 wd:Q3106311 wd:Q588942 wd:Q1574103 wd:Q5460503 wd:Q95238711 wd:Q106017345 wd:Q3290059 wd:Q94891650 wd:Q1904942 wd:Q17038206 wd:Q42749581 wd:Q3380683 wd:Q3297750 wd:Q18816375 wd:Q51163556 wd:Q19606849 wd:Q19840794 wd:Q953586 wd:Q17325931 wd:Q69026970 }. 
  ?wde schema:about ?item.
    ?wde schema:isPartOf <https://de.wikipedia.org/>.
    OPTIONAL {?wfr schema:about ?item.
    ?wfr schema:isPartOf <https://fr.wikipedia.org/>.}
  OPTIONAL {?item wdt:P485 ?archives}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
Try it!

par canton

[edit]
#Liste des personnes connues de Wikidata, nées dans le Canton de Berne et disposant d'une fiche descriptive dans SPAP
SELECT ?item ?itemLabel ?lieuLabel ?image
WHERE 
{
  ?item wdt:P31 wd:Q5;
        wdt:P8974 ?SAPA_ID;
        wdt:P19 ?lieu;
        wdt:P21 wd:Q6581072;
        wdt:P18 ?image.
        #wdt:P485 wd:Q50920401.
  ?lieu wdt:P131* wd:Q11911.                     
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
LIMIT 10
Try it!

SPARQL SPAP

[edit]

Voir la page dédiée avec la liste de requêtes utiles pour travailler au travers du SPARQL EndPoint de la Swiss Performing Arts Platform.

Demandes

[edit]
Retrieved from "https://www.wikidata.org/w/index.php?title=User:SAPA_bdc/SPARQL&oldid=1930611667"