User:Realworldobject/LRMExamples

Google Research recently published a paper “Everyone wants to do the model work, not the data work”

LRM also doesn't have example data to back up their ontology, so this is an attempt to rationalize it against a dataset that is gaining attention in the LD4 and IFLA library community.

Properties

lrmer:E1A1 "has category of res"

The word "category" in the label and "type" in the description seems to leave the possible values open to interpretation. Is this property equivalent/alternative to rdf:type and assumed to be constrained to one of the LRM classes, or is E1A1 in addition to rdf:type and left open for higher-fidelity use?

Things to note

• Wikidata conflates "version, edition, and translation", which LRM treats differently. I tried to split the hair by treating lrmer:Work as an external subclass of the Wikidata "work" class, which seems true, but that doesn't resolve the conflation in Wikidata. The edition/translation conflation is particularly annoying because a given translation may be published in many different editions.
• LRM things that places and organizations ("Collective Agents") are disjoint, but cities are easier to understand if they are treated as both.

The following query uses these:

• Items: Jane Austen (Q36322)   , London (Q84)   , Pride and Prejudice (Q170583)   , Pride and Prejudice (Q940014)   , Pride and Prejudice (2001 Norton critical ed.) (Q63296184)   

• Properties: instance of (P31)   , subclass of (P279)   , equivalent class (P1709)   , narrower external class (P3950)   , subject named as (P1810)   

  SELECT ?res ?resLabel ?resDescription (GROUP_CONCAT(DISTINCT ?typeLabel;SEPARATOR=" | ") AS ?types) (GROUP_CONCAT(DISTINCT ?hasCategoryOfResLabel;SEPARATOR=" | ") AS ?lrmType)
  WHERE {
    VALUES ?res {
      wd:Q36322 # Jane Austen
      wd:Q84 # London
      wd:Q170583 # Pride and Prejudice (work)
      wd:Q940014 # Pride and Prejudice (film)
      wd:Q63296184 # Pride and Prejudice (manifestation)
    }
    OPTIONAL {
      ?res wdt:P31 ?type .
      ?res wdt:P31/wdt:P279* ?wdType .
      ?wdType p:P1709 | p:P3950 [
        ps:P1709 | ps:P3950 ?hasCategoryOfRes ;
                 pq:P1810 ?hasCategoryOfResLabel
      ].
      FILTER(STRSTARTS(STR(?hasCategoryOfRes), "http://iflastandards.info/ns/lrm/lrmer/"))
    }
    SERVICE wikibase:label { 
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
      ?type rdfs:label ?typeLabel .
      ?res rdfs:label ?resLabel .
      ?res schema:description ?resDescription .
    }
  }
  GROUP BY ?res ?resLabel ?resDescription #?hasCategoryOfRes ?hasCategoryOfResLabel
  ORDER BY ?res
  

Try it!