User:Maxamado

Aides et vrac

Profil et travail de Pmartinolli, pour l'ESR

Sparql et listes de travail

BnF

PREFIX rdagroup2elements: <http://rdvocab.info/ElementsGr2/>
PREFIX isni: <http://isni.org/ontology#>
PREFIX bio: <http://vocab.org/bio/0.1/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX rdarelationships: <http://rdvocab.info/RDARelationshipsWEMI/>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT DISTINCT ?auteur ?name ?isni ?link ?wikidata ?lieuN WHERE {
  ?manif rdarelationships:expressionManifested ?expr ; rdarelationships:electronicReproduction ?URLGallica .
  ?expr dcterms:contributor ?auteur ; dcterms:language <http://id.loc.gov/vocabulary/iso639-2/fre> .
  {?expr <http://data.bnf.fr/vocabulary/roles/r70> ?auteur.} UNION {?expr <http://data.bnf.fr/vocabulary/roles/r680> ?auteur.}
  ?auteur bio:death ?d .
  ?auteur rdagroup2elements:placeOfBirth "Toulouse".
  FILTER (?d > "1900")
  OPTIONAL {?cIsni foaf:focus ?auteur . ?cIsni isni:identifierValid ?isni .}
  OPTIONAL {?auteur foaf:name ?name .}
  OPTIONAL {?auteur foaf:familyName ?lName .}
  ?link <http://xmlns.com/foaf/0.1/focus> ?auteur .
  OPTIONAL {?link <http://www.w3.org/2004/02/skos/core#exactMatch> ?wikidata . FILTER ( CONTAINS(STR(?wikidata) , "http://wikidata.org/" ) ) }
}
ORDER BY ?lName

Requête Sparql Bnf, auteurs et autrices ayant pour ville de naissance Toulouse avant 1900, avec (ou pas) une fiche Wikidata

Personnes nées en Ariège, mais décédées dans un pays autre que la France

SELECT ?personne ?personneLabel ?coord ?mortLabel ?image WHERE {
  ?personne wdt:P19/wdt:P131* wd:Q3184;
    wdt:P20 ?mort.
  ?mort wdt:P625 ?coord.
  OPTIONAL { ?personne wdt:P18 ?image }
  MINUS { ?mort wdt:P17 wd:Q142 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Toulouse FC (équipe masculine)

SELECT ?item ?itemLabel ?nomLabel ?naissanceLabel ?DateNaissanceLabel ?img ?coord ?debut ?fin ?matches ?hauteur WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q937857.
  ?item wdt:P21 wd:Q6581097 .
  OPTIONAL { ?item wdt:P734 ?nom. } 
  OPTIONAL { ?item wdt:P569  ?DateNaissance. } 
  OPTIONAL { ?item wdt:P18 ?img. }
  OPTIONAL { ?item wdt:P2048 ?hauteur. }
  ?item wdt:P19 ?naissance.
  ?naissance wdt:P625 ?coord.
  ?item p:P54 ?tfc.
  ?tfc ps:P54/wdt:P361* wd:Q19518.
  OPTIONAL { ?tfc pq:P580 ?debut. }
  OPTIONAL { ?tfc pq:P582 ?fin. }
  OPTIONAL { ?tfc pq:P1350 ?matches. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr, en". }
}
ORDER BY ?matches

Try it!