User:Gilliane/Tipps/SPARQL-PrixdeLausanne

From Wikidata
Jump to navigation Jump to search

Essais de requêtes SPARQL avec les données du Prix de Lausanne

Liste des participants au Prix de Lausanne (Q673014)[edit]

Problèmes à résoudre :

  • Comment mettre la date en AAAA ?
  • Comment concaténer les entrées multiples dues à plusieurs distinctions reçues et plusieurs nationalités ?
  • Comment ne pas afficher/chercher le deuxième prénom ?
  • Comment ajouter une colonne avec les articles Wikipédia existants ? (et pas que dans une seule langue)
  • Comment ajouter une colonne avec les URL de référence (P854) de la participation (#P1344) à Prix de Lausanne ?
  • Est-il possible d'ajouter les noms en caractères latins, cyrilliques, japonais, chinois et coréens quand ils existent ?
# Participant·e·s au Prix de Lausanne qui ont une entrée dans Wikidata, avec l'année de participation, la distinction reçue et la nationalité

SELECT DISTINCT ?dancer ?Personne ?Nom ?Prénom ?Année ?Distinction ?Pays ?article #(GROUP_CONCAT(DISTINCT(?distinctionLabel); separator=", ") as ?Distinctions)
    WHERE {
    ?dancer wdt:P31 wd:Q5 .  # ajouter instance of human
      { ?dancer wdt:P1344 wd:Q673014 . } # participant à Prix de Lausanne
    UNION
      { ?dancer wdt:P2522 wd:Q673014 . } # victoire à Prix de Lausanne
   OPTIONAL {?dancer p:P1344 ?participation.} # Les éléments qui ont participé
   OPTIONAL {?participation pq:P585 ?Année.} # cherche la date de participation si elle existe
   OPTIONAL {?participation pq:P166 ?distinction.} # cherche la distinction reçue si elle existe
   OPTIONAL { ?dancer wdt:P27 ?citizenship } .   # quelle que soit la nationalité, si pas d'Optional, ne s'affiche que si la nationalité est remplie
   OPTIONAL {?dancer wdt:P734 ?nom } . # nom de famille
   OPTIONAL {?dancer wdt:P735 ?prenom } . # prénom
   OPTIONAL { ?article schema:about ?dancer . ?article schema:isPartOf <https://fr.wikipedia.org/> . }
      
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr,en,es,ja,de,[AUTO_LANGUAGE]".
    ?dancer rdfs:label ?Personne.
    ?nom rdfs:label ?Nom.
    ?prenom rdfs:label ?Prénom.
    ?distinction rdfs:label ?Distinction.
    ?citizenship rdfs:label ?Pays.   } #résultats d'abord en français, autrement en anglais, puis espagnol, ...
}
ORDER BY ?Année
Try it!

Informations de suivi (alumni) : 

# Informations privées sur les participants au Prix de Lausanne

SELECT ?item ?itemLabel ?genreLabel ?employerLabel ?dateofbirth ?dateofdeath ?spouseLabel  # affiche les résultats de ces labels (en langage id Q ou en langage humain si on ajoute Label au label), on peut aussi préciser ici les item

WHERE
{
	# Item Property Value Stop
	?item wdt:P31 wd:Q5 .  # ajouter instance of human
      { ?item wdt:P1344 wd:Q673014 . } # participant à Prix de Lausanne
    UNION
      { ?item wdt:P2522 wd:Q673014 . } # victoire à Prix de Lausanne
	?item wdt:P21 ?genre
	OPTIONAL { ?item wdt:P569 ?dateofbirth } .
  	OPTIONAL { ?item wdt:P570 ?dateofdeath } .
    OPTIONAL { ?item wdt:P26 ?spouse } .
   	OPTIONAL { ?item wdt:P108 ?employer } .   # afficher l'employeur si connu

	SERVICE wikibase:label { bd:serviceParam wikibase:language "ru,ja,es,fr,en,[AUTO_Language]" . }
}
Try it!

Carte avec la provenance des participants au Prix de Lausanne (Q673014)[edit]

#Provenance des participants au Prix de Lausanne, avec images des danseurs
#defaultView:Map
SELECT ?item ?itemLabel ?citizenshipLabel ?coord ?image WHERE {
  ?item wdt:P31 wd:Q5.
  { ?item wdt:P1344 wd:Q673014. }
  UNION
  { ?item wdt:P2522 wd:Q673014. }
  ?item wdt:P27 ?citizenship.
  ?citizenship wdt:P625 ?coord.
  ?item wdt:P18 ?image.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, [AUTO_LANGUAGE]". }
}
Try it!

Graphique avec la provenance des participants au Prix de Lausanne (Q673014)[edit]

#Participants Prix de Lausanne selon leur nationalité, affichage des pays en croate

#defaultView:BubbleChart
SELECT ?citizenshipLabel (COUNT(DISTINCT ?participant) AS ?count) WHERE {
  ?participant wdt:P31 wd:Q5.
  ?participant wdt:P1344 wd:Q673014.
  ?participant wdt:P27 ?citizenship.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hr,fr". }
}
GROUP BY ?citizenshipLabel
ORDER BY DESC(?count)
Try it!

Liste des distinctions/awards distribués lors du concours[edit]

https://w.wiki/NnG 

# Liste des distinctions (en français et anglais) distribuées lors du Prix de Lausanne

SELECT ?item ?Distinction ?Award ?DateDebut ?DateFin

WHERE {
  ?item wdt:P361 wd:Q673014. # partie de Prix de Lausanne
  ?item wdt:P31 wd:Q1792571 . # prix artistique
  OPTIONAL {?item wdt:P580 ?DateDebut . }
  OPTIONAL {?item wdt:P582 ?DateFin .}

  SERVICE wikibase:label {bd:serviceParam wikibase:language "fr" . ?item rdfs:label ?Distinction }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" . ?item rdfs:label ?Award }
}
Try it!

Exemples de projets exploitant les outils Wikimedia (données de Wikidata et images de Wikimedia Commons)[edit]

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Gilliane/Tipps/SPARQL-PrixdeLausanne&oldid=1537430292"