User:FHd/Listes
< User:FHd
Musées en Occitanie[edit]
SELECT DISTINCT ?Site ?SiteLabel ?SiteDescription ?museofile ?distinctionLabel ?lieuLabel ?coord ?articleWikipédia ?lienswikipedia
WHERE
{
?Site wdt:P31/wdt:P279* wd:Q33506;
wdt:P131/wdt:P131/wdt:P131 wd:Q18678265;
wdt:P131 ?lieu.
OPTIONAL {?Site wdt:P539 ?museofile.}
OPTIONAL {?Site wdt:P625 ?coord.}
OPTIONAL {?Site wdt:P166 ?distinction.}
OPTIONAL {?articleWikipédia schema:about ?Site .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
?Site wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(?lieuLabel)
Peinture dans un musée d'Occitanie[edit]
SELECT DISTINCT ?OeuvreLabel ?SiteLabel ?lieuLabel ?articleWikipédiaOeuvre ?lienswikipediaOeuvre ?articleWikipédiaSite ?lienswikipediaSite
WHERE
{
?Oeuvre wdt:P31/wdt:P279* wd:Q3305213.
?Oeuvre wdt:P276 ?Site.
?Site wdt:P31/wdt:P279* wd:Q33506;
wdt:P131/wdt:P131/wdt:P131 wd:Q18678265;
wdt:P131 ?lieu.
OPTIONAL {?articleWikipédiaOeuvre schema:about ?Oeuvre .
?articleWikipédiaOeuvre schema:isPartOf <https://fr.wikipedia.org/>.
}
?Oeuvre wikibase:sitelinks ?lienswikipediaOeuvre.
OPTIONAL {?articleWikipédiaSite schema:about ?Site .
?articleWikipédiaSite schema:isPartOf <https://fr.wikipedia.org/>.
}
?Site wikibase:sitelinks ?lienswikipediaSite.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(?lieuLabel)
Jardins en Occitanie[edit]
SELECT DISTINCT ?Site ?EltLabel ?SiteLabel ?SiteDescription ?distinctionLabel ?lieuLabel ?coord ?articleWikipédia ?lienswikipedia
WHERE
{
?Site wdt:P31/wdt:P279* wd:Q1107656;
wdt:P131/wdt:P131/wdt:P131 wd:Q18678265;
wdt:P131 ?lieu.
?Site wdt:P31 ?Elt.
OPTIONAL {?Site wdt:P625 ?coord.}
OPTIONAL {?Site wdt:P166 ?distinction.}
OPTIONAL {?articleWikipédia schema:about ?Site .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
?Site wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(?lieuLabel)
MH en Occitanie sans coordonnées géographiques[edit]
SELECT DISTINCT ?item ?itemLabel WHERE {
{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #MH
?item wdt:P131/wdt:P131/wdt:P131 wd:Q18678265 . # en Occ
?item p:P380 [] #immeubles
MINUS { ?item wdt:P625 [] } #sans coordonnées géographique
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}
MH en Occitanie sans date de début[edit]
SELECT DISTINCT ?item ?itemLabel WHERE {
?item wdt:P131/wdt:P131/wdt:P131 wd:Q18678265 . # en Occ
?item p:P1435 ?stat .
{ ?stat ps:P1435 wd:Q10387575 . } UNION { ?stat ps:P1435 wd:Q10387684 . } #MH
MINUS { ?stat pq:P580 [] } #sans date de début
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}
MH protégés en 2023[edit]
SELECT DISTINCT ?item ?itemLabel ?articleWikipédia ?villeLabel ?departLabel ?regionLabel ?protectionLabel ?merimeeLabel ?coord ?pic ?protDate WHERE {
# ?item wdt:P131/wdt:P131/wdt:P131 wd:Q18678265 . # en Occ
# ?item p:P380 [] . #immeubles
?item p:P1435 ?stat .
{ ?stat ps:P1435 wd:Q10387575 ; pq:P580 ?protDate . } UNION { ?stat ps:P1435 wd:Q10387684 ; pq:P580 ?protDate . } #MH
?stat ps:P1435 ?protection ;
FILTER(year(?protDate) = 2023 )
?item wdt:P380 ?merimee ;
wdt:P131 ?ville ;
wdt:P131/wdt:P131 ?depart .
{ ?depart wdt:P31 wd:Q6465 ;
wdt:P131 ?region ;
wdt:P131/wdt:P31 wd:Q36784 . # region
}
UNION
{ ?depart wdt:P31 wd:Q56061 ; # entité Alsace
wdt:P131 ?region .
}
UNION
{ ?depart wdt:P31 wd:Q202216 ; # DOM
wdt:P131 ?region .
}
UNION
{ ?depart wdt:P131 wd:Q90 ;
wdt:P131/wdt:P131/wdt:P131 ?region .
}
UNION
{ ?ville wdt:P131 wd:Q90 ;
wdt:P131/wdt:P131/wdt:P131 ?region .
} # departement ou Paris
UNION
{ ?item wdt:P131 wd:Q90 ;
wdt:P131/wdt:P131/wdt:P131 ?region .
} # departement ou Paris
OPTIONAL {?item wdt:P625 ?coord.}
OPTIONAL {?item wdt:P18 ?pic.}
OPTIONAL {?articleWikipédia schema:about ?item .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}
MH protégés en 2023 - simplifié[edit]
SELECT DISTINCT ?item ?itemLabel ?coord ?pic WHERE {
{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #MH
OPTIONAL { {?item p:P1435 [ ps:P1435 wd:Q10387575 ; pq:P580 ?dateDebut ] . } UNION
{?item p:P1435 [ ps:P1435 wd:Q10387684 ; pq:P580 ?dateDebut ] . } }
FILTER(year(?dateDebut) = 2023 )
?item wdt:P380 ?id .
OPTIONAL {?item wdt:P625 ?coord.}
OPTIONAL {?item wdt:P18 ?pic.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}
Canal du Midi[edit]
SELECT DISTINCT ?item ?itemLabel ?articleWikipédia ?merimee WHERE {
{ ?item wdt:P361 wd:Q202494. } UNION { ?item wdt:P2505 wd:Q202494. } UNION { ?item wdt:P177 wd:Q202494. }
OPTIONAL { ?item wdt:P380 ?merimee . }
OPTIONAL {?articleWikipédia schema:about ?item .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}
BIC en Andorre[edit]
SELECT DISTINCT ?Site ?natureLabel ?SiteLabel ?SiteDescription ?lieuLabel ?coord ?articleWikipédia ?lienswikipedia ?layer
WHERE
{
?Site wdt:P1435 wd:Q5004973;
wdt:P31 ?nature.
OPTIONAL {?Site wdt:P131 ?lieu.}
OPTIONAL {?Site wdt:P625 ?coord.}
OPTIONAL {?articleWikipédia schema:about ?Site .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
BIND(IF(BOUND(?articleWikipédia), "Avec article", "Sans article") AS ?layer)
?Site wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(?natureLabel)
Sites préhistoriques en Occitanie[edit]
SELECT DISTINCT ?Site ?SiteLabel ?SiteDescription ?lieuLabel ?articleWikipédia ?lienswikipedia
WHERE
{
?Site wdt:P31/wdt:P279* wd:Q56320584;
wdt:P131/wdt:P131/wdt:P131 wd:Q18678265;
wdt:P131 ?lieu.
OPTIONAL {?articleWikipédia schema:about ?Site .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
?Site wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(?lieuLabel)
Mégalithes & sites mégalithiques du Morbihan[edit]
SELECT DISTINCT ?Site ?SiteLabel ?SiteDescription ?merimee ?lieuLabel ?coord ?articleWikipédia ?lienswikipedia WHERE {
{ ?Site (wdt:P31/(wdt:P279*)) wd:Q164240. }
UNION
{ ?Site (wdt:P31/(wdt:P279*)) wd:Q53336805. }
?Site (wdt:P131/wdt:P131) wd:Q12642;
wdt:P131 ?lieu.
OPTIONAL { ?Site wdt:P625 ?coord. }
OPTIONAL { ?Site wdt:P380 ?merimee. }
OPTIONAL {
?articleWikipédia schema:about ?Site;
schema:isPartOf <https://fr.wikipedia.org/>.
}
?Site wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
ORDER BY (?lieuLabel)
Malouinières[edit]
SELECT DISTINCT ?item ?itemLabel ?id ?gert ?coord ?pic ?articleWikipédia ?layer WHERE {
?item wdt:P31 wd:Q3284597.
OPTIONAL { ?item wdt:P380 ?id. }
OPTIONAL { ?item wdt:P1529 ?gert. }
OPTIONAL { ?item wdt:P625 ?coord. }
OPTIONAL { ?item wdt:P18 ?pic. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
OPTIONAL {
?articleWikipédia schema:about ?item;
schema:isPartOf <https://fr.wikipedia.org/>.
}
BIND(IF(BOUND(?articleWikipédia), "Article", "Sans article") AS ?layer)
}
Biens d'intérêt culturel en Andorre[edit]
SELECT DISTINCT ?Site ?SiteLabel ?SiteDescription ?lieuLabel ?coord ?articleWikipédia
WHERE
{
?Site wdt:P1435 wd:Q5004973;
wdt:P131 ?lieu.
OPTIONAL {?Site wdt:P625 ?coord.}
OPTIONAL {?articleWikipédia schema:about ?Site .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
?Site wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(?lieuLabel)
Élèves de l'École alsacienne à Paris[edit]
SELECT ?Personne ?PersonneLabel ?PersonneDescription ?datenais ?articleWikipédia ?lienswikipedia
WHERE
{
?Personne wdt:P69 wd:Q3577716;
wdt:P569 ?datenais.
OPTIONAL {?articleWikipédia schema:about ?Personne .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
?Personne wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by desc(?datenais)
Morts du Covid[edit]
SELECT ?personne ?age ?citoyenLabel
WHERE {
?personne wdt:P31 wd:Q5; wdt:P569 ?birth; wdt:P509 wd:Q84263196 ; wdt:P570 ?died.
BIND(FLOOR((?died - ?birth)/365.2425) AS ?age).
BIND((YEAR(?died)-2020)*12 + MONTH(?died) AS ?mthn).
?personne wdt:P27 ?citoyen.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
ORDER BY DESC(?age)
LIMIT 10000
Patriarcats catho & ortho[edit]
SELECT DISTINCT ?patriarcat ?patriarcatLabel ?patriarcatDescription ?articleWikipédia
{
?patriarcat wdt:P31/wdt:P279* wd:Q1282276.
OPTIONAL {?articleWikipédia schema:about ?patriarcat .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by asc(UCASE(?patriarcatLabel))
Conférences épiscopales[edit]
SELECT DISTINCT ?item ?itemLabel ?id WHERE {
?item wdt:P12509 ?id
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}
order by asc(?id)
Joueur de rugby passé par Colomiers Rugby[edit]
SELECT ?Personne ?PersonneLabel ?PersonneDescription ?datenais ?articleWikipédia ?lienswikipedia
WHERE
{
?Personne wdt:P54 wd:Q1407380;
wdt:P569 ?datenais.
OPTIONAL {?articleWikipédia schema:about ?Personne .
?articleWikipédia schema:isPartOf <https://fr.wikipedia.org/>.
}
?Personne wikibase:sitelinks ?lienswikipedia.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by desc(?datenais)
Liste peinture d'un peintre (récup)[edit]
This list is periodically updated by a bot. Manual changes to the list will be removed on the next update!
WDQS | PetScan | TABernacle | Find images | Recent changes | Query:SELECT ?item WHERE { ?item wdt:P170 wd:Q173223 }
drawing[edit]
painting[edit]
pastel[edit]
print[edit]
Misc[edit]
image | Article | RKDimages ID | inception | collection | inventory number | depicts | owned by | catalog code | genre | made from material | Item |
---|---|---|---|---|---|---|---|---|---|---|---|
Mary Cassatt Self-Portrait | 1880 | National Portrait Gallery | NPG.76.33 | Mary Cassatt | self-portrait | Q28796404 |
|sparql=SELECT ?item WHERE { ?item wdt:P170 wd:Q173223 } |section=31 |sort=571 |columns=P18,label:Article,P350,P571,P195,P217,P180,P127,P528,P136,P186,Item |thumb=128 |min_section=2 }}