User:2le2im-bdc/artfilm

From Wikidata
Jump to navigation Jump to search

La plateforme de video sur demande artfilm.ch (Q88870118) a ouvert son catalogue en signe de solidarité pendant la période du Covid-19, comme en atteste la presse[1].

Nous avons choisi d'importer les données principales de ce catalogue dans Wikidata afin de pouvoir mieux les rendre accessibles et en analyser le contenu.

Nous nous attendions à devoir créer des notices pour les films en eux-mêmes mais le plus difficile fut de créer l'enmseble des entrées des réalisateurs et réalisatrices, ainsi que celles sur leurs nom de famille (afin de pouvoir réaliser des tris).

Princiaples notices créées (hors films et réalisateurs/trices)[edit]

Contenu du catalogue[edit]

Films[edit]

#films mis à disposition en libre accès en VOD par artfilm.ch durant la crise du Covid-19
SELECT DISTINCT ?film ?filmLabel (GROUP_CONCAT(DISTINCT(?réalLabel); separator=", ") as ?réals) ?duree (MIN(?date) as ?oldest_date) ?accès
WHERE 
{
  ?film wdt:P1344 wd:Q89370484;
        wdt:P2047 ?duree;
        wdt:P577 ?date;
        wdt:P57 ?réal.
  ?film p:P973 ?describestmt.
  ?describestmt ps:P973 ?accès.
  ?describestmt pq:P407 wd:Q150.
  FILTER STRSTARTS(STR(?accès), "https://www.artfilm.ch").
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         }
}
GROUP BY ?film ?filmLabel ?duree ?accès
ORDER BY ?oldest_date

Try it!

Publié sur Twitter : https://twitter.com/b3d2c/status/1246907777278246918

#films mis à disposition en libre accès en VOD par artfilm.ch durant la crise du Covid-19
SELECT DISTINCT ?film ?filmLabel (GROUP_CONCAT(DISTINCT(?réalLabel); separator=", ") as ?réals) ?duree (MIN(?date) as ?oldest_date) ?accès
WHERE 
{
  ?film wdt:P1344 wd:Q89370484;
        wdt:P2047 ?duree;
        wdt:P57 ?réal.
  OPTIONAL {?film wdt:P577 ?date.}
  ?film p:P973 ?describestmt.
  ?describestmt ps:P973 ?accès.
  ?describestmt pq:P407 wd:Q150.
  FILTER STRSTARTS(STR(?accès), "https://www.artfilm.ch").
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         }
}
GROUP BY ?film ?filmLabel ?duree ?accès
ORDER BY ?oldest_date

Try it!

#films connus de Wikidata diffusés en VOD par artfilm.ch
SELECT DISTINCT ?film ?filmLabel (GROUP_CONCAT(DISTINCT(?réalLabel); separator=", ") as ?réals) ?duree (MIN(?date) as ?oldest_date) ?URL
WHERE 
{
  ?film p:P3301 ?artfilm.
  ?artfilm ps:P3301 ?artfilmCH;
           pq:P2699 ?URL.
  FILTER STRSTARTS(STR(?URL), "https://www.artfilm.ch").
  OPTIONAL {?film wdt:P2047 ?duree.}
  OPTIONAL {?film wdt:P57 ?réal.}
  OPTIONAL {?film wdt:P577 ?date.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         }
}
GROUP BY ?film ?filmLabel ?duree ?URL
ORDER BY ?oldest_date

Try it!

Films par réalisatrice ou réalisateur et date[edit]

#films mis à disposition en libre accès en VOD par artfilm.ch durant la crise du Covid-19 triés par réalisatrice ou réalisateur et date
SELECT DISTINCT ?film ?filmLabel ?réalLabel ?familleLabel ?duree (MIN(?date) as ?oldest_date) ?accès
WHERE 
{
  ?film wdt:P1344 wd:Q89370484;
        wdt:P2047 ?duree;
        wdt:P577 ?date;
        wdt:P57 ?réal.
  ?film p:P973 ?describestmt.
  ?describestmt ps:P973 ?accès.
  ?describestmt pq:P407 wd:Q150.
  FILTER STRSTARTS(STR(?accès), "https://www.artfilm.ch").
  OPTIONAL {?réal wdt:P734 ?famille.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         ?famille rdfs:label ?familleLabel.
                         }
}
GROUP BY ?film ?filmLabel ?réalLabel ?familleLabel ?duree ?accès
ORDER BY STR(?familleLabel) ?réalLabel ?oldest_date

Try it!

  • 387 résultats (05.04.2020)
#films diffusés en VOD par artfilm.ch triés par réalisatrice ou réalisateur et date
SELECT DISTINCT ?film ?filmLabel ?réalLabel ?familleLabel ?duree (MIN(?date) as ?oldest_date) ?accès
WHERE 
{
?film p:P3301 ?artfilm.
  ?artfilm ps:P3301 ?artfilmCH;
           pq:P2699 ?URL.
  FILTER STRSTARTS(STR(?URL), "https://www.artfilm.ch").
  OPTIONAL {?film wdt:P2047 ?duree.}
  OPTIONAL {?film wdt:P57 ?réal.}
  OPTIONAL {?film wdt:P577 ?date.}
  OPTIONAL {?réal wdt:P734 ?famille.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         ?famille rdfs:label ?familleLabel.
                         }
}
GROUP BY ?film ?filmLabel ?réalLabel ?familleLabel ?duree ?accès
ORDER BY STR(?familleLabel) ?réalLabel ?oldest_date

Try it!

Films par réalisatrices et date[edit]

#films mis à disposition en libre accès en VOD par artfilm.ch durant la crise du Covid-19 triés par réalisatrice et date
SELECT DISTINCT ?film ?filmLabel ?réalLabel ?familleLabel ?duree (MIN(?date) as ?oldest_date) ?accès
WHERE 
{
  ?film wdt:P1344 wd:Q89370484;
        wdt:P2047 ?duree;
        wdt:P577 ?date;
        wdt:P57 ?réal.
  ?film p:P973 ?describestmt.
  ?describestmt ps:P973 ?accès.
  ?describestmt pq:P407 wd:Q150.
  FILTER STRSTARTS(STR(?accès), "https://www.artfilm.ch").
  OPTIONAL {?réal wdt:P734 ?famille.}
  ?réal wdt:P21 wd:Q6581072.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         ?famille rdfs:label ?familleLabel.
                         }
}
GROUP BY ?film ?filmLabel ?réalLabel ?familleLabel ?duree ?accès
ORDER BY STR(?familleLabel) ?réalLabel ?oldest_date

Try it!

  • 110 résultats (05.04.2020)
#films diffusés en VOD par artfilm.ch triés par réalisatrice et date
SELECT DISTINCT ?film ?filmLabel ?réalLabel ?familleLabel ?duree (MIN(?date) as ?oldest_date) ?accès
WHERE 
{
?film p:P3301 ?artfilm.
  ?artfilm ps:P3301 ?artfilmCH;
           pq:P2699 ?URL.
  FILTER STRSTARTS(STR(?URL), "https://www.artfilm.ch").
  OPTIONAL {?film wdt:P2047 ?duree.}
  OPTIONAL {?film wdt:P57 ?réal.}
  OPTIONAL {?film wdt:P577 ?date.}
  OPTIONAL {?réal wdt:P734 ?famille.}
   ?réal wdt:P21 wd:Q6581072.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         ?famille rdfs:label ?familleLabel.
                         }
}
GROUP BY ?film ?filmLabel ?réalLabel ?familleLabel ?duree ?accès
ORDER BY STR(?familleLabel) ?réalLabel ?oldest_date

Try it!

  • 122 résultats (17.04.2020)

Par une ou un réalisateur·trice[edit]

#films de Peter Mettler connus de Wikidata et diffusés en VOD par artfilm.ch
SELECT DISTINCT ?film ?filmLabel (GROUP_CONCAT(DISTINCT(?réalLabel); separator=", ") as ?réals) ?duree (MIN(?date) as ?oldest_date) ?URL
WHERE 
{
  ?film wdt:P57 wd:Q7175862;
        p:P3301 ?artfilm.
  ?artfilm ps:P3301 ?artfilmCH;
           pq:P2699 ?URL.
  FILTER STRSTARTS(STR(?URL), "https://www.artfilm.ch").
  OPTIONAL {?film wdt:P2047 ?duree.}
  OPTIONAL {?film wdt:P577 ?date.}
  OPTIONAL {?film wdt:P57 ?réal.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,it,es".
                         ?réal rdfs:label ?réalLabel.
                         ?film rdfs:label ?filmLabel.
                         }
}
GROUP BY ?film ?filmLabel ?duree ?URL
ORDER BY ?oldest_date

Try it!

Making-off[edit]

Nous avons bénéficier pour l'import des données de deux lots :

  1. le premier lot (réalisateur, titre) a été récupéré dans le code URL de la page qui listait les films sur la plateforme elle-même. Nous l'avons nettoyé et importer dans OpenRefine.
  2. Le second lot (année,ISAN,durée) a été mise à disposition pour la plateforme elle-même sur notre demande dans un format json que l'aide précieuse d'Ettore Rizza nous a permis d'importer dans OpenRefine.

Notes et références[edit]

  1. Mathieu Loewer (3 April 2020). "Le cinéma résiste en ligne". Le Courrier (in French) (66): 19. ISSN 1424-1404. Wikidata Q89369783.