User:Symac
Jump to navigation
Jump to search
Find me on French WP, mainly working there with my bot.
Revue Leaves[edit]
SPARQL[edit]
Docteurs Honoris Causa[edit]
Docteurs Honoris Causa avec leur université de rattachement (dans le cas de l'utilisation de
SELECT ?person ?personLabel ?universityLabel (YEAR(?date) AS ?annee)
WHERE
{
{
?person p:P166 ?distinction.
?distinction (ps:P166/(wdt:P279*)) wd:Q209896 .
?distinction pq:P1027 ?university
OPTIONAL { ?distinction pq:P585 ?date }
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
order by ?universityLabel
Écrivains sans idref[edit]
Wikidata items for writers with more than one interwiki and without a IdRef ID (P269) :
SELECT distinct ?s ?writer ?sitelink ?linkcount
WHERE
{
{?s wdt:P106 wd:Q36180 .} UNION { ?s wdt:P106 wd:Q482980 . } UNION { ?s wdt:P106 wd:Q49757 . }
?s wdt:P27 wd:Q142 .
?s wikibase:sitelinks ?linkcount .
{ ?sitelink schema:about ?s . ?sitelink schema:inLanguage "fr" . ?sitelink schema:isPartOf <https://fr.wikipedia.org/> .}
MINUS { ?s wdt:P269 [] } .
OPTIONAL {
?s rdfs:label ?writer filter (lang(?writer) = "fr").
}
} GROUP BY ?s ?writer ?sitelink ?linkcount HAVING (?linkcount > 1) ORDER BY DESC(?linkcount)
Parents non associés à leurs enfants[edit]
Parents that are not linked back from their child's page.
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
SELECT ?son ?sonLabel ?parent ?parentLabel WHERE {
{?son wdt:P25 ?parent}
UNION
{?son wdt:P22 ?parent}
FILTER
(
NOT EXISTS{?parent wdt:P40 ?son}
)
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en" .
}
}
Écrivains français sans lien BnF[edit]
French writer born after 1800 and without a Bibliothèque nationale de France ID (P268) :
SELECT distinct ?s ?writer ?born ?linkcount
WHERE
{
{?s wdt:P106 wd:Q36180 .} UNION { ?s wdt:P106 wd:Q482980 . } UNION { ?s wdt:P106 wd:Q49757 . }
?s wdt:P27 wd:Q142 .
?s wikibase:sitelinks ?linkcount .
MINUS { ?s wdt:P268 [] }.
?s wdt:P569 ?born .
FILTER (?born >= "1800-01-01T00:00:00Z"^^xsd:dateTime) .
OPTIONAL {
?s rdfs:label ?writer filter (lang(?writer) = "fr").
}
} GROUP BY ?s ?writer ?born ?linkcount HAVING (?linkcount > 1) ORDER BY DESC(?linkcount)
Acteurs dans un film sorti avant leur naissance[edit]
Actor that are in the distribution of a movie that was published before they were born :
SELECT ?actor ?actorLabel ?movie ?movieLabel ?dob ?age WHERE {
{
SELECT ?actor ?dob {
?dob_node wikibase:timePrecision "11"^^xsd:integer .
?dob_node wikibase:timeValue ?dob .
?actor p:P569/psv:P569 ?dob_node .
}
}
?actor wdt:P21 ?genre .
?actor wdt:P106 wd:Q33999 .
?actor wdt:P27 wd:Q142 .
?movie wdt:P161 ?actor .
?movie wdt:P577 ?dateMovie .
BIND(YEAR(?dateMovie)-YEAR(?dob) as ?age) .
FILTER(?age < 0) .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
Portraits de Libé[edit]
Portraits de Libé
SELECT ?item ?itemLabel ?date
WHERE
{
?item wdt:P361 wd:Q30091381.
?item wdt:P577 ?date
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY DESC(?date)
SELECT DISTINCT ?item ?itemLabel ?personLabel ?date ?genderLabel
WHERE
{
?item wdt:P361 wd:Q30091381.
?item wdt:P577 ?date .
?item wdt:P921 ?person .
?person wdt:P21 ?gender
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY DESC(?date)
Édifices religieux de Gironde[edit]
SELECT DISTINCT ?item ?itemLabel ?image ?commune ?communeLabel ?religionLabel ?coordinates ?idcdf ?messes
(GROUP_CONCAT(?odpr; separator=";") AS ?odprs) (GROUP_CONCAT(?merimee; separator=";") AS ?merimees) (MIN(?codepostal) AS ?CP) WHERE
{
{ ?item wdt:P31/wdt:P279* wd:Q16970 . }
# Église
UNION { ?item wdt:P31/wdt:P279* wd:Q34627 . } # Synagogue
UNION { ?item wdt:P31/wdt:P279* wd:Q32815 . } # Mosquée
UNION { ?item wdt:P31/wdt:P279* wd:Q56242063 . } # temple protestant
?item wdt:P131/wdt:P131 wd:Q12526 .
?item wdt:P131 ?commune .
OPTIONAL{?commune wdt:P281 ?codepostal .}
OPTIONAL{?item wdt:P140 ?religion .}
OPTIONAL{?item wdt:P625 ?coordinates .}
OPTIONAL{?item wdt:P3963 ?idcdf .}
OPTIONAL{?item wdt:P380 ?merimee .}
OPTIONAL{?item wdt:P1644 ?messes .}
OPTIONAL{?item wdt:P3371 ?odpr .}
OPTIONAL{?item wdt:P18 ?image .}
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en"
}
}
GROUP BY ?item ?itemLabel ?image ?commune ?communeLabel ?religionLabel ?coordinates ?idcdf ?messes ?odprs ?merimees
ORDER BY ?communeLabel
Docteur.e plus âgé.e.s que leurs responsables de thèse[edit]
SELECT ?difference ?doctor ?doctorLabel ?doctorBirthdate ?doctorIdref ?supervisor ?supervisorLabel ?supervisorBirthdate ?supervisorIdref
WHERE
{
?doctor wdt:P184 ?supervisor .
?supervisor wdt:P269 ?supervisorIdref .
?doctor wdt:P269 ?doctorIdref .
?doctor p:P569/psv:P569 [
wikibase:timePrecision "9"^^xsd:integer ; # precision of at least year
wikibase:timeValue ?doctorBirthdate ;
] .
?supervisor p:P569/psv:P569 [
wikibase:timePrecision "9"^^xsd:integer ; # precision of at least year
wikibase:timeValue ?supervisorBirthdate ;
]
FILTER(datatype(?supervisorBirthdate) = <http://www.w3.org/2001/XMLSchema#dateTime>) .
FILTER(datatype(?doctorBirthdate) = <http://www.w3.org/2001/XMLSchema#dateTime>) .
BIND(YEAR(?doctorBirthdate)-YEAR(?supervisorBirthdate) as ?difference)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # le label viendra de préférence dans votre langue, et autrement en anglais
}
ORDER BY ?difference
LIMIT 10
Femmes portraitisées dans Libé sans article sur fr.wp[edit]
SELECT DISTINCT ?person ?personLabel ?occupationLabel WHERE
{
?article wdt:P921 ?person.
?article wdt:P361 wd:Q30091381 .
?person wdt:P21 wd:Q6581072 .
?person wdt:P106 ?occupation
MINUS { ?frArticle schema:about ?person; schema:isPartOf <https://fr.wikipedia.org/>. } # No article on pt.wiki
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en". }
}