User:Miraclepine/queries

SELECT ?item ?itemLabel ?surnameLabel ?dob ?oxford_collegeLabel
WHERE
{
  { ?item wdt:P69 wd:Q34433 . }
  UNION { ?item wdt:P69 ?oxford_college .
    ?oxford_college wdt:P31 wd:Q2581649 . }
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P734 ?surname .
  ?item wdt:P569 ?dob . hint:Prior hint:rangeSafe true .
  FILTER("1694-00-00T00:00:00Z"^^xsd:dateTime <= ?dob && ?dob < "1868-00-00T00:00:00Z"^^xsd:dateTime)
  FILTER NOT EXISTS { ?item wdt:P1343 wd:Q19036877 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?surnameLabel

Try it!

# may be useful for creating Wikisource author pages
SELECT ?item ?itemLabel ?value ?sl
{
  {
       SELECT *
       {
          ?item wdt:P31 wd:Q5 .
          ?item wdt:P27 wd:Q174193 .
          ?item wdt:P1343 wd:Q15987216 .
          ?item wdt:P648 ?value ; wikibase:sitelinks ?sl
          FILTER NOT EXISTS { [] schema:about ?item ; schema:isPartOf <https://en.wikisource.org/> }
       }
       ORDER BY DESC(?sl) ?item
       LIMIT 1000
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY DESC(?sl) ?item

Try it!

# Fellows of the American Society of Genealogists
SELECT ?item ?itemLabel ?date ?nom
WHERE
{
  ?item wdt:P31 wd:Q5.
  ?item p:P166 ?fellow.
  ?fellow ps:P166 wd:Q19604396.
  ?fellow a wikibase:BestRank.
  OPTIONAL { ?fellow pq:P585 ?date. }
  OPTIONAL { ?fellow pq:P1545 ?nom. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

# People with more than one honorary degree but no enwiki page
# Per enwiki WP:NPROF 1: "For the purposes of partially satisfying Criterion 1, significant academic awards and honors may include [...] honorary degrees"
SELECT DISTINCT ?person ?personLabel ?personDescription ?degrees WHERE {
  { SELECT DISTINCT ?person (COUNT(DISTINCT ?degree) as ?degrees) WHERE {
  { ?person wdt:P166 ?degree . ?degree wdt:P279 wd:Q11415564 . } UNION { ?person p:P166 ?degree. ?degree ps:P166 wd:Q11415564. }
  } GROUP BY ?person } FILTER ( ?degrees > 1 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } 
  FILTER NOT EXISTS { [] schema:about ?person ; schema:isPartOf <https://en.wikipedia.org/> }
} ORDER BY DESC (?degrees)

Try it!

# People with Mathematics Genealogy Project IDs, enwiki pages, and a familiar description pattern
# Currently zero as of 21 Feb 2022.
SELECT DISTINCT ?item ?itemLabel ?d 
{
  ?item wdt:P549 ?id; schema:description ?d .
  FILTER( lang(?d) = "en" && strstarts(?d, "Ph.D.") )
  FILTER EXISTS { [] schema:about ?item ; schema:isPartOf <https://en.wikipedia.org/> }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

# People with ORCID IDs, enwiki pages, and a familiar description pattern
# Currently up to just over 1,900 results
SELECT DISTINCT ?item ?itemLabel ?d 
{
  ?item wdt:P496 ?id; schema:description ?d .
  FILTER( lang(?d) = "en" && strstarts(?d, "researcher") )
  FILTER EXISTS { [] schema:about ?item ; schema:isPartOf <https://en.wikipedia.org/> }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

# People with The Peerage IDs, enwiki pages, and a familiar description pattern
# Currently over 1,300 as of 21 Feb 2022.
SELECT DISTINCT ?item ?itemLabel ?d 
{
  ?item wdt:P4638 ?id; schema:description ?d .
  FILTER( lang(?d) = "en" && strstarts(?d, "(1") )
  FILTER EXISTS { [] schema:about ?item ; schema:isPartOf <https://en.wikipedia.org/> }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!