User:Gerd Fahrenhorst

Babel user information
de-N Dieser Benutzer spricht Deutsch als Muttersprache. en-2 This user has intermediate knowledge of English.
Users by language

Gerd Fahrenhorst

About me

• Address: Gerd Fahrenhorst, Spinnereistr. 1, 30449 Hannover, Germany
• E-Mail: gerd@fahrenhorst.de
• German Wikipedia user page: de:Benutzer:Gerd Fahrenhorst
• Webpages (in German): http://www.fahrenhorst.de , http://www.cwallers.de

Siehe auch

• User:Gerd Fahrenhorst/KunstNachOrt

ToDo

• User_talk:Hogü-456#Straßen_in_den_Niederlanden
• Vapiano (Q506252) was denn nun, Marke oder Unternehmen, wenn letzteres welches?
• windmill (Q38720) und wind turbine (Q49833) vongemeinsamer Basisklasse ableiten
• Wikidata_talk:WikiProject_Railways#Include_"railway_station"_in_title_or_not

SPARQL Links

• Wikidata:SPARQL tutorial
• Wikidata:SPARQL query service/queries/examples

Nearby ohne Stolpersteine, Straßen und Sonderausstellungen

The following query uses these:

• Items: Rüstersiel (Q2204038)   , stumbling stone (Q26703203)   , temporary exhibition (Q29023906)   , street (Q79007)   

• Properties: coordinate location (P625)   , instance of (P31)   , located in the administrative territorial entity (P131)   , OpenStreetMap way ID (P10689)   , OpenStreetMap node ID (P11693)   , location (P276)   

  SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel ?ortLabel ?OsmLi ?OsmKn
  WHERE
  {
    # Nearby ohne Stolpersteine, Straßen und Sonderausstellungen
    wd:Q2204038 wdt:P625 ?loc . # irgendein Item mit Geokoordinaten
    #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
    SERVICE wikibase:around {
        ?place wdt:P625 ?location .
        bd:serviceParam wikibase:center ?loc .
        bd:serviceParam wikibase:radius "5" .
    }
    OPTIONAL { ?place wdt:P31 ?istEin }
    OPTIONAL { ?place wdt:P131 ?liegtIn }
    OPTIONAL { ?place wdt:P10689 ?OsmLi }
    OPTIONAL { ?place wdt:P11693 ?OsmKn }
    OPTIONAL { ?place wdt:P276  ?ort }
    FILTER ( ?istEin != wd:Q26703203 && ?istEin != wd:Q29023906 && ?istEin != wd:Q79007 )
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
    BIND(geof:distance(?loc, ?location) as ?dist)
  } ORDER BY ?dist
  LIMIT 50
  

Try it!

Nearby mit Denkmal Nds und OSM, ohne Stolpersteine

The following query uses these:

• Items: Spinnereistraße 1 (Q120143231)   , stumbling stone (Q26703203)   , temporary exhibition (Q29023906)   

• Properties: coordinate location (P625)   , instance of (P31)   , located in the administrative territorial entity (P131)   , located in statistical territorial entity (P8138)   , Monument Atlas Lower Saxony Objekt-ID (P7900)   , OpenStreetMap way ID (P10689)   , OpenStreetMap node ID (P11693)   , OpenStreetMap relation ID (P402)   

  SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel ?StatLabel ?Denkmal ?OsmLi ?OsmKn ?OsmRe
  WHERE
  {
    # Nearby ohne Stolpersteine und Sonderausstellungen
    wd:Q120143231 wdt:P625 ?loc . # Item mit Geokoordinaten
    #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
    SERVICE wikibase:around {
        ?place wdt:P625 ?location .
        bd:serviceParam wikibase:center ?loc .
        bd:serviceParam wikibase:radius "0.5" .
    }
    OPTIONAL { ?place wdt:P31 ?istEin }
    OPTIONAL { ?place wdt:P131 ?liegtIn }
    OPTIONAL { ?place wdt:P8138 ?Stat }
    OPTIONAL { ?place wdt:P7900 ?Denkmal }
    OPTIONAL { ?place wdt:P10689 ?OsmLi }
    OPTIONAL { ?place wdt:P11693 ?OsmKn }
    OPTIONAL { ?place wdt:P402 ?OsmRe }
    FILTER ( ?istEin != wd:Q26703203 && ?istEin != wd:Q29023906) # keine Stolpersteine
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
    BIND(geof:distance(?loc, ?location) as ?dist)
  } ORDER BY ?dist
  LIMIT 250
  

Try it!

Unvollständig

Nearby, mit Geokoordinaten aber ohne P31 (ist ein) oder ohne P17 (Staat)

Hier muss man sorgfältig ein ODER Zeichen "||" bei der FILTER Anweisung vermeiden, damit das SPARQL2 Template die FILTER Zeile verarbeiten kann.

The following query uses these:

• Items: Sassnitz (Q494631)   

• Properties: coordinate location (P625)   , instance of (P31)   , located in the administrative territorial entity (P131)   , country (P17)   

  SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel
  WHERE
  {
    wd:Q494631 wdt:P625 ?loc . # Objekt mit Geokoordinaten
    #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
    SERVICE wikibase:around {
        ?place wdt:P625 ?location .
        bd:serviceParam wikibase:center ?loc .
        bd:serviceParam wikibase:radius "20" .
    }
    OPTIONAL { ?place wdt:P31 ?istEin }
    OPTIONAL { ?place wdt:P131 ?liegtIn }
    OPTIONAL { ?place wdt:P17 ?staat }
    FILTER ( ! (BOUND(?istEin ) && BOUND(?staat )) ) # nur wenn kein P31 oder P17 angegeben
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
    BIND(geof:distance(?loc, ?location) as ?dist)
  } ORDER BY ?dist
  LIMIT 50
  

Try it!

Nearby, mit Geokoordinaten aber ohne "ist ein", "Staat" oder "liegt in"

Hier muss man sorgfältig ein ODER Zeichen "||" bei der FILTER Anweisung vermeiden, damit das SPARQL2 Template die FILTER Zeile verarbeiten kann.

The following query uses these:

• Items: Sassnitz (Q494631)   , stumbling stone (Q26703203)   , temporary exhibition (Q29023906)   

• Properties: coordinate location (P625)   , instance of (P31)   , located in the administrative territorial entity (P131)   , country (P17)   

  SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel
  WHERE
  {
    # Nearby, mit Geokoordinaten aber ohne "ist ein", Staat oder "liegt in"
    wd:Q494631 wdt:P625 ?loc . # Objekt mit Geokoordinaten
    #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
    SERVICE wikibase:around {
        ?place wdt:P625 ?location .
        bd:serviceParam wikibase:center ?loc .
        bd:serviceParam wikibase:radius "10" .
    }
    OPTIONAL { ?place wdt:P31 ?istEin }
    OPTIONAL { ?place wdt:P131 ?liegtIn }
    OPTIONAL { ?place wdt:P17 ?staat }
    FILTER ( ! (BOUND(?istEin ) && BOUND(?staat ) && BOUND(?liegtIn )) ) # nur wenn kein P31 oder P17 oder P131 angegeben
    FILTER ( ?istEin != wd:Q26703203 && ?istEin != wd:Q29023906) # keine Stolpersteine und keine Sonderausstellungen
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
    BIND(geof:distance(?loc, ?location) as ?dist)
  } ORDER BY ?dist
  LIMIT 50
  

Try it!

Schleuse in Deutschland ohne P206 (liegt am Gewässer) oder P131 (liegt in)

Hier muss man sorgfältig ein ODER Zeichen "||" bei der FILTER Anweisung vermeiden, damit das SPARQL2 Template die FILTER Zeile verarbeiten kann.

The following query uses these:

• Items: lock (Q105731)   , Germany (Q183)   

• Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , located in the administrative territorial entity (P131)   , located in or next to body of water (P206)   

  SELECT ?item ?itemLabel ?itemDescription ?istEinLabel ?liegtInVerwLabel ?liegtInGewLabel
  WHERE
  {
    ?item wdt:P31/wdt:P279? wd:Q105731.
    ?item wdt:P17 wd:Q183.
    ?item wdt:P31 ?istEin
    OPTIONAL { ?item wdt:P131 ?liegtInVerw }
    OPTIONAL { ?item wdt:P206 ?liegtInGew }
    FILTER ( ! (BOUND(?liegtInGew ) && BOUND(?liegtInVerw )) ) # nur wenn kein liegt in oder P131 angegeben
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  } ORDER BY ?liegtInGew
  LIMIT 300
  

Try it!

Niedersachsen

Hauptverwaltung in Niedersachsen

The following query uses these:

• Items: Lower Saxony (Q1197)   

• Properties: headquarters location (P159)   , contains the administrative territorial entity (P150)   , located in the administrative territorial entity (P131)   , instance of (P31)   

  SELECT ?item ?itemLabel ?liegtinLabel ?isteinLabel
  WHERE {
    ?item wdt:P159 ?sub0. # P159 = Hauptverwaltung
    ?tree0 wdt:P150* ?sub0. # P150 = Untereinheit
    ?tree0 wdt:P131* wd:Q1197. # P131 = liegt in der Verwaltungseinheit
    ?item wdt:P131 ?liegtin.
    ?item wdt:P31 ?istein.
     SERVICE wikibase:label {
       bd:serviceParam wikibase:language "de,en" .
     }
  }
  LIMIT 50
  

Try it!

Bauwerk in Niedersachsen

The following query uses these:

• Items: Lower Saxony (Q1197)   , architectural structure (Q811979)   

• Properties: located in the administrative territorial entity (P131)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?liegtinLabel ?isteinLabel WHERE {
    ?item wdt:P131 wd:Q1197.
    # ist Bauwerk oder direkte Unterklasse von Bauwerk. * statt ? wären alle Unterklassen gibt aber Timeout.
    ?item wdt:P31/wdt:P279? wd:Q811979.
    ?item wdt:P131 ?liegtin.
    ?item wdt:P31 ?istein.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  }
  LIMIT 50
  

Try it!

irgendwas in Region Hannover

The following query uses these:

• Items: Hanover region (Q5963)   

• Properties: located in the administrative territorial entity (P131)   , instance of (P31)   

  SELECT ?item ?itemLabel ?liegtinLabel ?isteinLabel WHERE {
    ?item wdt:P131 wd:Q5963.
    ?item wdt:P131 ?liegtin.
    ?item wdt:P31 ?istein.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  } ORDER BY ?istein
  LIMIT 500
  

Try it!

liegt in Verwaltungseinheit grafisch

The following query uses these:

• Items: Hanover (Q1715)   

• Properties: located in the administrative territorial entity (P131)   , coordinate location (P625)   , instance of (P31)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?item ?itemLabel ?isteinLabel ?liegtinLabel ?loc WHERE {
  # liegt in der Verwaltungseinheit, oder in einer Einheit die in dieser Verw.Einheit liegt
  ?item wdt:P131/wdt:P131? wd:Q1715.
  ?item wdt:P625 ?loc.
  ?item wdt:P131 ?liegtin.
  ?item wdt:P31 ?istein.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
LIMIT 9000   # Sind (Stand: 7/2022) über 7000 Items

Try it!

liegt in statistischer Einheit grafisch

The following query uses these:

• Items: Linden-Mitte (Q18615961)   

• Properties: located in statistical territorial entity (P8138)   , coordinate location (P625)   , located in the administrative territorial entity (P131)   , instance of (P31)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?item ?itemLabel ?isteinLabel ?liegtinLabel ?loc WHERE {
  # liegt in der Verwaltungseinheit, oder in einer Einheit die in dieser Verw.Einheit liegt
  ?item wdt:P8138 wd:Q18615961.
  ?item wdt:P625 ?loc.
  ?item wdt:P131 ?liegtin.
  ?item wdt:P31 ?istein.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
LIMIT 9000   # Sind (Stand: 7/2022) über 7000 Items

Try it!

Zierbrunnen in der Umgebung eines Ortes

The following query uses these:

• Items: Hamburg (Q1055)   , fountain (Q483453)   

• Properties: coordinate location (P625)   , instance of (P31)   , located in the administrative territorial entity (P131)   , country (P17)   , image (P18)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?place ?location ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel ?pic
WHERE
{
  wd:Q1055 wdt:P625 ?loc . # Q1055=Hamburg, Q1715=Hannover, muss mit Geokoord. sein
  SERVICE wikibase:around {
      ?place wdt:P625 ?location .
      bd:serviceParam wikibase:center ?loc .
      bd:serviceParam wikibase:radius "20" .
  }
  OPTIONAL { ?place wdt:P31 ?istEin }
  OPTIONAL { ?place wdt:P131 ?liegtIn }
  OPTIONAL { ?place wdt:P17 ?staat }
  OPTIONAL { ?place wdt:P18 ?pic }
  #FILTER ( ?placeLabel == "Brunnen" ) # funktioniert nicht ?!
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  FILTER ( ?istEin = wd:Q483453 )   # Q483453 ist Zierbrunnen, Q43483 Wasserbrunnen
  BIND(geof:distance(?loc, ?location) as ?dist)
} ORDER BY ?dist
LIMIT 150

Try it!

Standorte der Kupferhäuser

The following query uses these:

• Items: Copper house (Q1306182)   

• Properties: instance of (P31)   , coordinate location (P625)   , located in the administrative territorial entity (P131)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?item ?itemLabel ?liegtinLabel ?loc WHERE {
  # ist ein Kupferhaus
  ?item wdt:P31 wd:Q1306182.
  ?item wdt:P625 ?loc.
  ?item wdt:P131 ?liegtin.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
LIMIT 90

Try it!

Werke eines Künstlers

Werke von C. W. Allers

The following query uses these:

• Items: Christian Wilhelm Allers (Q704689)   

• Properties: author (P50)   , illustrator (P110)   , creator (P170)   , instance of (P31)   , inception (P571)   , image (P18)   

  SELECT ?objekt ?objektLabel ?objektDescription ?istEinLabel ?autorLabel ?illustLabel ?urheberLabel ?pic ?jahr
  WHERE
  {
    VALUES ?wasSuchenWir { wdt:P50 wdt:P110 wdt:P170 }  # Autor, Illustrator oder Urheber
    ?objekt  ?wasSuchenWir wd:Q704689.    # Q704689 = C. W. Allers
    OPTIONAL { ?objekt  wdt:P31  ?istEin }
    OPTIONAL { ?objekt  wdt:P50  ?autor }
    OPTIONAL { ?objekt  wdt:P110 ?illust }
    OPTIONAL { ?objekt  wdt:P170 ?urheber }
    OPTIONAL { ?objekt  wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
    OPTIONAL { ?objekt  wdt:P18  ?pic }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  } ORDER BY ?objektLabel 
  LIMIT 150
  

Try it!

Werke von Andreas Rimkus

The following query uses these:

• Items: Andreas Rimkus (Q500247)   

• Properties: creator (P170)   , instance of (P31)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , inception (P571)   , image (P18)   , OpenStreetMap node ID (P11693)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?objekt ?objektLabel ?objektDescription ?istEinLabel ?liegtInLabel ?pic ?jahr ?loc ?osm
WHERE
{
  ?objekt  wdt:P170 wd:Q500247 . # P170 = Urheber, Q500247 = Andreas Rimkus
  OPTIONAL { ?objekt  wdt:P31  ?istEin }
  OPTIONAL { ?objekt  wdt:P131 ?liegtIn }
  OPTIONAL { ?objekt  wdt:P625 ?loc }
  OPTIONAL { ?objekt  wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
  OPTIONAL { ?objekt  wdt:P18  ?pic }
  OPTIONAL { ?objekt  wdt:P11693 ?osm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
} ORDER BY ?objektLabel 
LIMIT 50  # 17 in 411 ms (Oktober 2023)

Try it!

Werke von Diether Heisig

The following query uses these:

• Items: Diether Heisig (Q63929521)   

• Properties: creator (P170)   , instance of (P31)   , coordinate location (P625)   , located in the administrative territorial entity (P131)   , inception (P571)   , image (P18)   , OpenStreetMap node ID (P11693)   

Features: ImageGrid (Q24515278)   

# #defaultView:ImageGrid
SELECT ?item ?itemLabel ?istEinLabel ?itemDescription ?liegtinLabel ?pic ?loc ?jahr ?osm
WHERE {
  ?item wdt:P170 wd:Q63929521.   # Urheber ist Diether Heisig
  ?item wdt:P31 ?istEin.
  OPTIONAL { ?item wdt:P625 ?loc }
  OPTIONAL { ?item wdt:P131 ?liegtin }
  OPTIONAL { ?item wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
  OPTIONAL { ?item wdt:P18 ?pic }
  OPTIONAL { ?item wdt:P11693 ?osm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
} ORDER BY ?datum 
LIMIT 50  # 40 in 530 ms (Oktober 2023)

Try it!

Werke von Hartmut Wiesner

The following query uses these:

• Items: Hartmut Wiesner (Q26453676)   

• Properties: creator (P170)   , instance of (P31)   , coordinate location (P625)   , located in the administrative territorial entity (P131)   , inception (P571)   , image (P18)   , OpenStreetMap node ID (P11693)   

  # #defaultView:Table
  SELECT ?item ?itemLabel ?istEinLabel ?itemDescription ?liegtinLabel ?loc ?jahr ?pic ?osm WHERE {
    ?item wdt:P170 wd:Q26453676.    # Urheber ist Hartmut Wiesner
    OPTIONAL { ?item wdt:P31  ?istEin }
    OPTIONAL { ?item wdt:P625 ?loc }
    OPTIONAL { ?item wdt:P131 ?liegtin }
    OPTIONAL { ?item wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
    OPTIONAL { ?item wdt:P18  ?pic }
    OPTIONAL { ?item wdt:P11693 ?osm }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  } ORDER BY ?itemLabel
  LIMIT 50
  

Try it!

Skulpturen, Zierbrunnen, Denkmäler u.ä. nach Ort

Siehe User:Gerd Fahrenhorst/KunstNachOrt.

Objekte mit Vanderkrogt-ID

Objekte in Niedersachsen mit Vanderkrogt-ID

The following query uses these:

• Properties: instance of (P31)   , Vanderkrogt.net Statues ID (P3711)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   

  SELECT ?vanderk ?item ?isteinLabel ?itemLabel ?itemDescription ?liegtinLabel ?loc
  WHERE {
    ?item wdt:P31 ?istein.
    ?item wdt:P3711 ?vanderk.
    OPTIONAL { ?item wdt:P131  ?liegtin }
    OPTIONAL { ?item wdt:P625  ?loc }
    FILTER("dens0" <= ?vanderk && ?vanderk < "dens9999").
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  } ORDER BY ?vanderk
  LIMIT 500
  

Try it!

Objekte in Hamburg mit Vanderkrogt-ID

The following query uses these:

• Properties: instance of (P31)   , Vanderkrogt.net Statues ID (P3711)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   

  SELECT ?vanderk ?item  ?isteinLabel ?itemLabel ?itemDescription ?liegtinLabel ?loc
  WHERE {
    ?item wdt:P31 ?istein.
    ?item wdt:P3711 ?vanderk.
    OPTIONAL { ?item wdt:P131  ?liegtin }
    OPTIONAL { ?item wdt:P625  ?loc }
    FILTER("dehh0" <= ?vanderk && ?vanderk < "dehh9999").
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  } ORDER BY ?vanderk
  LIMIT 500
  

Try it!

Straßen in Kiel

The following query uses these:

• Items: Kiel (Q1707)   , street (Q79007)   

• Properties: located in the administrative territorial entity (P131)   , instance of (P31)   , coordinate location (P625)   

  SELECT ?item ?itemLabel  ?liegtinLabel ?loc WHERE {
    # liegt in der Verwaltungseinheit, oder in einer Einheit die in dieser Verw.Einheit liegt
    ?item wdt:P131/wdt:P131? wd:Q1707.
    ?item wdt:P31 wd:Q79007.
    ?item wdt:P625 ?loc.
    ?item wdt:P131 ?liegtin.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  } ORDER BY ?itemLabel
  LIMIT 2000   # über 1000
  

Try it!