Status: Unknown

User:Back ache

From Wikidata
Jump to navigation Jump to search


Back ache is currently:

Somewhere

Check my status history for more info.
Update: On • Busy • Class • Away
Wikibreak • Asleep • Holiday • Off


My current project comes from the back of me needing to become prificanent in the computer language "powershell" and API's, rather then make examples , I am using this as an opportunity to "fill in the blanks" in wikidata entries by calling publicly available data using API's

Babel user information
en-GB-N This user has a native understanding of British English.
en-N This user has a native understanding of English.
es-1 Este usuario tiene un conocimiento básico del español.
Users by language

I have been reading public domain poems and adding the recordings to commons, Wikipedia and Wikidata, and wondered if a querys could help find me more that need doing.

Looking at Q3072813 I can see that it would be something like

  instance of P31 = poem Q5185279
  copyright status P6216 = public domain Q19652

and has no entry or value for

  spoken text audio (P989)

and is either in English (Q1860) or not tagged in as having a language at all

  language of work or name (P407)

https://hay.toolforge.org/vizquery/


I have tried adapting an existing query's as it seems more than 6000 of the poems haven't been tagged for the language they are in, 

#Public Domain Poems, without audio or a language
#defaultView:Table
SELECT ?item ?itemLabel ?author 
WHERE
{
?item wdt:P31 wd:Q5185279 .
?item wdt:P6216 wd:Q19652 .
?item wdt:P50 ?author  
    MINUS {?item wdt:P989 [] } .
    MINUS {?item wdt:P407 [] } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY DESC(?author)
Try it! 
#Public Domain Poems, in English but without audio
#defaultView:Table
SELECT ?item ?itemLabel ?pic
WHERE
{
?item wdt:P31 wd:Q5185279 .
?item wdt:P6216 wd:Q19652 .  
    MINUS {?item wdt:P989 [] } .
?item wdt:P407 wd:Q1860 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
Try it!
@Back ache:
#Public Domain Poems, in English  or with no P407 but without audio
SELECT ?item ?itemLabel WHERE
{
  ?item wdt:P31 wd:Q5185279 .
  ?item wdt:P6216 wd:Q19652 .  
  filter not exists  {?item wdt:P989 []. } 
  {?item wdt:P407 wd:Q1860 .}
  UNION 
  {FILTER NOT EXISTS {?item wdt:P407 [].} }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
Try it!
--Tagishsimon (talk) 12:41, 29 June 2021 (UTC)
#Poets, who write in English but don't have a Librivox link
#defaultView:Table
SELECT ?item ?itemLabel ?pic
WHERE
{
?item wdt:P106 wd:Q49757  .
?item wdt:P6886 wd:Q1860  .
    MINUS {?item wdt:P1899 [] } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
Try it! 
#Public Domain Poems, in English and with audio
#defaultView:Table
SELECT ?item ?itemLabel ?audio
WHERE
{
?item wdt:P31 wd:Q5185279 .
?item wdt:P6216 wd:Q19652 .  
?item wdt:P989 ?audio  .
?item wdt:P407 wd:Q1860 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
Try it! 
#Public Domain Limericks, in English and with audio
#defaultView:Table
SELECT ?item ?itemLabel ?audio
WHERE
{
?item wdt:P31 wd:Q204698 .
?item wdt:P989 ?audio  .

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
Try it! 


#Poe Poens not marked as an instance of a translation, but has a translator
#defaultView:Table
SELECT ?item ?itemLabel ?translator
WHERE
{
?item wdt:P31 wd:Q5185279 .
?item wdt:P50 wd:Q16867 .
?item wdt:P655 ?translator
  FILTER NOT EXISTS { 
    ?item wdt:P31 wd:Q3331189 .  
}
  

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
Try it! 
#Wikidata items of files in Category:Audio files of poetry WITHOUT anything in its P180
SELECT ?file ?title ?item
WITH
{
  SELECT ?file ?title
  WHERE
  {
    SERVICE wikibase:mwapi
    {
      bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "commons.wikimedia.org" .
      bd:serviceParam mwapi:gcmtitle "Category:Audio files of poetry" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "file" .
      bd:serviceParam mwapi:gcmlimit "max" .
      ?title wikibase:apiOutput mwapi:title .
      ?pageid wikibase:apiOutput "@pageid" .
    }
    BIND (URI(CONCAT('https://commons.wikimedia.org/entity/M', ?pageid)) AS ?file).
    MINUS {?item wdt:P180 [] }
  }
} AS %get_files
WHERE
{
  INCLUDE %get_files
 }
Try it! 
#title:Commons files in Category:Audio files of poetry WITHOUT anything in its P180
SELECT ?file ?title 
WITH
{
  SELECT ?file ?title
  WHERE
  {
    SERVICE wikibase:mwapi
    {
      bd:serviceParam wikibase:api "Generator" .
      bd:serviceParam wikibase:endpoint "commons.wikimedia.org" .
      bd:serviceParam mwapi:gcmtitle "Category:Audio files of poetry" .
      bd:serviceParam mwapi:generator "categorymembers" .
      bd:serviceParam mwapi:gcmtype "file" .
      bd:serviceParam mwapi:gcmlimit "max" .
      ?title wikibase:apiOutput mwapi:title .
      ?pageid wikibase:apiOutput "@pageid" .
    }
    BIND (URI(CONCAT('https://commons.wikimedia.org/entity/M', ?pageid)) AS ?file).
   }
} AS %get_files
WHERE
{
  INCLUDE %get_files
  MINUS {?file wdt:P180 [] .}
}



#What entrys are using URL match pattern and which contain VIAF
SELECT ?item ?itemLabel ?value
WHERE 
{
  ?item wdt:P8966 ?value
     FILTER (CONTAINS(lcase(?value), "viaf"))   
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # Helps get the label in your language, if not, then en language
}
Try it! 
#What noteable people don't have an ISNI
#Shows people raised in the public domain "life + 50 years".
SELECT ?item ?itemLabel ?genderLabel (GROUP_CONCAT(DISTINCT ?occupationLabel; SEPARATOR=", ") AS ?occupations) (GROUP_CONCAT(DISTINCT ?countryLabel; SEPARATOR=", ") AS ?countries) ?death ?articles {
  VALUES ?target_country { wd:Q16 wd:Q142 wd:Q39 wd:Q31 wd:Q145 } . #countries: Canada, France, Switzerland, Belgium, UK. Removing this line to get worldwide may cause a query timeout.
  VALUES ?occ { wd:Q2500638 wd:Q20826540 wd:Q215627 } . #occupation: creator, erudite, person. These 3 occupations will also look for subclasses. Example: Alan Turing is a cryptographer, a subclass of cryptologist, a subclass of mathematician, a subclass of scientist, a subclass of erudite.
   ?item wdt:P31 wd:Q5;
               wdt:P21 ?gender;
               wdt:P27 ?target_country;
               wdt:P27 ?country;
               wdt:P106/wdt:P279* ?occ ;
               wdt:P106 ?occupation;
               wikibase:sitelinks ?articles . #Service to count the number of articles in Wikipedia language versions. The higher the number, the greater the chances that the person is very notorious.
   ?item wdt:P570 ?death . hint:Prior hint:rangeSafe true .
  MINUS { ?item wdt:P213 [] }
   FILTER( ?death >= "1969-01-01T00:00:00"^^xsd:dateTime && ?death < "1970-01-01T00:00:00"^^xsd:dateTime ) #death: public domain "life+50 years". Change both years to get a list in different legislation. Example for USA: life+70 years
   SERVICE wikibase:label {
       bd:serviceParam wikibase:language "en" . #Service to retrieve the labels of items, in order of language. Example: if the label does not exist in French, the service will take the English label
       ?item rdfs:label ?itemLabel .
       ?gender rdfs:label ?genderLabel .
       ?occupation rdfs:label ?occupationLabel .
       ?country rdfs:label ?countryLabel .
   } .
} GROUP BY ?item ?itemLabel ?genderLabel ?death ?articles ORDER BY DESC (?articles) #Order by the number of articles in Wikipedia language versions. The most notorious people will be at the top of the list.
Try it! 
SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P27 wd:Q145.
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en,de,pt,es,no". }
  FILTER(NOT EXISTS {
    ?item rdfs:label ?lang_label.
    FILTER(LANG(?lang_label) = "en-gb")
  })
 }
 ORDER BY ?itemLabel
Try it!

podcasts[edit]

podcasts with a feed not a language with an apple id but not a feed List entries with an apple podcast id but no end date or episode count


Apple podcasts with an episode count and not and end date 


SELECT DISTINCT ?item WHERE {
  ?item p:P31 ?statement0.
  ?statement0 (ps:P31/(wdt:P279*)) wd:Q24634210.
  ?item p:P1113 ?statement1.
  ?statement1 (psv:P1113/wikibase:quantityAmount) ?numericQuantity.
  ?item p:P5842 ?statement2.
  ?statement2 (ps:P5842) _:anyValueP5842.
  MINUS {
    ?item p:P582 ?statement_3.
    ?statement_3 psv:P582 ?statementValue_3.
    ?statementValue_3 wikibase:timeValue ?P582_3.
  }
}
Try it!

tones[edit]

w:en:beat (acoustics)#Binaural beats

  • 174 Hz (Stress Relief)
  • 285 Hz (Heals Trauma)
  • 396 Hz (Release Fear)
  • 417 Hz (Remove Negative Energy)
  • 528 Hz (Positive Change)
  • 639 Hz (Love)
  • 741 Hz (Higher Consciousness)
  • 852 Hz (Awaken Intuition)
  • 963 Hz (Transcendence)

boats[edit]

http://marineplan.com/open-ship-data-api/ https://ais.marineplan.com/location/2/ship.json?ship=232043461 Shows thigs with an MMSI but not a callsign

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Back_ache&oldid=2087194350"