Talk:Q28026639
Jump to navigation
Jump to search
Autodescription — Christmas film (Q28026639)
description: film genre associated with Christmas
- Useful links:
- View it! – Images depicting the item on Commons
- Report on constraint conformation of “Christmas film” claims and statements. Constraints report for items data
For help about classification, see Wikidata:Classification.
- Parent classes (classes of items which contain this one item)
- Christmas film (Q28026639)
- fiction film (Q12912091)
- film (Q11424)
- fiction (Q8253) (◊)→
- recreative work (Q17538258)
- Christmas fiction (Q77762397)
- fiction film (Q12912091)
- Christmas film (Q28026639)
- Subclasses (classes which contain special kinds of items of this class)
- ⟨
Christmas film⟩ on wikidata tree visualisation (external tool)(depth=1) - Generic queries for classes
- See also
- This documentation is generated using
{{Item documentation}}.
Queries[edit]
actors[edit]
- Properties used: genre (P136)
, set during recurring event (P9215) , instance of (P31) , cast member (P161) , image (P18) , title (P1476)
- Features used: ImageGrid (Q24515278)
# by Jura1; December 20, 2021 - Merry Xmas
#title:actors in Christmas movies: by frequency, with film titles and sample film item
#defaultView:ImageGrid
SELECT ?item ?itemLabel ?itemDescription
(SAMPLE(?img) AS ?image)
(COUNT(DISTINCT ?film) AS ?count)
(GROUP_CONCAT(DISTINCT ?title; SEPARATOR = "; ") AS ?films)
(SAMPLE( ?film ) as ?sample_film)
WHERE
{
{ ?film wdt:P136 wd:Q28026639 } UNION { ?film wdt:P9215 wd:Q3517772 ; wdt:P31 wd:Q11424 }
?film wdt:P161 ?item.
OPTIONAL { ?item wdt:P18 ?img }
OPTIONAL { ?film wdt:P1476 ?title }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY DESC (?count)
LIMIT 100
filming locations[edit]
- Properties used: genre (P136) , set during recurring event (P9215) , instance of (P31) , filming location (P915) , coordinate location (P625) , image (P18) , title (P1476)
- Features used: map (Q24515275)
# by Jura1; December 20, 2021 - Merry Xmas
#title:filming locations of Christmas movies, with film titles and sample film item
#defaultView:Map{"hide":["?coor"]}
SELECT
?item ?itemLabel ?itemDescription
?coor
(SAMPLE ( ?img ) as ?image)
(COUNT(DISTINCT ?film) AS ?count)
(GROUP_CONCAT(DISTINCT ?title; SEPARATOR = "; ") AS ?films)
(SAMPLE( ?film ) as ?sample_film)
WHERE
{
{ ?film wdt:P136 wd:Q28026639 } UNION { ?film wdt:P9215 wd:Q3517772 ; wdt:P31 wd:Q11424 }
?film wdt:P915 ?item .
?item wdt:P625 ?coor .
OPTIONAL { ?item wdt:P18 ?img }
OPTIONAL { ?film wdt:P1476 ?title }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?itemDescription ?coor
ORDER BY DESC (?count)
films lacking filming location[edit]
- Properties used: genre (P136) , set during recurring event (P9215) , instance of (P31) , filming location (P915) , publication date (P577)
# by Jura1; December 20, 2021 - Merry Xmas
#title:recent Christmas movies lacking filming location
SELECT DISTINCT
?item ?itemLabel ?itemDescription (MIN(YEAR(?pub)) as ?year)
WHERE
{
{ ?item wdt:P136 wd:Q28026639 } UNION { ?item wdt:P9215 wd:Q3517772 ; wdt:P31 wd:Q11424 }
MINUS { ?item wdt:P915 [] }
?item wdt:P577 ?pub .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY DESC(?year)
LIMIT 200