Talk:Q1747944

Carte/Map

Map of transport network in ÎDF region (query)

@Bouzinac: Salut. Peut-on avoir la même chose avec ce qui est en construction ? Ce serait bien de pouvoir se représenter le réseau tel qu'il sera quand ces travaux seront terminés. Potentiellement on pourrait représenter les prolongements en pointillé, mais je ne sais pas si c'est possible ou même important. Thierry Caro (talk) 18:06, 25 April 2022 (UTC)

Bonsoir, voici un bon début (je n'ai pas été vérifier dans les détails mais à vue d'œil grande louche ça a l'air OK. j'ai juste un petit doute sur le mix entre station en construction et ligne en construction...)

#title: Carte des réseaux d'Île-de-France avec en vert, les fonctionnels et en jaune les en cours de construction
#defaultView:Map{"hide":["?coords", "?line","?rgb"]}
SELECT ?station ?stationLabel ?subwayLine ?coords ?line ?layer ?rgb WHERE {
 VALUES ?search {   wd:Q1142114 wd:Q389554 wd:Q50716 wd:Q216125  #critère de recherche de système de tramway
  }
     ?search wdt:P527 ?lignes.#quelles sont les lignes de ce tramway
     ?lignes wdt:P559 ?termini.#quels sont les terminus de ce tramway
 ?station wdt:P31/wdt:P279* wd:Q548662;  #de type poteau d'arrêt ou plus précis
          wdt:P361|wdt:P16 ?search;#qui font partie du réseau recherché
   wdt:P625 ?coords;
    wdt:P81|wdt:P1192 ?subwayLine;
   wdt:P197 ?pred.
 ?pred wdt:P625 ?coords_pred;
   wdt:P81|wdt:P1192 ?subwayLine_pred.  ?station p:P197 _:b1.
  _:b1 ps:P197 ?pred ;    pq:P5051 ?towards;    pq:P81|pq:P1192 ?line_pq .  
  ?subwayLine wdt:P1671 ?line_number.
  FILTER(?subwayLine_pred = ?lignes)#on ne prend les LIGNES que si la correspondance est sur la même ligne
  FILTER(?subwayLine = ?lignes)
  FILTER(?towards = ?termini) 
 ?pred  p:P625 ?node_pred .
  ?node_pred psv:P625/wikibase:geoLatitude ?lat1 ;psv:P625/wikibase:geoLongitude ?lon1 .
  ?node_pred a wikibase:BestRank.
  ?station p:P625 ?node_station.
 ?node_station psv:P625/wikibase:geoLatitude ?lat2 ;psv:P625/wikibase:geoLongitude ?lon2.
 ?node_station a wikibase:BestRank.
  BIND(CONCAT("LINESTRING(", STR(?lon1), " ", STR(?lat1),  ",", STR(?lon2), " ", STR(?lat2), ")") AS ?str)
  BIND(STRDT(?str, geo:wktLiteral) AS ?line)
  ?subwayLine wdt:P5817 ?etat_ligne.
  ?etat_ligne wdt:P465 ?rgb_ligne.
  ?station wdt:P5817 ?etat_station.
  ?etat_station wdt:P465 ?rgb_station.
  BIND(COALESCE(?rgb_station, ?rgb_ligne) AS ?rgb).
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
    ?subwayLine rdfs:label ?layer.
    ?pred rdfs:label ?predLabel.
    ?station rdfs:label ?stationLabel .
  } } GROUP BY ?station ?stationLabel ?subwayLine ?rgb ?predLabel ?layer ?coords ?line order by xsd:integer(?line_number) ?line_number ?subwayLine

Carte des réseaux d'Île-de-France avec en vert, les fonctionnels et en jaune les en cours de construction

Bouzinac ^{💬●✒️●💛} 16:43, 26 April 2022 (UTC)

@Bouzinac: Merci beaucoup. Ta nouvelle carte m'a permis de corriger pas mal de state of use (P5817) qui n'étaient pas corrects. En bidouillant à partir de l'ancien lien, je suis parvenu à faire une version en couleur qui couvre métros, trams et téléphérique. Thierry Caro (talk) 00:22, 27 April 2022 (UTC)