Wikidata:WikiProject Invasion biology

From Wikidata
Jump to navigation Jump to search

invasion biology (Q42985020): branch of biology that deals with the spread of alien species, with its building blocks theory, case studies and application, embedded in societal context
Lantana camara (Q332469): species of plant is native to Latin America and has spread to tropical and subtropical habitats around the globe.
Pterois volitans (Q824672): species of lionfish is native to the Pacific and invasive in the Western Atlantic
Six approaches for the analysis of living systems
Global air and sea traffic contributes to biological invasions by providing introduction pathways
Invasions can occur in any ecosystem

About

[edit]

This WikiProject is about invasion biology (Q42985020): branch of biology that deals with the spread of alien species as well as about biological, ecological, conservational and other aspects of invasive species (Q183368): non-native organism causing damage to an established environment.

Properties

[edit]

These properties should be tagged with maintained by WikiProject (P6104): WikiProject Invasion Biology (Q56241615). Note that usage of on focus list of Wikimedia project (P5008) for this is deprecated.

Existing

[edit]

Possibly relevant

[edit]

To be proposed

[edit]

Schemas

[edit]

Existing

[edit]
  • E392 for invasive taxa

To be considered

[edit]
  • invasion biologist
  • biological invasion
  • invaded habitat
  • native taxon in an invasion context
  • invasion biology publication
  • invasion biology journal
  • invasion biology hypothesis
  • invasion biology event

Items

[edit]

General concepts

[edit]

Invasive taxa by higher-level taxon group

[edit]

This is still very drafty. The emphasis here is on ecological relevance of the groupings, less on taxonomic precision.

Invasion biology hypotheses

[edit]

For the moment, we include rules.

Textbook examples

[edit]

Items with confusion potential

[edit]

Test items

[edit]

Themes

[edit]

Caveats

[edit]

Data sources

[edit]

Lexemes

[edit]

Lexemes associated with items about entities studied by invasion biology and/or ecology

[edit]

The following query uses these:

  • Properties: studied in (P2579)Β β€―View with ReasonatorΒ View with SQID, item for this sense (P5137)Β β€―View with ReasonatorΒ View with SQID
    #title: Lexemes associated with items about entities studied by invasion biology and/or ecology
SELECT 
DISTINCT ?qid
(GROUP_CONCAT(DISTINCT ?lemma; separator=" // ") AS ?lexemes)
(CONCAT("https://ordia.toolforge.org/Q", STR(?qid ) ) AS ?ordia)

WHERE {
  { ?item wdt:P2579 wd:Q42985020 .}
  UNION
  { ?item wdt:P2579 wd:Q7150 .}
  ?item ^wdt:P5137 ?sense .
  ?sense ^ontolex:sense ?lexeme .
  ?lexeme wikibase:lemma ?lemma .
  BIND(xsd:integer(STRAFTER(STR(?item), 'Q')) as ?qid)
}
GROUP BY ?qid ?lexemes ?ordia
ORDER BY ASC(?qid)
Lexemes associated with items about entities studied by invasion biology and/or ecology

Lexemes associated with topics that occur in the invasion biology literature

[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, item for this sense (P5137)Β β€―View with ReasonatorΒ View with SQID
    #title: Lexemes associated with topics that occur in the invasion biology literature
SELECT 
DISTINCT ?qid
(GROUP_CONCAT(DISTINCT ?lemma; separator=" // ") AS ?lexemes)
(CONCAT("https://ordia.toolforge.org/Q", STR(?qid ) ) AS ?ordia)

WHERE {
  { ?invasion_biology_item wdt:P6104 wd:Q56241615 ;
                           wdt:P921 ?item . }
  ?item ^wdt:P5137 ?sense .
  ?sense ^ontolex:sense ?lexeme .
  ?lexeme wikibase:lemma ?lemma .
  BIND(xsd:integer(STRAFTER(STR(?item), 'Q')) as ?qid)
}
GROUP BY ?qid ?lexemes ?ordia
ORDER BY ASC(?qid)
Lexemes associated with topics that occur in the invasion biology literature

Queries

[edit]

πŸͺ£ Content queries

[edit]

πŸͺ£ Generic

[edit]
πŸͺ£ Number of entities within scope of the WikiProject
[edit]

The following query uses these:

Try it!
πŸͺ£ Entity types within scope of the WikiProject
[edit]

The following query uses these:

  • Properties: instance of (P31)Β β€―View with ReasonatorΒ View with SQID, subclass of (P279)Β β€―View with ReasonatorΒ View with SQID, maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT 
  ?type ?typeLabel 
  ?count ?sample ?sampleLabel
WITH {
  SELECT DISTINCT ?type (COUNT(?item_) AS ?count) (SAMPLE(?item_) AS ?sample)  
  WHERE {
    ?item_ wdt:P31|wdt:P279 ?type .    
    ?item_ wdt:P6104 wd:Q56241615 .  
  }
  GROUP BY ?type ?count ?sample
} AS %items
WHERE {
  INCLUDE %items 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
}
GROUP BY ?type ?typeLabel ?count ?sample ?sampleLabel 
ORDER BY DESC(?count)
LIMIT 200
Try it!
πŸͺ£ Entities within scope of the WikiProject
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT 
  ?item ?itemLabel ?sitelinks
WITH {
  SELECT DISTINCT ?item ?sitelinks
  WHERE {
    ?item wdt:P6104 wd:Q56241615 .  
    ?item wikibase:sitelinks ?sitelinks.
  }
  GROUP BY ?item ?sitelinks
} AS %items
WHERE {
  INCLUDE %items 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
}
GROUP BY ?item ?itemLabel ?sitelinks
ORDER BY DESC(?sitelinks)
LIMIT 200
Try it!


πŸͺ£ Property use within scope of the WikiProject
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    SELECT DISTINCT ?property ?propertyLabel ?count
WITH {
  SELECT DISTINCT ?item WHERE {
    ?item wdt:P6104 wd:Q56241615 .
  }
  LIMIT 200000
  } AS %items 
WITH {
  SELECT DISTINCT ?property (COUNT(*) AS ?count) WHERE {
  INCLUDE %items.
    ?item ?p [ ] .
    ?property a wikibase:Property;
                wikibase:claim ?p.
  }
  GROUP BY ?property 
#   LIMIT 100
  } AS %results 
WHERE {
  INCLUDE %results.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY DESC(?count)
# LIMIT 100
Try it!
πŸͺ£ Pictorial overview of WikiProject Invasive species
[edit]

The following query uses these:

Features: ImageGrid (Q24515278)Β β€―View with ReasonatorΒ View with SQID

#defaultView:ImageGrid
PREFIX target: <http://www.wikidata.org/entity/Q56241615>

SELECT DISTINCT ?item (SAMPLE(?image_) AS ?image) WHERE {
  {
    # Images of the target
    target: wdt:P18 ?image_ .
  }
  UNION {
    # Images from whatever property value is linked.
    
    # Excluded "different from" property and take all other properties
    target: !wdt:P1889 ?item .

    ?item wdt:P18 ?image_ . 
    
    # All people are humans, so these images are excluded.
    FILTER (?item != wd:Q5)
  }
  UNION {
    # Images from whatever property value is linked.
    
    # Excluded "different from" property and take all other properties
    ?item !wdt:P1889 target: .

    ?item wdt:P18 ?image_ .     
  }
  ?item wikibase:sitelinks ?sitelinks .
}   
GROUP BY ?item ?image
ORDER BY DESC(?sitelinks)
LIMIT 200
Try it!
πŸͺ£ Entitites studied by invasion biology
[edit]

The following query uses these:

  • Properties: studied in (P2579)Β β€―View with ReasonatorΒ View with SQID
    #title: Entitites studied by invasion biology
SELECT DISTINCT ?item ?itemLabel
WHERE {
  ?item wdt:P2579 wd:Q42985020 .
  BIND(xsd:integer(STRAFTER(STR(?item), 'Q')) as ?qid)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" .}
}
ORDER BY ASC(?qid )
Entitites studied by invasion biology
πŸͺ£ Invasion biology in a broader context that includes restoration ecology, urban ecology and freshwater ecology
[edit]

The following query uses these:

Features: Graph (Q24515287)Β β€―View with ReasonatorΒ View with SQID

#defaultView:Graph
#title: Invasion biology in a broader context that includes restoration ecology, urban ecology and freshwater ecology

PREFIX target1: <http://www.wikidata.org/entity/Q183368> # invasive species
PREFIX target2: <http://www.wikidata.org/entity/Q2428433>  # restoration ecology
PREFIX target3: <http://www.wikidata.org/entity/Q60566657> # freshwater ecology
PREFIX target4: <http://www.wikidata.org/entity/Q1430301> # urban ecology
PREFIX target5: <http://www.wikidata.org/entity/Q42985020> # invasion biology

SELECT
  ?topic1 ?topic1Label ?rgb ?topic2 ?topic2Label 
WITH {
  SELECT
    (COUNT(DISTINCT ?work) AS ?count) ?topic1 ?topic2 ?rgb
  WHERE {
    # Find works that are marked with main subject of the topic.
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target1: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target2: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target3: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target4: .}
    UNION
    {?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target5: .}
    
    # Identify co-occuring topics. 
    ?work wdt:P921 ?topic1, ?topic2 . 

    # Exclude the topic it self
    FILTER (target1: != ?topic1 && target1: != ?topic2 && ?topic1 != ?topic2)
      BIND(IF(?topic1 = target5:,"7FFF00",
              IF( ?topic1 = target4:, "3080BB",
                IF( ?topic1 = target3:, "3080BB",
                  IF( ?topic1 = target2:, "3080BB",
                "FFA500"
                     )
                  )
                )
              )
           AS ?rgb).
  }
  GROUP BY ?topic1 ?topic2 ?rgb
  ORDER BY DESC(?count)

  # There a performance problems in the browser: We cannot show large graphs,
  # so we put a limit on the number of links displayed.
  LIMIT 200

} AS %results
WHERE {
  INCLUDE %results
  
  # Label the results
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh".
  }
}
Invasion biology in a broader context that includes restoration ecology, urban ecology and freshwater ecology
πŸͺ£ Most recently created entities within scope of the WikiProject
[edit]

The following query uses these:

SELECT ?item ?itemLabel {
  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:endpoint "www.wikidata.org";
                    wikibase:api "Generator" ;
                    wikibase:limit "once" ;
                    mwapi:generator "search";
                    mwapi:gsrsearch "haswbstatement:P6104=Q56241615" ;
                    mwapi:gsrsort "create_timestamp_desc" ;
                    mwapi:gsrlimit "100".
    ?item wikibase:apiOutputItem mwapi:title.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(xsd:integer(SUBSTR(STR(?item), 33)))
Try it!

πŸͺ£ Taxa

[edit]
πŸͺ£ Taxon names sorted by association with invasion biology in the literature
[edit]
πŸͺ£ Overall
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, taxon name (P225)Β β€―View with ReasonatorΒ View with SQID, taxon rank (P105)Β β€―View with ReasonatorΒ View with SQID, parent taxon (P171)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT 
  ?topic ?speciesname ?classname 
  ?count
  (CONCAT('https://scholia.toolforge.org/taxon/', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q")), '/curation') AS ?taxon_curation) 

WITH {
  SELECT DISTINCT ?topic 
  (COUNT(?paper) AS ?count)
  WHERE {
  ?paper wdt:P6104 wd:Q56241615 ;
         wdt:P921 ?topic .
  }  
  GROUP BY ?topic ?count
} AS %papers
WITH {
  SELECT DISTINCT ?topic ?speciesname ?count WHERE {
    INCLUDE %papers
  ?topic wdt:P225 ?speciesname ;
         wdt:P105 wd:Q7432 .

  }
  GROUP BY ?topic ?speciesname ?count
  
} AS %species

WHERE {
  INCLUDE %species
  ?topic wdt:P171* ?class .
  ?class wdt:P105 wd:Q37517;
         wdt:P225 ?classname .
}
GROUP BY ?topic ?speciesname ?classname ?count ?taxon_curation
ORDER BY DESC(?count)
Try it!
πŸͺ£ By taxonomic kingdom
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, taxon name (P225)Β β€―View with ReasonatorΒ View with SQID, taxon rank (P105)Β β€―View with ReasonatorΒ View with SQID, parent taxon (P171)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT 
  ?topic ?kingdomname ?speciesname
  ?count
  (CONCAT('https://scholia.toolforge.org/taxon/', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q")), '/curation') AS ?taxon_curation) 

WITH {
  SELECT DISTINCT ?topic 
  (COUNT(?paper) AS ?count)
  WHERE {
  ?paper wdt:P6104 wd:Q56241615 ;
         wdt:P921 ?topic .
  }  
  GROUP BY ?topic ?count
} AS %papers
WITH {
  SELECT DISTINCT ?topic ?speciesname ?count WHERE {
    INCLUDE %papers
  ?topic wdt:P225 ?speciesname ;
         wdt:P105 wd:Q7432 .

  }
  GROUP BY ?topic ?speciesname ?count
#  HAVING (?count > 25)
  
} AS %species

WHERE {
  INCLUDE %species
  ?topic wdt:P171* ?kingdom .
  ?kingdom wdt:P105 wd:Q36732;
         wdt:P225 ?kingdomname .
}
GROUP BY ?topic ?kingdomname ?speciesname ?count ?taxon_curation
ORDER BY ASC(?kingdomname) DESC(?count)
Try it!
πŸͺ£ By taxonomic class
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, taxon name (P225)Β β€―View with ReasonatorΒ View with SQID, taxon rank (P105)Β β€―View with ReasonatorΒ View with SQID, parent taxon (P171)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT 
  ?topic ?classname ?speciesname
  ?count
  (CONCAT('https://scholia.toolforge.org/taxon/', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q")), '/curation') AS ?taxon_curation) 

WITH {
  SELECT DISTINCT ?topic 
  (COUNT(?paper) AS ?count)
  WHERE {
  ?paper wdt:P6104 wd:Q56241615 ;
         wdt:P921 ?topic .
  }  
  GROUP BY ?topic ?count
} AS %papers
WITH {
  SELECT DISTINCT ?topic ?speciesname ?count WHERE {
    INCLUDE %papers
  ?topic wdt:P225 ?speciesname ;
         wdt:P105 wd:Q7432 .

  }
  GROUP BY ?topic ?speciesname ?count
#  HAVING (?count > 25)
  
} AS %species

WHERE {
  INCLUDE %species
  ?topic wdt:P171* ?class .
  ?class wdt:P105 wd:Q37517;
         wdt:P225 ?classname .
}
GROUP BY ?topic ?classname ?speciesname ?count ?taxon_curation
ORDER BY ASC(?classname) DESC(?count)
Try it!
πŸͺ£ Most common fish in the invasion biology literature
[edit]

The following query uses these:

Features: BubbleChart (Q24515280)Β β€―View with ReasonatorΒ View with SQID

#title: Most common fish in the invasion biology literature
#defaultView:BubbleChart

PREFIX target: <http://www.wikidata.org/prop/direct/P921>

SELECT ?count ?o ?taxonname 
WITH {
  SELECT (COUNT(?s) AS ?count) ?o WHERE {
    ?s target: ?o .
    ?o wdt:P105 wd:Q7432 .
    ?o wdt:P6104 wd:Q56241615 .
    ?o wdt:P938 ?fishbase .
  }
  GROUP BY ?o
  ORDER BY DESC(?count)
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  ?o wdt:P225 ?taxonname .
}
ORDER BY DESC(?count)
Most common fish in the invasion biology literature
πŸͺ£ Within-scope papers about Rosaceae
[edit]

The following query uses these:

  • Properties: main subject (P921)Β β€―View with ReasonatorΒ View with SQID, maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, title (P1476)Β β€―View with ReasonatorΒ View with SQID, parent taxon (P171)Β β€―View with ReasonatorΒ View with SQID
    #title: Within-scope papers about Rosaceae
SELECT ?paper ?title ?topic ?topicLabel

WHERE {
  ?paper wdt:P921 ?topic ;
         wdt:P6104 wd:Q56241615 ;
         wdt:P1476 ?title .
  ?topic wdt:P171* wd:Q46299 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
}
Within-scope papers about Rosaceae
πŸͺ£ Taxa within scope of the project
[edit]

See also #Invasive species without an image on Wikidata.


The following query uses these:

Features: ImageGrid (Q24515278)Β β€―View with ReasonatorΒ View with SQID

#defaultView:ImageGrid
SELECT 
  DISTINCT 
  ?topic ?taxonname (SAMPLE(?image_) AS ?image)
  (COUNT(?paper) AS ?count)
WHERE {
  ?paper wdt:P6104 wd:Q56241615 ;
         wdt:P921 ?topic .
  ?topic wdt:P225 ?taxonname ;
         wdt:P105 wd:Q7432 .
  ?topic wdt:P18 ?image_.
}
GROUP BY ?topic ?taxonname ?image ?count
ORDER BY DESC(?count)
LIMIT 200
Try it!
πŸͺ£ In-scope taxa as depicted in art
[edit]

The following query uses these:

Features: ImageGrid (Q24515278)Β β€―View with ReasonatorΒ View with SQID

#defaultView:ImageGrid
SELECT 
  DISTINCT 
?taxon ?taxonname ?pic ?image
WHERE {
  ?taxon wdt:P6104 wd:Q56241615 ;
         wdt:P225 ?taxonname ;
         wdt:P105 wd:Q7432 .
  FILTER (?taxon != wd:Q15978631 )
  FILTER (?taxon != wd:Q140 )
  ?pic wdt:P180 ?taxon ;
       wdt:P18 ?image .
}
Try it!
[edit]

The following query uses these:

Features: ImageGrid (Q24515278)Β β€―View with ReasonatorΒ View with SQID

#defaultView:ImageGrid
SELECT DISTINCT ?item ?taxonname (SAMPLE(?image_) AS ?image) ?linkcount WHERE {

  {?item wdt:P5698 [].} UNION {?item wdt:P5626 [].}
#   ?item wdt:P6104 wd:Q56241615 . 
  ?item wdt:P18 ?image_ ;
        wdt:P225 ?taxonname.
  ?work wdt:P921 ?item .
  ?item wikibase:sitelinks ?linkcount .
}
GROUP BY ?item ?taxonname ?image ?linkcount
ORDER BY DESC(?linkcount)
Try it!

πŸͺ£ Publications

[edit]
πŸͺ£ Works within scope of WikiProject Invasion Biology
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, DOI (P356)Β β€―View with ReasonatorΒ View with SQID
    #title: Publications within scope of WikiProject Invasion biology

SELECT DISTINCT ?item ?itemLabel 
WHERE {
  ?item wdt:P6104 wd:Q56241615;
        wdt:P356 ?doi .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel
Publications within scope of WikiProject Invasion biology


πŸͺ£ Topics of works within scope of WikiProject Invasion Biology
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID
    #title: Topics of works within scope of WikiProject Invasion Biology
SELECT ?count ?topic ?topicLabel ?example_work ?example_workLabel
WITH {
  SELECT DISTINCT ?topic (SAMPLE(?work) AS ?example_work) (COUNT(?work) AS ?count) WHERE {
    # Find works for the specific queried topic
    ?work wdt:P6104 wd:Q56241615 .

    # Find co-occuring topics
    ?work wdt:P921 ?topic .

  }
  GROUP BY ?topic
} AS %result
WHERE {
  # Label the results
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
ORDER BY DESC(?count)
LIMIT 200
Topics of works within scope of WikiProject Invasion Biology


πŸͺ£ Items about invasion biology hypothesis papers
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, DOI (P356)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, instance of (P31)Β β€―View with ReasonatorΒ View with SQID
    #title: Items about invasion biology hypothesis papers
SELECT DISTINCT ?item ?itemLabel ?topic ?topicLabel ?doi
WHERE { 
  ?item wdt:P6104 wd:Q56241615 ;
        wdt:P356 ?doi ;
        wdt:P921 ?topic .
  ?topic wdt:P31 wd:Q41719 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?topic ?topicLabel ?doi
ORDER BY DESC(?doi)
Items about invasion biology hypothesis papers
πŸͺ£ Openly licensed invasion biology publications about hypotheses known to Wikidata
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, DOI (P356)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, instance of (P31)Β β€―View with ReasonatorΒ View with SQID, copyright license (P275)Β β€―View with ReasonatorΒ View with SQID, subclass of (P279)Β β€―View with ReasonatorΒ View with SQID
    #title: Openly licensed invasion biology publications about hypotheses known to Wikidata
SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
WHERE { 
  ?item wdt:P6104 wd:Q56241615;
        wdt:P356 ?doi ;
        wdt:P921 ?topic .
  ?topic wdt:P31 wd:Q41719 .        
  ?item wdt:P275 ?license .
  ?license wdt:P31*/wdt:P279* wd:Q30939938 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
Openly licensed invasion biology publications about hypotheses known to Wikidata
πŸͺ£ Items about invasion biology theme papers
[edit]

The following query uses these:

  • Properties: main subject (P921)Β β€―View with ReasonatorΒ View with SQID, maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, DOI (P356)Β β€―View with ReasonatorΒ View with SQID
    #title: Items about invasion biology theme papers
SELECT DISTINCT ?item ?itemLabel ?theme ?themeLabel ?doi
WHERE {
  VALUES ?theme { wd:Q112148709 wd:Q109467185 wd:Q111525751 wd:Q113019190 }
  ?item wdt:P921 ?theme ;
        wdt:P6104 wd:Q56241615 ;
        wdt:P356 ?doi .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?theme ?themeLabel ?doi
ORDER BY DESC(?doi)
Items about invasion biology theme papers
πŸͺ£ Invasion biology publications for inclusion in the OAI-PMH endpoint
[edit]

The results of this query are exposed (about weekly) via the OAI-PMH endpoint for WikiProject Invasion biology.

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, DOI (P356)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, instance of (P31)Β β€―View with ReasonatorΒ View with SQID, copyright license (P275)Β β€―View with ReasonatorΒ View with SQID, subclass of (P279)Β β€―View with ReasonatorΒ View with SQID
    #title: Invasion biology publications for inclusion in the OAI-PMH endpoint

SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
WHERE {
  ?item wdt:P6104 wd:Q56241615;
        wdt:P356 ?doi ;
        wdt:P921 ?topic .
 
  {?topic wdt:P31 wd:Q41719 .}
  UNION
  {VALUES ?topic { wd:Q109467185 wd:Q112148709 wd:Q111525751 wd:Q113019190} }
  UNION
  {?item wdt:P275 ?license .
  ?license wdt:P31*/wdt:P279* wd:Q30939938 .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?license ?licenseLabel ?topic ?topicLabel
Invasion biology publications for inclusion in the OAI-PMH endpoint
πŸͺ£ Language distribution of works within scope of the project
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    PREFIX target: <http://www.wikidata.org/prop/direct/P407>

SELECT ?count ?Language ?LanguageLabel 
WITH {
  SELECT (COUNT(?s) AS ?count) ?Language WHERE {
    ?s target: ?Language .
    ?s wdt:P6104 wd:Q56241615 .
  }
  GROUP BY ?Language
  ORDER BY DESC(?count)
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language  "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . }
}
ORDER BY DESC(?count)
Try it!
πŸͺ£ Works that are (i) used as references and (b) have a topic that is a species with either a Global Invasive Species Database ID (P5626) or an Invasive Species Compendium Datasheet ID (P5698)
[edit]

The following query uses these:

Try it!
πŸͺ£ Works in scope by publication venue and its main subjects
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, published in (P1433)Β β€―View with ReasonatorΒ View with SQID, part of the series (P179)Β β€―View with ReasonatorΒ View with SQID, short name (P1813)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID
    #defaultView:Table
SELECT ?count ?short_name ?venue ?venueLabel ?topic ?topicLabel
WITH {
  SELECT (count(?work) as ?count) ?venue (SAMPLE(?short_name_) AS ?short_name) WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P1433/wdt:P179* ?venue .
    OPTIONAL { ?venue wdt:P1813 ?short_name_ . }
  }
  GROUP BY ?venue
} AS %result
WHERE {
  INCLUDE %result
  OPTIONAL  { ?venue wdt:P921 ?topic }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
ORDER BY DESC(?count)
Try it!
πŸͺ£ Works in scope available under an Open Definition-compliant license
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, copyright license (P275)Β β€―View with ReasonatorΒ View with SQID, instance of (P31)Β β€―View with ReasonatorΒ View with SQID, subclass of (P279)Β β€―View with ReasonatorΒ View with SQID
    SELECT DISTINCT ?item ?itemLabel ?license ?licenseLabel
WHERE { 
  ?item wdt:P6104 wd:Q56241615 . 
  ?item wdt:P275 ?license .
  ?license wdt:P31*/wdt:P279* wd:Q30939938 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?license ?licenseLabel
LIMIT 200
Try it!
πŸͺ£ In-scope articles with no license statement, by their identifiers (DOI, PubMed ID, PubMed Central ID)
[edit]

The following query uses these:

In-scope articles with no license statement, by their identifiers (DOI, PubMed ID, PubMed Central ID)


[edit]

The following query uses these:

In-scope articles by authors related to Canada

πŸͺ£ Hypotheses

[edit]
πŸͺ£ List of hypotheses studied by invasion biology
[edit]

The following query uses these:

  • Properties: instance of (P31)Β β€―View with ReasonatorΒ View with SQID, studied in (P2579)Β β€―View with ReasonatorΒ View with SQID
    SELECT ?hypothesis ?hypothesisLabel WHERE {
  ?hypothesis wdt:P31 wd:Q41719 ;
        wdt:P2579 wd:Q42985020 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
}
Try it!
πŸͺ£ List of hypotheses within scope of this Wikiproject
[edit]

Some hypotheses may be studied by fields broader than invasion biology, so they would not be listed in the results of the above query for "List of hypotheses studied by invasion biology".

The following query uses these:

  • Properties: instance of (P31)Β β€―View with ReasonatorΒ View with SQID, maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID
    SELECT DISTINCT ?hypothesis ?hypothesisLabel WHERE {
  ?hypothesis wdt:P31 wd:Q41719 .
  {?hypothesis wdt:P6104 wd:Q56241615 .}
  UNION
  {?paper wdt:P6104 wd:Q56241615 ;
          wdt:P921 ?hypothesis .  }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }  
}
Try it!

πŸͺ£ People

[edit]
πŸͺ£ Authors publishing about invasion biology
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, author (P50)Β β€―View with ReasonatorΒ View with SQID
    #defaultView:Table
SELECT ?count ?author ?authorLabel ?sample_pub ?sample_pubLabel
WITH {
  SELECT (count(DISTINCT ?work) as ?count) ?author (SAMPLE(?work) AS ?sample_pub) WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P921 ?topic . 
    ?work wdt:P50 ?author .
  }
  GROUP BY ?author
  ORDER BY DESC(?count)
  LIMIT 200
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
}
ORDER BY DESC(?count)
Try it!
πŸͺ£ Authors publishing about invasion biology who are not tagged as within scope of this WikiProject
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, author (P50)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
DISTINCT
  (REPLACE(STR(?author), ".*Q", "Q") AS ?qid) 
  ("P6104" AS ?property)
  ("Q56241615" AS ?ReplaceWithYourTargetID)

WITH {
  SELECT (count(DISTINCT ?work) as ?count) ?author 
  WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P921 ?topic . 
    ?work wdt:P50 ?author .
    MINUS { ?author wdt:P6104 wd:Q56241615 }
  }
  GROUP BY ?author
  HAVING(?count > 9)
  LIMIT 200
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
}
Try it!


πŸͺ£ Authors tagged as within scope of this WikiProject who have less than three in-scope papers
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, author (P50)Β β€―View with ReasonatorΒ View with SQID
    SELECT

DISTINCT
  (REPLACE(STR(?author), ".*Q", "-Q") AS ?qid)
  ("P6104" AS ?property)
  ("Q56241615" AS ?ReplaceWithYourTargetID)

WITH {
  SELECT (count(DISTINCT ?work) as ?count) ?author
  WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P921 ?topic .
    ?work wdt:P50 ?author .
    ?author wdt:P6104 wd:Q56241615
  }
  GROUP BY ?author
  HAVING(?count < 3)
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . }
}
Try it!
πŸͺ£ Authors tagged as within scope of this WikiProject who have no in-scope papers
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, instance of (P31)Β β€―View with ReasonatorΒ View with SQID, author (P50)Β β€―View with ReasonatorΒ View with SQID
    SELECT
DISTINCT
  (REPLACE(STR(?author), ".*Q", "-Q") AS ?qid)
  ("P6104" AS ?property)
  ("Q56241615" AS ?ReplaceWithYourTargetID)

WITH {
  SELECT DISTINCT ?author
  WHERE {
    ?author wdt:P6104 wd:Q56241615 ;
            wdt:P31 wd:Q5 .
    FILTER NOT EXISTS {    ?work wdt:P50 ?author ; wdt:P6104 wd:Q56241615 .}
  }
  GROUP BY ?author
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . }
}
Try it!
πŸͺ£ Awards received by people studying invasion biology
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, instance of (P31)Β β€―View with ReasonatorΒ View with SQID, award received (P166)Β β€―View with ReasonatorΒ View with SQID
    SELECT ?count ?award ?awardLabel ?recipients ?recipientsUrl
WITH {
  SELECT (COUNT(?researcher) AS ?count) ?award 
  (GROUP_CONCAT(DISTINCT ?researcher_label; separator=", ") AS ?recipients) 
  (CONCAT("https://scholia.toolforge.org/authors/", GROUP_CONCAT(DISTINCT SUBSTR(STR(?researcher), 32); separator=",")) AS ?recipientsUrl)
  WHERE {
    { 
      SELECT DISTINCT ?researcher ?award WHERE {
        hint:Query hint:optimizer "None" .
        ?researcher wdt:P6104 wd:Q56241615 ; 
                    wdt:P31 wd:Q5 ;
                    wdt:P166 ?award .
      } 
      LIMIT 100000
    }
    ?researcher rdfs:label ?researcher_label . FILTER (LANG(?researcher_label) = 'en')
  }
  GROUP BY ?award 
} AS %result
WHERE {
  INCLUDE %result
    ?award rdfs:label ?awardLabel . FILTER (LANG(?awardLabel) = 'en')
}
GROUP BY ?count ?award ?awardLabel ?recipients ?recipientsUrl
ORDER BY DESC(?count)
Try it!

πŸͺ£ Organizations

[edit]
πŸͺ£ Institutions associated with authors publishing about invasion biology
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, author (P50)Β β€―View with ReasonatorΒ View with SQID, employer (P108)Β β€―View with ReasonatorΒ View with SQID, member of (P463)Β β€―View with ReasonatorΒ View with SQID, affiliation (P1416)Β β€―View with ReasonatorΒ View with SQID, part of (P361)Β β€―View with ReasonatorΒ View with SQID
    #defaultView:Table
SELECT ?count ?organization ?organizationLabel ?sample_author ?sample_authorLabel
WITH {
  SELECT (count(DISTINCT ?work) as ?count) ?organization (SAMPLE(?author) AS ?sample_author) WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P921 ?topic . 
    ?work wdt:P50 ?author .
    ?author ( wdt:P108 | wdt:P463 | wdt:P1416 ) / wdt:P361* ?organization . 
  }
  GROUP BY ?organization ?sample_author
  ORDER BY DESC(?count)
  LIMIT 200
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTOLANG],en" . } 
}
GROUP BY ?count ?organization ?organizationLabel ?sample_author ?sample_authorLabel
ORDER BY DESC(?count)
Try it!

πŸͺ£ Chemicals

[edit]
πŸͺ£ Chemicals within scope of the project
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, InChIKey (P235)Β β€―View with ReasonatorΒ View with SQID, ChEBI ID (P683)Β β€―View with ReasonatorΒ View with SQID
    #title: Chemicals associated with the invasion biology literature

SELECT 
  DISTINCT 
    ?topic ?topicLabel 
    ?count 
    ?SamplePaper ?SamplePaperLabel
    (CONCAT('https://scholia.toolforge.org/topics/Q42985020,Q183368,', ENCODE_FOR_URI(REPLACE(STR(?topic), ".*Q", "Q"))) AS ?curation_url ) 
WITH {
  SELECT 
  ?topic
  (COUNT(?paper_) AS ?count)
  (SAMPLE(?paper_) AS ?SamplePaper)
  {
    ?paper_ wdt:P6104 wd:Q56241615 ;
            wdt:P921 ?topic .
  }
  GROUP BY ?topic ?count ?SamplePaper
}
AS %topics
WHERE {
  INCLUDE %topics
  { ?topic wdt:P235 ?InChIKey .}
  UNION
  { ?topic wdt:P683 ?ChEBI .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?topic ?topicLabel ?count ?SamplePaper ?SamplePaperLabel ?curation_url 
ORDER BY DESC(?count)
Chemicals associated with the invasion biology literature

πŸͺ£ Habitats

[edit]
πŸͺ£ Map of geolocated entities co-occurring with invasive species in the literature
[edit]

The following query uses these:

Features: map (Q24515275)Β β€―View with ReasonatorΒ View with SQID

#defaultView:Map

PREFIX target: <http://www.wikidata.org/entity/Q183368>

SELECT
  ?location ?locationLabel
  ?geo
  ?example_work ?example_workLabel
WITH {
  SELECT
    ?location ?geo
    (SAMPLE(?work) AS ?example_work)
  WHERE {
    # Find works that are marked with main subject of the topic.
    ?work wdt:P921 / ( wdt:P31*/wdt:P279* | wdt:P361+ | wdt:P1269+ ) target: .
    
    # Identify co-occuring topic that is geo-locatable. 
    ?work wdt:P921 ?location .
    ?location wdt:P625 ?geo .
  }
  GROUP BY ?location ?geo
} AS %results
WHERE {
  INCLUDE %results
  
  # Label the results
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh".
  }
}
Try it!

πŸͺ£ Journals

[edit]
πŸͺ£ Journals publishing about invasive species
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, published in (P1433)Β β€―View with ReasonatorΒ View with SQID, part of the series (P179)Β β€―View with ReasonatorΒ View with SQID, short name (P1813)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID
    #defaultView:Table
SELECT ?count ?short_name ?venue ?venueLabel ?topic ?topicLabel
WITH {
  SELECT (count(?work) as ?count) ?venue (SAMPLE(?short_name_) AS ?short_name) WHERE {
    ?work wdt:P6104 wd:Q56241615 .
    ?work wdt:P1433/wdt:P179* ?venue .
    OPTIONAL { ?venue wdt:P1813 ?short_name_ . }
  }
  GROUP BY ?venue
} AS %result
WHERE {
  INCLUDE %result
  OPTIONAL  { ?venue wdt:P921 ?topic }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
ORDER BY DESC(?count)
Try it!

πŸͺ£ Methods

[edit]
πŸͺ£ Methods used for research described in in-scope publications
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, describes a project that uses (P4510)Β β€―View with ReasonatorΒ View with SQID
    SELECT
  ?count
  ?use ?useLabel 
  ?useDescription
  ?example_work ?example_workLabel
WITH {
  SELECT
    (COUNT(?work) AS ?count)
    ?use
    (SAMPLE(?work) AS ?example_work)
  {
    ?work wdt:P6104 wd:Q56241615 ;
          wdt:P4510 ?use .
  }
  GROUP BY ?use
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?count)
Try it!

πŸͺ£ Lexemes

[edit]
πŸͺ£ Overview
[edit]

The following query uses these:

  • Properties: item for this sense (P5137)Β β€―View with ReasonatorΒ View with SQID, maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    #title: Items within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes
# adapted from https://w.wiki/5H28
SELECT ?item ?itemLabel ?count ?langExample ?langExampleLabel (SAMPLE(?lexeme) AS ?lexemeExample) (SAMPLE(?lemma) AS ?lemmaExample) (SAMPLE(?sens) AS ?sense) {
  {
    SELECT ?item (COUNT(DISTINCT ?lang) AS ?count) (SAMPLE(?lang) AS ?langExample) {
      ?sens wdt:P5137 ?item .
      ?lexeme ontolex:sense ?sens ;
              dct:language ?lang .
      ?item wdt:P6104 wd:Q56241615 .
  
    } 
    GROUP BY ?item
  }
  
  ?lexeme ontolex:sense ?sens ;
          dct:language ?langExample ;
          wikibase:lemma ?lemma .
  ?sens wdt:P5137 ?item .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?count ?langExample ?langExampleLabel ?lemmaExample
ORDER BY DESC(?count)
Items within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes
[edit]

The following query uses these:

  • Properties: item for this sense (P5137)Β β€―View with ReasonatorΒ View with SQID, studied in (P2579)Β β€―View with ReasonatorΒ View with SQID
    #title: Concepts studied by ecology or invasion biology, sorted by number of languages with associated lexemes
# adapted from https://w.wiki/5H28
SELECT ?item ?itemLabel ?count ?langExample ?langExampleLabel (SAMPLE(?lexeme) AS ?lexemeExample) (SAMPLE(?lemma) AS ?lemmaExample) (SAMPLE(?sens) AS ?sense) {
  {
    SELECT ?item (COUNT(DISTINCT ?lang) AS ?count) (SAMPLE(?lang) AS ?langExample) {
      ?sens wdt:P5137 ?item .
      ?lexeme ontolex:sense ?sens ;
              dct:language ?lang .
      { ?item wdt:P2579 wd:Q7150 . }
      UNION
      { ?item wdt:P2579 wd:Q42985020 . }
    } 
    GROUP BY ?item
  }
  
  ?lexeme ontolex:sense ?sens ;
          dct:language ?langExample ;
          wikibase:lemma ?lemma .
  ?sens wdt:P5137 ?item .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?count ?langExample ?langExampleLabel ?lemmaExample
ORDER BY DESC(?count)
Concepts studied by ecology or invasion biology, sorted by number of languages with associated lexemes
[edit]

The following query uses these:

  • Properties: item for this sense (P5137)Β β€―View with ReasonatorΒ View with SQID, maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, taxon name (P225)Β β€―View with ReasonatorΒ View with SQID
    #title: Taxa within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes
# adapted from https://w.wiki/5H28
SELECT ?item ?itemLabel ?taxonname ?count ?langExample ?langExampleLabel (SAMPLE(?lexeme) AS ?lexemeExample) (SAMPLE(?lemma) AS ?lemmaExample) (SAMPLE(?sens) AS ?sense) {
  {
    SELECT ?item ?taxonname (COUNT(DISTINCT ?lang) AS ?count) (SAMPLE(?lang) AS ?langExample) {
      ?sens wdt:P5137 ?item .
      ?lexeme ontolex:sense ?sens ;
              dct:language ?lang .
      ?item wdt:P6104 wd:Q56241615 ;
            wdt:P225 ?taxonname .
    } 
    GROUP BY ?item ?taxonname
  }
  
  ?lexeme ontolex:sense ?sens ;
          dct:language ?langExample ;
          wikibase:lemma ?lemma .
  ?sens wdt:P5137 ?item .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?taxonname ?count ?langExample ?langExampleLabel ?lemmaExample
ORDER BY DESC(?count)
Taxa within scope of WikiProject Invasion biology, sorted by number of languages with associated lexemes

⚽ Community queries

[edit]

⚽ Recent changes

[edit]

Scholia's curation pages (example) now point to a set of recent changes pages in a way that is generic for a given Scholia page. The links below point to pages that list recent changes to pages that are

⚽ Overlap with other WikiProjects

[edit]

The following query uses these:


Features: BubbleChart (Q24515280)Β β€―View with ReasonatorΒ View with SQID

#defaultView:BubbleChart

PREFIX target: <http://www.wikidata.org/prop/direct/P6104>

SELECT ?count ?o ?oLabel 
WITH {
  SELECT (COUNT(?s) AS ?count) ?o WHERE {
    ?s target: wd:Q56241615 .
    ?s target: ?o .
    FILTER (?o != wd:Q56241615)
  }
  GROUP BY ?o
  ORDER BY DESC(?count)
  LIMIT 100
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language  "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . }
}
ORDER BY DESC(?count)
Try it!

🌿 Property queries

[edit]
🌿 Properties used on items about invasive species
[edit]

More precisely, the query asks about properties used on items that have a Global Invasive Species Database ID (P5626): identifier for a taxon in the IUCN's Global Invasive Species Database.

The following query uses these:

  • Properties: Global Invasive Species Database ID (P5626)Β β€―View with ReasonatorΒ View with SQID
    SELECT DISTINCT ?property ?propertyLabel ?count
WITH {
  SELECT DISTINCT ?property (COUNT(*) AS ?count) WHERE {
    ?item wdt:P5626 [];
    ?p [ ] .
    ?property a wikibase:Property;
                wikibase:claim ?p.
  }
  GROUP BY ?property 
  } AS %results WHERE {
  INCLUDE %results.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY DESC(?count)
LIMIT 100
Try it!
🌿 External identifier properties used on items about works within scope of the project
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID, title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT ?ExternalIdentifierProperty ?ExternalIdentifierPropertyLabel ?count WHERE {
    {
        SELECT ?ExternalIdentifierProperty (COUNT(DISTINCT ?item) AS ?count) WHERE {
           
           hint:Query hint:optimizer "None" .
           ?item wdt:P6104 wd:Q56241615 ;
                 wdt:P1476 ?title .
           ?item ?p ?id .
           ?ExternalIdentifierProperty wikibase:directClaim ?p; wikibase:propertyType wikibase:ExternalId.     
        }  GROUP BY ?ExternalIdentifierProperty
    }
    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
    }
}
ORDER BY DESC(?count)
Try it!

🌿 Properties maintained by the WikiProject

[edit]
🌿 List of properties maintained by the WikiProject
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    #:title: List of properties maintained by the WikiProject
SELECT DISTINCT ?property ?propertyLabel (COUNT(DISTINCT ?entity) AS ?count) WHERE {
  ?entity wdt:P6104 wd:Q56241615 .
  ?entity ?p [ ] .
  ?property a wikibase:Property;
              wikibase:claim ?p.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?property ?propertyLabel
ORDER BY DESC(?count)
Try it!
🌿 Properties used on properties maintained by the WikiProject
[edit]

The following query uses these:

  • Properties: maintained by WikiProject (P6104)Β β€―View with ReasonatorΒ View with SQID
    #:title: Properties used on properties maintained by the WikiProject
SELECT DISTINCT ?property ?propertyLabel ?count
WITH {
  SELECT DISTINCT ?entity WHERE {
    ?entity wdt:P6104 wd:Q56241615 .
  }
  LIMIT 200000
  } AS %items 
WITH {
  SELECT DISTINCT ?property (COUNT(*) AS ?count) WHERE {
  INCLUDE %items.
    ?entity ?p [ ] .
    ?property a wikibase:Property;
                wikibase:claim ?p.
  }
  GROUP BY ?property 
  LIMIT 100
  } AS %results 
WHERE {
  INCLUDE %results.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY DESC(?count)
LIMIT 100
Try it!

🚧 Maintenance queries

[edit]

In the following queries, the expected outcome is that there are no results. If there are, this means that some curation is necessary, and to facilitate that, the query variables are arranged such that commenting out the line after the (first or only) DISTINCT line will yield output that can be pasted into QuickStatements to make corresponding edits. Before running such QuickStatements batches, please check those planned edits.

🚧 Works with X in their title but no statement about X being their main subject

[edit]
🚧 X = 'invasive species'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q183368" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "invasive species haswbstatement:P31=Q13442814 -haswbstatement:P921=Q183368".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "invasive(.)species").

}
Try it!
🚧 X = 'invasion biology'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q42985020" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "invasion biology haswbstatement:P31=Q13442814 -haswbstatement:P921=Q42985020".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "invasion(.)biology").

}
Try it!
🚧 X = 'invasion ecology'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q105094378" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "invasion ecology haswbstatement:P31=Q13442814 -haswbstatement:P921=Q105094378".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "invasion(.)ecology").

}
Try it!
🚧 X = 'invasion science'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q113050263" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "invasion science haswbstatement:P31=Q13442814 -haswbstatement:P921=Q113050263".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "invasion(.)science").

}
Try it!
🚧 X = 'invasion success'
[edit]

See also https://w.wiki/65fC.

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q109467185" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "invasion success haswbstatement:P31=Q13442814 -haswbstatement:P921=Q109467185".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "invasion(.)success").

}
Try it!
🚧 X = 'biological invasion'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q446911" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "biological invasion haswbstatement:P31=Q13442814 -haswbstatement:P921=Q446911".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "biological(.)invasion").

}
Try it!
🚧 X = 'biotic invasion'
[edit]

'Biotic invasion' is an alias to biological invasion (Q446911).

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q446911" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "biotic invasion haswbstatement:P31=Q13442814 -haswbstatement:P921=Q446911".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "biotic(.)invasion").

}
Try it!


🚧 X = 'propagule pressure'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q7250076" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "propagule pressure haswbstatement:P31=Q13442814 -haswbstatement:P921=Q7250076".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "propagule(.)pressure").

}
Try it!
🚧 X = 'aquatic invasion'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q110758984" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "aquatic invasion haswbstatement:P31=Q13442814 -haswbstatement:P921=Q110758984".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "aquatic(.)invasion").

}
Try it!
🚧 X = 'enemy release hypothesis'
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID
    SELECT 
  DISTINCT
  ?item ?title
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  ("P921" AS ?property)
  ("Q85759287" AS ?ReplaceWithYourTargetID)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WHERE {
  hint:Query hint:optimizer "None".
  
{  SERVICE wikibase:mwapi {
    bd:serviceParam wikibase:api "Search";
                    wikibase:endpoint "www.wikidata.org";
                    mwapi:srsearch "enemy release hypothesis haswbstatement:P31=Q13442814 -haswbstatement:P921=Q85759287".
      ?page_title wikibase:apiOutput mwapi:title.
  }
 }
  BIND(IRI(CONCAT(STR(wd:), ?page_title)) AS ?item)
  
  ?item wdt:P1476 ?title.
  FILTER REGEX(LCASE(?title), "enemy(.)release(.)hypothesis").

}
Try it!
[edit]

The following query uses these:

  • Properties: title (P1476)Β β€―View with ReasonatorΒ View with SQID, main subject (P921)Β β€―View with ReasonatorΒ View with SQID, taxon rank (P105)Β β€―View with ReasonatorΒ View with SQID, taxon name (P225)Β β€―View with ReasonatorΒ View with SQID
    SELECT DISTINCT ?Taxon ?TaxonName ?SampleWork ?SampleTitle ?WorkCount
WITH {
  SELECT ?work WHERE {
    hint:Query hint:optimizer "None".

    {  SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:api "Search"