Wikidata:WikiProject France/Administrations

From Wikidata
Jump to navigation Jump to search

Ce sous projet explore les administrations publiques en France.

Les administrations publiques sont Sur la Wikipedia francophone, les informations sur les administrations publiques françaises peuvent être importées avec l'Infobox Organisation2.

Identification des administrations publiques[edit]

Les administrations françaises peuvent être identifiées comme des administrations publiques (public administration (Q31728)) situées en France :

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  ?item (wdt:P31/(wdt:P279*)) wd:Q31728;
    wdt:P17 wd:Q142.
}
ORDER BY ?itemLabel

Try it!

On peut aussi identifier les éléments dont la nature est une sous classe de public administration of France (Q2824642) :

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
  ?item (wdt:P31/(wdt:P279*)) wd:Q2824642.
}
ORDER BY (?itemLabel)

Try it!

Administrations d'État[edit]

Les administrations d'État sont identifiées sur Wikidata, soit comme des filiales (subsidiary (P355)), soit comme des parties (has part (P527)) de Government of France (Q1450662).

SELECT DISTINCT ?item ?itemLabel WHERE {
  wd:Q1450662 ((wdt:P355*)/(wdt:P527*)) ?item.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY (?itemLabel)

Try it!

Résumé[edit]

SELECT ?label ?count
WITH {
  SELECT DISTINCT (COUNT(?item) as ?count) WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q2824642.
  }
} AS %sub
WITH {
   SELECT DISTINCT (COUNT(?item) AS ?count) WHERE { 
    ?item (wdt:P31/(wdt:P279*)) wd:Q31728;
      wdt:P17 wd:Q142.
   } 
} AS %all
WITH {
  SELECT (COUNT(?item) as ?count) WHERE {
    wd:Q1450662 ((wdt:P355*)/(wdt:P527*)) ?item.
  }
} AS %etat
WHERE { 
  {
  INCLUDE %all
  BIND("Aministrations publiques en France" as ?label) 
  }
  UNION 
  {
  INCLUDE %sub    
  BIND("Aministrations publiques françaises" as ?label) 
  }
  UNION 
  {
  INCLUDE %etat    
  BIND("Administrations d'Etat" as ?label) 
  }
}
ORDER BY DESC(?count)

Try it!

Propriétés[edit]

Propriétés générales[edit]

Nature de l'élément instance of (P31)[edit]

Hiérarchie des sous classes d'administration publique française[edit]
#defaultView:Tree
SELECT ?root ?rootLabel 
        ?level1 ?level1Label 
        ?level2 ?level2Label  
        ?level3 ?level3Label 
        ?level4 ?level4Label 
        ?level5 ?level5Label 
        ?level6 ?level6Label 
        ?level7 ?level7Label 
        ?level8 ?level8Label 
        ?level9 ?level9Label 
  WHERE {
  BIND(wd:Q2824642 AS ?super)
  ?level1 wdt:P279 ?super.
  OPTIONAL {
    ?level2 wdt:P279 ?level1. 
    OPTIONAL {
      ?level3 wdt:P279 ?level2.
          OPTIONAL {
            ?level4 wdt:P279 ?level3.
            OPTIONAL {
              ?level5 wdt:P279 ?level4.
              OPTIONAL {
                ?level6 wdt:P279 ?level5.
                OPTIONAL {
                  ?level7 wdt:P279 ?level6.
                  OPTIONAL {
                    ?level8 wdt:P279 ?level7.
                      OPTIONAL {
                      ?level9 wdt:P279 ?level8.
                     }
                   }
                 }
               }
             }
          }
      }
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!


Pays souverain country (P17)[edit]

Toutes les administrations françaises devraient avoir comme valeur de country (P17) doit être France (Q142).

Liste des administrations d'État sans valeur de P17[edit]
SELECT ?item ?itemLabel WHERE {
  wd:Q1450662 ((wdt:P355*)/(wdt:P527*)) ?item.
  FILTER(NOT EXISTS { ?item wdt:P17 ?country. })
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY (?itemLabel)

Try it!

Autres propriétés générales[edit]

Identifiants[edit]

Infobox[edit]

Sur la Wikipedia francophone, il est recommandé d'utiliser Infobox Organisation2.

Voir aussi[edit]