Wikidata:WikiProject Armenia/Showcase Queries
Jump to navigation
Jump to search
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
Try it!
# Cities that have an Armenian sister city
SELECT ?item ?itemLabel ?sisterCity ?sisterCityLabel ?coord
WHERE {
?item wdt:P17 wd:Q399 .
?item wdt:P190 ?sisterCity .
?sisterCity wdt:P625 ?coord .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en" .
?item rdfs:label ?itemLabel .
?sisterCity rdfs:label ?sisterCityLabel .
}
}
# What is the most commons birthplace in Armenia for people on Wikipedia
#defaultView:BubbleChart
SELECT ?place ?placeLabel ?count
WHERE
{
{
SELECT ?place (count(?item) as ?count)
WHERE
{
?item wdt:P19 ?place .
?place wdt:P17 wd:Q399 .
}
GROUP BY ?place
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY DESC(?count)
# Map of lakes and 'subclasses of lakes' that lie in Armenia
#defaultView:Map
SELECT ?item ?itemLabel ?location
WHERE {
?item wdt:p279*/wdt:P31 wd:Q23397 .
?item wdt:P17 wd:Q399 .
?item wdt:P625 ?location .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en".
}
}
# Female/Male ratio for people that have Armenian citizenship
#defaultView:BubbleChart
SELECT ?gender ?genderLabel ?count
WHERE
{
{
SELECT ?gender (COUNT(?gender) AS ?count)
WHERE
{
?person wdt:P27 wd:Q399.
?person wdt:P21 ?gender.
}
GROUP BY ?gender
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY DESC(?count)
# Things that are named after Armenian citiziens or people born in Armenia
SELECT ?item ?itemLabel ?person ?personLabel WHERE {
{
?item wdt:P138 ?person .
?person wdt:P27 wd:Q399
}
UNION
{
?item wdt:P138 ?person .
?person wdt:P19 ?place .
?place wdt:P17 wd:Q399 .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
# Map of things that are named after Armenian citiziens or people born in Armenia
#defaultView:Map
SELECT ?item ?itemLabel ?person ?personLabel ?coords WHERE {
{
?item wdt:P138 ?person .
?item wdt:P625 ?coords .
?person wdt:P27 wd:Q399
}
UNION
{
?item wdt:P138 ?person .
?item wdt:P625 ?coords .
?person wdt:P19 ?place .
?place wdt:P17 wd:Q399 .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
# Given names of all people born in Armenia, on Wikidata
#defaultView:BubbleChart
SELECT ?givenName ?givenNameLabel ?count
WHERE
{
{
SELECT ?givenName (count(?item) as ?count)
WHERE {
?item wdt:P19 ?place .
?place wdt:P17 wd:Q399 .
?item wdt:P735 ?givenName .
}
GROUP BY ?givenName
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY DESC(?count)
# What languages do people that are Armenian citiziens (and notable on Wikidata) speak
#defaultView:BubbleChart
SELECT ?language ?languageLabel ?count WHERE
{
{
SELECT ?language (count(?item) as ?count) WHERE {
?item wdt:P27 wd:Q399.
?item wdt:P1412 ?language
}
GROUP BY ?language
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "hy". }
}
ORDER BY DESC(?count)
# What languages do people speak that speak Armenian
#defaultView:BubbleChart
SELECT ?language ?languageLabel ?count WHERE {
{
SELECT ?language (COUNT(?item) AS ?count) WHERE {
?item wdt:P1412 wd:Q8785.
?item wdt:P1412 ?language.
}
GROUP BY ?language
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "hy". }
}
ORDER BY DESC(?count)