User:Toni 001

From Wikidata
Jump to navigation Jump to search
Babel user information
de-N Dieser Benutzer spricht Deutsch als Muttersprache.
es-3 Este usuario tiene un conocimiento avanzado del español.
en-3 This user has advanced knowledge of English.
hu-1 Ez a szerkesztő alapszinten beszéli a magyar nyelvet.
fr-1 Cet utilisateur dispose de connaissances de base en français.
Users by language

Ich bin Toni.

Soy Toni.

I am Toni.

Conflict of interest[edit]

I work at Wolfram Research (Q1367937).

Properties[edit]

Wolfram Language unit code (P7007).

Tango[edit]

Songs[edit]

select
  ?song
  (sample(?songLabel) as ?songLabel)
  (group_concat(distinct ?genreLabel; separator = "; ") as ?genres)
  (group_concat(distinct ?composerLabel; separator = "; ") as ?composers)
  (group_concat(distinct ?lyricistLabel; separator = "; ") as ?lyricists)
  (year(min(?date)) as ?firstYear)
  (sample(?mbID) as ?mbID)
  (sample(?ttID) as ?ttID)
  (sample(?audio) as ?audio)
where {
  ?song wdt:P31 / wdt:P279* wd:Q2188189 . # musical work
  filter not exists { ?song wdt:P31 / wdt:P279* wd:Q2031291 . } # not an album ("release")
  {
    { ?song wdt:P136 / wdt:P279* wd:Q14390274 . } # tango
    union
    { ?song wdt:P136 wd:Q942955 . } # milonga
    union
    { ?song wdt:P136 wd:Q61891621 . } # vals
  }
  optional { ?song rdfs:label ?songLabel . filter(lang(?songLabel) = "es") }
  optional { ?song wdt:P136 / rdfs:label ?genreLabel . filter(lang(?genreLabel) = "es") }
  optional { ?song wdt:P86 / rdfs:label ?composerLabel . filter (lang(?composerLabel) = "es") }
  optional { ?song wdt:P676 / rdfs:label ?lyricistLabel . filter (lang(?lyricistLabel) = "es") }
  optional { ?song wdt:P577 ?date . }
  optional { ?song wdt:P435 ?mbID . }
  optional { ?song wdt:P4932 ?ttID . }
  optional { ?song wdt:P51 ?audio . }
}
group by ?song
order by ?firstYear

Try it!

Musicians[edit]

select distinct * where {
  {
    { ?artist wdt:P31 wd:Q5 . } # human
    union
    { ?artist wdt:P31 wd:Q2088357 . } # group
  }
  ?artist wdt:P136 / wdt:P279* wd:Q14390274 . # tango
  optional { ?artist rdfs:label ?artistLabel . filter(lang(?artistLabel) = "es") }
  optional { ?artist wdt:P434 ?mbartist . }
  optional { ?artist wdt:P4931 ?ttperson . }
}

Try it!