User:Renessaince/SPARQL

From Wikidata
Jump to navigation Jump to search

Пружаншчына[edit]

Нарадзіліся[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID, date of birth (P569) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID, VIAF ID (P214) View with Reasonator View with SQID, IMDb ID (P345) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID
     1 # асобы, якія нарадзіліся на тэрыторыі Пружанскага раёну
     2 SELECT ?item ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?statements (COUNT(DISTINCT ?sitelink) AS ?linkshere) ?VIAF ?IMDb WHERE {
     3   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }   # фарматаваньне метак вываду
     4   BIND(xsd:integer(STRAFTER(STR(?item), "Q")) AS ?qid)                                        
     5   ?item wikibase:statements ?statements.                                                      # дзеля падліку сьцьверджаньняў
     6   OPTIONAL {
     7     ?sitelink schema:about ?item.
     8     ?sitelink schema:inLanguage ?lang.
     9   }                                                                                           # дзеля падліку спасылак на элемэнт
    10   ?item wdt:P31 wd:Q5.                                                                        # толькі людзі
    11   { ?item wdt:P19 wd:Q1885543. }                                                              # месца нараджэньня — Пружанскі раён
    12   UNION
    13   {
    14     ?item wdt:P19 ?pob.
    15     ?pob wdt:P131* wd:Q1885543.
    16   }                                                                                           # альбо месца нараджэньня знаходзіцца ў Пружанскім раёне
    17   OPTIONAL { ?item wdt:P569 ?birthDate. }
    18   OPTIONAL { ?item wdt:P19 ?pob. }
    19   OPTIONAL { ?item wdt:P18 ?pic. }
    20   OPTIONAL { ?item wdt:P214 ?VIAF. }
    21   OPTIONAL { ?item wdt:P345 ?IMDb. }
    22   OPTIONAL { ?pob wdt:P625 ?coord. }
    23 }
    24 GROUP BY ?item ?statements ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?VIAF ?IMDb
    25 ORDER BY DESC(?linkshere)
    

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID, date of birth (P569) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID, VIAF ID (P214) View with Reasonator View with SQID, IMDb ID (P345) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID
     1 # асобы, якія нарадзіліся на тэрыторыі Пружанскага павету
     2 SELECT ?item ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?statements (COUNT(DISTINCT ?sitelink) AS ?linkshere) ?VIAF ?IMDb WHERE {
     3   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }   # фарматаваньне метак вываду
     4   BIND(xsd:integer(STRAFTER(STR(?item), "Q")) AS ?qid)                                        
     5   ?item wikibase:statements ?statements.                                                      # дзеля падліку сьцьверджаньняў
     6   OPTIONAL {
     7     ?sitelink schema:about ?item.
     8     ?sitelink schema:inLanguage ?lang.
     9   }                                                                                           # дзеля падліку спасылак на элемэнт
    10   ?item wdt:P31 wd:Q5.                                                                        # толькі людзі
    11   { ?item wdt:P19 wd:Q4382545. }                                                              # месца нараджэньня — Пружанскі павет (Польшча)
    12   UNION
    13   {
    14     ?item wdt:P19 ?pob.
    15     ?pob wdt:P131* wd:Q4382545.
    16   }                                                                                           # альбо месца нараджэньня знаходзіцца ў Пружанскім павеце
    17   OPTIONAL { ?item wdt:P569 ?birthDate. }
    18   OPTIONAL { ?item wdt:P19 ?pob. }
    19   OPTIONAL { ?item wdt:P18 ?pic. }
    20   OPTIONAL { ?item wdt:P214 ?VIAF. }
    21   OPTIONAL { ?item wdt:P345 ?IMDb. }
    22   OPTIONAL { ?pob wdt:P625 ?coord. }
    23 }
    24 GROUP BY ?item ?statements ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?VIAF ?IMDb
    25 ORDER BY DESC(?linkshere)
    

Населеныя пункты[edit]

The following query uses these:

Славутасьці[edit]

The following query uses these:

Features: Map (Q24515275) View with Reasonator View with SQID

 1 #defaultView:Map
 2 #Усе пружанскія славутасьці
 3 SELECT ?item ?itemLabel ?image ?coord ?катLabel WHERE {
 4   ?item wdt:P1435 ?кат                        # славутасьці
 5   { ?item wdt:P131 wd:Q1885543. }             # у Пружанскім раёне
 6   UNION
 7   {
 8     ?item wdt:P131 ?loc.
 9     ?loc wdt:P131* wd:Q1885543.
10   }                                           # або ў населеным пункце Пружанскага раёну
11   OPTIONAL { ?item wdt:P625 ?coord. }
12   OPTIONAL { ?item wdt:P18 ?image. }
13   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
14 }
15 GROUP BY ?item ?itemLabel ?image ?coord ?катLabel

Сядзібы[edit]

The following query uses these:

Features: Map (Q24515275) View with Reasonator View with SQID

 1 #defaultView:Map
 2 #Усе пружанскія сядзібы
 3 SELECT ?item ?itemLabel ?image ?coord WHERE {
 4   { ?item wdt:P31 wd:Q16560. }                # палацы
 5   UNION
 6   { ?item wdt:P31 wd:Q23413. }                # замкі
 7   UNION
 8   { ?item wdt:P31 wd:Q57831. }                # фартэцыі
 9   UNION
10   { ?item wdt:P31 wd:Q879050. }               # сядзібы
11   UNION
12   { ?item wdt:P31 wd:Q12292478. }             # сядзібы
13   { ?item wdt:P131 wd:Q1885543. }             # у Пружанскім раёне
14   UNION
15   {
16     ?item wdt:P131 ?loc.
17     ?loc wdt:P131* wd:Q1885543.
18   }                                           # або ў населеным пункце Пружанскага раёну
19   OPTIONAL { ?item wdt:P625 ?coord. }
20   OPTIONAL { ?item wdt:P18 ?image. }
21   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
22 }
23 GROUP BY ?item ?itemLabel ?image ?coord

Усё, што мае каардынаты[edit]

The following query uses these:

  • Properties: located in the administrative territorial entity (P131) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID
     1 #Нешта на Пружаншчыне з каардынатамі
     2 SELECT ?item ?itemLabel ?coord WHERE {
     3   { ?item wdt:P131 wd:Q1885543. }             # у Пружанскім раёне
     4   UNION
     5   {
     6     ?item wdt:P131 ?pob.
     7     ?pob wdt:P131* wd:Q1885543.
     8   }
     9   ?item wdt:P625 ?coord.                  # з каардынатамі
    10   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
    11 }
    12 GROUP BY ?item ?itemLabel ?coord
    13 ORDER BY ?itemLabel ?item
    

Беларусь[edit]

Асобы[edit]

Нарадзіліся ў Беларусі[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID
     1 # найпапулярнейшыя ў ВікіЗьвестках асобы, народжаныя на тэрыторыі Беларусі
     2 SELECT ?item ?itemLabel ?statements ?itemDescription (COUNT(DISTINCT ?sitelink) AS ?linkshere) WHERE {
     3   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }   # фарматаваньне метак вываду
     4   BIND(xsd:integer(STRAFTER(STR(?item), "Q")) AS ?qid)                                        
     5   ?item wikibase:statements ?statements.                                                      # дзеля падліку сьцьверджаньняў
     6   OPTIONAL {
     7     ?sitelink schema:about ?item.
     8     ?sitelink schema:inLanguage ?lang.
     9   }                                                                                           # дзеля падліку спасылак на элемэнт
    10   ?item wdt:P31 wd:Q5.                                                                        # толькі людзі
    11   { ?item wdt:P19 wd:Q184. }                                                                  # месца нараджэньня — Беларусь
    12   UNION
    13   {
    14     ?item wdt:P19 ?pob.
    15     ?pob wdt:P131* wd:Q184.
    16   }                                                                                           # альбо месца нараджэньня знаходзіцца ў Беларусі
    17 }
    18 GROUP BY ?item ?statements ?itemLabel ?itemDescription
    19 ORDER BY DESC(?linkshere)
    20 LIMIT 100
    

Нарадзіліся ў гэты дзень[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, date of birth (P569) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID, country of citizenship (P27) View with Reasonator View with SQID, date of death (P570) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID
     1 #Нарадзіліся ў зададзены дзень
     2 SELECT ?элемэнт ?элемэнтLabel ?месцаНараджэньняLabel ?каардынаты ?выява ?датаСьмерці
     3 WHERE
     4 {
     5     BIND(MONTH(NOW()) AS ?месяцАдбору)
     6     BIND(DAY(NOW()) AS ?дзеньАдбору)
     7 
     8     ?элемэнт wdt:P31 wd:Q5.                                                 # толькі людзі
     9     ?элемэнт wdt:P569 ?date.
    10     { ?элемэнт wdt:P19 wd:Q184. }                                           # месца нараджэньня — Беларусь
    11     UNION
    12     { ?элемэнт wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
    13     UNION
    14     { ?элемэнт wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
    15     OPTIONAL { ?элемэнт wdt:P570 ?датаСьмерці. }
    16     OPTIONAL { ?элемэнт wdt:P19 ?месцаНараджэньня. }
    17     OPTIONAL { ?месцаНараджэньня wdt:P625 ?каардынаты. }
    18     OPTIONAL { ?элемэнт wdt:P18 ?выява. }
    19     FILTER (MONTH(?date) = ?месяцАдбору && DAY(?date) = ?дзеньАдбору)
    20     SERVICE wikibase:label {
    21         bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
    22     }
    23 }
    

Памерлі ў дату[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, date of death (P570) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID, country of citizenship (P27) View with Reasonator View with SQID, date of birth (P569) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID, place of death (P20) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID
     1 #Памерлі ў гэты дзень
     2 SELECT ?элемэнт ?элемэнтLabel ?выява ?датаНараджэньня ?месцаНараджэньняLabel ?каардынатыНараджэньня ?месцаСьмерціLabel
     3 WHERE
     4 {
     5     BIND(MONTH(NOW()) AS ?месяцАдбору)
     6     BIND(DAY(NOW()) AS ?дзеньАдбору)
     7 
     8     ?элемэнт wdt:P31 wd:Q5.                                                 # толькі людзі
     9     ?элемэнт wdt:P570 ?date.
    10     { ?элемэнт wdt:P19 wd:Q184. }                                           # месца нараджэньня — Беларусь
    11     UNION
    12     { ?элемэнт wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
    13     UNION
    14     { ?элемэнт wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
    15     OPTIONAL { ?элемэнт wdt:P569 ?датаНараджэньня. }
    16     OPTIONAL { ?элемэнт wdt:P19 ?месцаНараджэньня. }
    17 #    OPTIONAL { ?месцаНараджэньня wdt:P625 ?каардынатыНараджэньня. }
    18     OPTIONAL { ?элемэнт wdt:P20 ?месцаСьмерці. }
    19 #    OPTIONAL { ?месцаСьмерці wdt:P625 ?каардынатыСьмерці. }
    20     OPTIONAL { ?элемэнт wdt:P18 ?выява. }
    21     FILTER (MONTH(?date) = ?месяцАдбору && DAY(?date) = ?дзеньАдбору)
    22     SERVICE wikibase:label {
    23         bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
    24     }
    25 }
    

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, date of death (P570) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID, country of citizenship (P27) View with Reasonator View with SQID, place of death (P20) View with Reasonator View with SQID, date of birth (P569) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID, cause of death (P509) View with Reasonator View with SQID
     1 #Памерлі 29—30 кастрычніка 1937
     2 # Навучыцца фільтраваць паўторныя элемэнты
     3 SELECT ?элемэнт ?элемэнтLabel ?выява (sample(?датаНараджэньня) as ?датаНараджэньня) ?месцаНараджэньняLabel ?каардынатыНараджэньня ?месцаСьмерціLabel ?прычынаLabel
     4 WHERE
     5 {
     6     BIND(1937 AS ?годАдбору)
     7     BIND(10 AS ?месяцАдбору)
     8     BIND(29 AS ?дзеньАдбору)
     9 
    10     ?элемэнт wdt:P31 wd:Q5.                                                 # толькі людзі
    11     ?элемэнт wdt:P570 ?date.
    12     { ?элемэнт wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
    13     UNION
    14     { ?элемэнт wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
    15     UNION
    16     { ?элемэнт wdt:P19/wdt:P131* wd:Q2895. }                                # альбо месца нараджэньня знаходзіцца ў БССР
    17     UNION
    18     { ?элемэнт wdt:P19/wdt:P131* wd:Q1378225. }                             # альбо месца нараджэньня знаходзіцца ў Паўночна-Заходнім краі
    19     UNION
    20     { ?элемэнт wdt:P19/wdt:P131* wd:Q842199. }                              # альбо месца нараджэньня знаходзіцца ў БНР
    21     UNION
    22     { ?элемэнт wdt:P19/wdt:P131* wd:Q68678. }                               # альбо месца нараджэньня знаходзіцца ў ССРБ
    23     UNION
    24     { ?элемэнт wdt:P19/wdt:P131* wd:Q76236. }                               # альбо месца нараджэньня знаходзіцца ў ЛітБеле
    25     UNION
    26     { ?элемэнт wdt:P19/wdt:P131* wd:Q523380. }                              # альбо месца нараджэньня знаходзіцца ў Сярэдняй Літве
    27     UNION
    28     { ?элемэнт wdt:P20/wdt:P131* wd:Q184. }                                 # альбо месца сьмерці знаходзіцца ў Беларусі
    29     OPTIONAL { ?элемэнт wdt:P569 ?датаНараджэньня. }
    30     OPTIONAL { ?элемэнт wdt:P19 ?месцаНараджэньня. }
    31 #    OPTIONAL { ?месцаНараджэньня wdt:P625 ?каардынатыНараджэньня. }
    32     OPTIONAL { ?элемэнт wdt:P20 ?месцаСьмерці. }
    33 #    OPTIONAL { ?месцаСьмерці wdt:P625 ?каардынатыСьмерці. }
    34     OPTIONAL { ?элемэнт wdt:P18 ?выява. }
    35     OPTIONAL { ?элемэнт wdt:P509 ?прычына. }
    36     FILTER (YEAR(?date) = ?годАдбору && MONTH(?date) = ?месяцАдбору && DAY(?date) in (?дзеньАдбору, ?дзеньАдбору+1))
    37     SERVICE wikibase:label {
    38         bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
    39     }
    40 }
    41 GROUP BY ?элемэнт ?элемэнтLabel ?выява ?датаНараджэньня ?месцаНараджэньняLabel ?каардынатыНараджэньня ?месцаСьмерціLabel ?прычынаLabel
    42 # ORDER BY
    

Тэнісісткі[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, sex or gender (P21) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, located in the administrative territorial entity (P131) View with Reasonator View with SQID, country for sport (P1532) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID, occupation (P106) View with Reasonator View with SQID, ranking (P1352) View with Reasonator View with SQID, end time (P582) View with Reasonator View with SQID, sport (P641) View with Reasonator View with SQID
     1 # Беларускія тэнісісткі
     2 SELECT ?item ?itemLabel ?image (sample(?рэйтынг) as ?рэйтынг)
     3 WHERE {
     4   BIND(wd:Q10833314 AS ?тэнісістка)                                  # замяніць на любую іншую прафэсію
     5   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,pl,en". }   # фарматаваньне метак вываду
     6 
     7   ?item wdt:P31 wd:Q5.                                               # толькі людзі
     8   ?item wdt:P21 wd:Q6581072.                                         # жанчыны
     9   { ?item wdt:P19 wd:Q184. }                                         # месца нараджэньня — Беларусь
    10   UNION
    11   { ?item wdt:P19/wdt:P131* wd:Q184. }                               # альбо месца нараджэньня знаходзіцца ў Беларусі
    12   UNION
    13   { ?item wdt:P1532 wd:Q184. }                                       # альбо спартовае грамадзянства Беларусі
    14   ?item p:P106 ?прафэсія.                                            # маюць прафэсію
    15   ?прафэсія ps:P106 ?тэнісістка.                                     # …тэнісісткі
    16   FILTER NOT EXISTS { ?прафэсія pq:P582 ?x }                         # …бяз даты сканчэньня
    17   OPTIONAL { ?item wdt:P18 ?image. }                                 # выява
    18   OPTIONAL { ?item p:P1352 ?адзінкавы.                               # спартовы рэйтынг
    19              ?адзінкавы ps:P1352 ?рэйтынг.
    20              ?адзінкавы pq:P641 wd:Q18123880. }                      # адзінкавы
    21 }
    22 GROUP BY ?item ?itemLabel ?image ?рэйтынг
    23 ORDER BY ?itemLabel IF(BOUND(?рэйтынг), xsd:integer(?рэйтынг), 9999)
    

Паводле стаці[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, sex or gender (P21) View with Reasonator View with SQID
     1 # Колькасьць артыкулаў пра розныя плоці ў беларускай Вікіпэдыі
     2 SELECT (COUNT(?sex) as ?count) ?sexLabel
     3 WHERE {
     4   ?item wdt:P31 wd:Q5. # людзі
     5   ?item wdt:P21 ?sex. # з пазначанай плоцьцю
     6 
     7   ?article schema:about ?item. # якія маюць артыкул
     8   ?article schema:isPartOf <https://be-tarask.wikipedia.org/>. # у *беларускай* Вікіпэдыі
     9 
    10   SERVICE wikibase:label { bd:serviceParam wikibase:language "be-tarask,uk,en,ru". }
    11 } GROUP BY ?sexLabel
    12 ORDER BY DESC(?count)
    

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, sex or gender (P21) View with Reasonator View with SQID, image (P18) View with Reasonator View with SQID, country of citizenship (P27) View with Reasonator View with SQID, occupation (P106) View with Reasonator View with SQID, ethnic group (P172) View with Reasonator View with SQID
     1 #Усе трансы ў беларускай Вікіпэдыі
     2 SELECT ?item ?itemLabel ?pic ?stateLabel (GROUP_CONCAT(DISTINCT ?job; SEPARATOR=", ") AS ?jobs) ?nationLabel
     3 WHERE {
     4   ?item wdt:P31 wd:Q5. # людзі
     5   { ?item wdt:P21 wd:Q1052281. }   # транс
     6   UNION
     7   { ?item wdt:P21 wd:Q2449503. }   # транс
     8   OPTIONAL { ?item wdt:P18 ?pic. }
     9   OPTIONAL { ?item wdt:P27 ?state. }
    10   OPTIONAL { ?item wdt:P106 [rdfs:label ?job]. FILTER(LANG(?job)='be-tarask'). }
    11   OPTIONAL { ?item wdt:P172 ?nation. }
    12 
    13   ?article schema:about ?item. # якія маюць артыкул
    14   ?article schema:isPartOf <https://be-tarask.wikipedia.org/>. # у *беларускай* Вікіпэдыі
    15 
    16   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,en,ru". }
    17 }
    18 GROUP BY ?item ?itemLabel ?pic ?stateLabel ?nationLabel
    

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, country (P17) View with Reasonator View with SQID, sex or gender (P21) View with Reasonator View with SQID
    1 # Беларусы бяз стаці
    2 SELECT ?item ?itemLabel
    3 WHERE {
    4   ?item wdt:P31 wd:Q5.
    5   ?item wdt:P19 ?place.
    6   ?place wdt:P17 wd:Q184.
    7   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,pl,en". }
    8   FILTER(NOT EXISTS { ?item wdt:P21 _:b6. })
    9 }
    

Адсутныя[edit]

The following query uses these:

  • Properties: country of citizenship (P27) View with Reasonator View with SQID
     1 # Элемэнты ВікіЗьвестак пра беларусаў, у якіх адсутнічае метка па-беларуску,
     2 # адсартаваныя паводле колькасьці спасылак.
     3 # Меткі выводзяцца мовамі, зададзенымі ў 8 радку (першая знойдзеная).
     4 # Калі запыт вісьне, трэба раскамэнтаваць 16 радок.
     5 SELECT ?item ?itemLabel ?itemDescription ?linkcount WHERE {
     6   ?item wdt:P27 wd:Q184.                                                      # грамадзяне Беларусі
     7   ?item wikibase:sitelinks ?linkcount.                                        # колькасьць спасылак
     8   SERVICE wikibase:label { bd:serviceParam wikibase:language "en,uk,pl,ru". } # вывесьці метку першай знойдзенай мовай
     9   FILTER(?linkcount >= 2)                                                     # вывесьці толькі калі больш за 2 спасылкі
    10   FILTER(NOT EXISTS {
    11     ?item rdfs:label ?lang_label.
    12     FILTER((LANG(?lang_label)) = "be-tarask")                                 # калі няма па-беларуску
    13   })
    14 }
    15 ORDER BY DESC(?linkcount)
    16 # LIMIT 100
    

Прычыны сьмерці[edit]

The following query uses these:

  • Properties: instance of (P31) View with Reasonator View with SQID, cause of death (P509) View with Reasonator View with SQID, place of birth (P19) View with Reasonator View with SQID, country (P17) View with Reasonator View with SQID, date of birth (P569) View with Reasonator View with SQID, date of death (P570) View with Reasonator View with SQID
     1 #Беларусы паводле прычыны сьмерці
     2 SELECT ?pid ?прэзыдэнт ?прычына_сьмерці ?нарадзіўся ?памёр WHERE {
     3     ?pid wdt:P31 wd:Q5.
     4     ?pid wdt:P509 ?cid.
     5     ?pid wdt:P19 ?place.
     6     ?place wdt:P17 wd:Q184.
     7     ?pid wdt:P569 ?нарадзіўся.
     8     ?pid wdt:P570 ?памёр.
     9 
    10     OPTIONAL {
    11         ?pid rdfs:label ?прэзыдэнт filter (lang(?прэзыдэнт) = "be-tarask") .
    12     }
    13     OPTIONAL {
    14         ?cid rdfs:label ?прычына_сьмерці filter (lang(?прычына_сьмерці) = "be-tarask") .
    15     }
    16 }
    

Замкі, палацы ды фартэцыі[edit]

The following query uses these:

Features: Map (Q24515275) View with Reasonator View with SQID

 1 #Усе беларускія палацы
 2 #defaultView:Map
 3 SELECT ?item ?itemLabel ?image ?coord WHERE {
 4   { ?item wdt:P31 wd:Q16560. }                # палацы
 5   UNION
 6   { ?item wdt:P31 wd:Q23413. }                # замкі
 7   UNION
 8   { ?item wdt:P31 wd:Q57831. }                # фартэцыі
 9   ?item wdt:P17 wd:Q184.                      # у Беларусі
10   OPTIONAL { ?item wdt:P625 ?coord. }
11   OPTIONAL { ?item wdt:P18 ?image. }
12   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
13 }

Насельніцтва суседніх дзяржаваў[edit]

The following query uses these:

  • Properties: shares border with (P47) View with Reasonator View with SQID, population (P1082) View with Reasonator View with SQID, point in time (P585) View with Reasonator View with SQID
     1 #defaultView:LineChart
     2 # Насельніцтва краінаў-суседак
     3 SELECT ?country ?year ?population ?countryLabel WHERE {
     4   {
     5     SELECT ?country ?year (AVG(?population) AS ?population) WHERE {
     6       {
     7         SELECT ?country (str(YEAR(?date)) AS ?year) ?population WHERE {
     8           ?country wdt:P47 wd:Q184;   # shares border with Biełaruś
     9                    p:P1082 ?populationStatement.
    10           ?populationStatement ps:P1082 ?population;
    11                                pq:P585 ?date.
    12         }
    13       }
    14     }
    15     GROUP BY ?country ?year
    16   }
    17   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
    18 }
    

ВікіЭкспэдыцыі[edit]

Палесьсе — славутасьці[edit]

The following query uses these:

Features: Map (Q24515275) View with Reasonator View with SQID

 1 #defaultView:Map
 2 #Да вандроўкі на Палесьсе
 3 SELECT ?item ?itemLabel ?image ?coord ?катLabel WHERE {
 4   ?item wdt:P1435 ?кат                        # славутасьці
 5   { ?item wdt:P131 wd:Q367015. }              # у Жыткавіцкім раёне
 6   UNION
 7   {
 8     ?item wdt:P131 ?loc.
 9     ?loc wdt:P131* wd:Q367015.
10   }                                           # або ў населеным пункце Жыткавіцкага раёну
11   UNION
12   { ?item wdt:P131 wd:Q1885628. }             # у Лунінецкім раёне
13   UNION
14   {
15     ?item wdt:P131 ?loc.
16     ?loc wdt:P131* wd:Q367015.
17   }                                           # або ў населеным пункце Лунінецкага раёну
18   UNION
19   { ?item wdt:P131 wd:Q1885570. }             # у Столінскім раёне
20   UNION
21   {
22     ?item wdt:P131 ?loc.
23     ?loc wdt:P131* wd:Q1885570.
24   }                                           # або ў населеным пункце Столінскага раёну
25   OPTIONAL { ?item wdt:P625 ?coord. }
26   OPTIONAL { ?item wdt:P18 ?image. }
27   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
28 }
29 GROUP BY ?item ?itemLabel ?image ?coord ?катLabel

Палесьсе — усё з каардынатамі[edit]

The following query uses these:

  • Properties: located in the administrative territorial entity (P131) View with Reasonator View with SQID, coordinate location (P625) View with Reasonator View with SQID
     1 #Нешта на Палесьсі з каардынатамі
     2 SELECT ?item ?itemLabel ?coord WHERE {
     3   { ?item wdt:P131 wd:Q367015. }          # у Жыткавіцкім раёне
     4   UNION
     5   {
     6     ?item wdt:P131 ?loc.
     7     ?loc wdt:P131* wd:Q367015.
     8   }                                       # або ў населеным пункце Жыткавіцкага раёну
     9   UNION
    10   { ?item wdt:P131 wd:Q1885628. }         # у Лунінецкім раёне
    11   UNION
    12   {
    13     ?item wdt:P131 ?loc.
    14     ?loc wdt:P131* wd:Q367015.
    15   }                                       # або ў населеным пункце Лунінецкага раёну
    16   UNION
    17   { ?item wdt:P131 wd:Q1885570. }         # у Столінскім раёне
    18   UNION
    19   {
    20     ?item wdt:P131 ?loc.
    21     ?loc wdt:P131* wd:Q1885570.
    22   }                                       # або ў населеным пункце Столінскага раёну
    23   ?item wdt:P625 ?coord.                  # з каардынатамі
    24   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
    25 }
    26 GROUP BY ?item ?itemLabel ?coord
    27 ORDER BY ?itemLabel ?item
    

Глядзіце таксама[edit]