User:Erfurth/GLAM

Archive in Deutschland und ihre Bestände

# Archive in Deutschland: eingehende Verwendungen von Property:P485 ("archives at") zählen
SELECT ?archive ?archiveLabel (COUNT(?item) AS ?archivesAtCount) WHERE {
  # Archive in Deutschland
  ?archive wdt:P17 wd:Q183 ;
           (wdt:P31/wdt:P279*) wd:Q166118 .

  # Items, die im jeweiligen Archiv liegen
  ?item wdt:P485 ?archive .

  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
GROUP BY ?archive ?archiveLabel
ORDER BY DESC(?archivesAtCount)

Try it!

... und für alle Archive (Timeout möglich): https://w.wiki/FrWC

bloggende Archive

#defaultView:Map,Table
SELECT distinct ?item ?itemLabel ?itemDescription ?image ?coord ?verwaltungseinheitLabel ?streetLabel ?zip ?adress ?blog ?layerLabel {

  ?item wdt:P17 wd:Q183.
  ?item (wdt:P31/wdt:P279*) wd:Q166118 . # ist ein Archiv oder Subklasse davon
  ?item wdt:P31 ?layer.
   OPTIONAL { ?item wdt:P18 ?image . }     
  OPTIONAL { ?item wdt:P625 ?coord. }  
  OPTIONAL { ?item wdt:P6375 ?adress. }  
  OPTIONAL { ?item wdt:P131 ?verwaltungseinheit. } 
 ?item wdt:P1581 ?blog. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
} ORDER BY ?layerLabel

Try it!

Gartenlauben-Items mit GLAM-Bezug

SELECT DISTINCT ?item ?itemLabel ?mainSubjectLabel ?cityLabel (GROUP_CONCAT(DISTINCT ?glamItem; separator=', ') AS ?GLAM)
 WHERE
 {
   ?item wdt:P1433 wd:Q655617.
   ?item wdt:P921 ?mainSubject.
   ?glamItem wdt:P279+ wd:Q1030034 .
   ?mainSubject wdt:P31 ?glamItem.
   ?mainSubject wdt:P131 ?city.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
 } GROUP BY ?item ?itemLabel ?mainSubjectLabel ?cityLabel ?GLAM ORDER BY ?mainSubjectLabel

Try it!

Niedersachsen

• regionquery

#defaultView:Map,Table
SELECT distinct ?item ?itemLabel ?itemDescription ?image ?coord ?verwaltungseinheitLabel ?streetLabel ?zip ?adress ?blog ?layerLabel
WITH {
 SELECT distinct ?region                   # Unterabfrage für alle Verwaltungseinheiten (Kreise, Städte, Gemeinden, Ortsteile, etc.)
 WHERE {
 hint:Query hint:optimizer "None" .         
 BIND(wd:Q1197 AS ?state).                 # liegt in Niedersachsen
 ?region wdt:P131* ?state.            
 MINUS { ?region wdt:P576 _:b0. }          # Verwaltungseinheit ohne Auflösungsdatum   
 }
} AS %region

WHERE {
  INCLUDE %region.
  ?item wdt:P131 ?region.      
  ?item (wdt:P31/wdt:P279*) wd:Q166118 . # ist ein Archiv oder Subklasse davon
  ?item wdt:P31 ?layer.
   OPTIONAL { ?item wdt:P18 ?image . }     
  OPTIONAL { ?item wdt:P625 ?coord. }  
  OPTIONAL { ?item wdt:P6375 ?adress. }  
  OPTIONAL { ?item wdt:P131 ?verwaltungseinheit. } 
  OPTIONAL { ?item wdt:P1581 ?blog. }  
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
} ORDER BY ?layerLabel

Try it!

• regionquery via TOP100 niedersächsischer Städte WP-List

SELECT ?archiv ?archivLabel ?blog WHERE {
  VALUES ?item { wd:Q1860693 }  
  ?item wdt:P921 ?mainSubject .
  ?archiv (wdt:P31/wdt:P279*) wd:Q166118 .
  ?archiv wdt:P131 ?mainSubject .
  OPTIONAL { ?archiv wdt:P1581 ?blog. }  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
} GROUP BY ?archiv ?archivLabel ?blog

Try it!

Wartungslisten (mit Karte)

#alle Archiv-Items mit DDB-ID ohne P6375 street address
SELECT DISTINCT ?item ?itemLabel (URI(CONCAT("https://www.wikidata.org/wiki/Special:SetLabelDescriptionAliases/", substr(str(?item),32),"/en")) as ?editURL) ?coord
WHERE
{
  ?item wdt:P13081 ?id.                 # alle Items mit DDB-IDs
  ?item (wdt:P31/wdt:P279*) wd:Q166118. # alle Archive und Subklassen davon
  ?item wdt:P625 ?coord.                # mit Geo-Koordinaten
  minus {
   ?item wdt:P6375 []                    # nur Items ohne Ortsangabe
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
} ORDER BY ?itemLabel

Try it!

#alle Archiv-Items ohne VIAF als Karte
#defaultView:Map
SELECT ?item ?itemLabel ?coord
WHERE
{
  ?item (wdt:P31/wdt:P279*) wd:Q166118. # alle Archive und Subklassen davon
  ?item wdt:P625 ?coord.                # mit Geo-Koordinaten
  minus {
   ?item wdt:P214 []                    # nur Items ohne VIAF-ID
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!

Wartungslisten (ohne Karte)

#alle Archiv-Items von Deutschland ohne Koordinate
SELECT ?item ?itemLabel ?cityLabel
WHERE
{
  ?item (wdt:P31/wdt:P279*) wd:Q166118. # alle Archive und Subklassen davon
  ?item wdt:P17 wd:Q183.                # mit Land: Deutschland
  ?item wdt:P131 ?city.                 # liegt in einer Stadt
  minus {
   ?item wdt:P625 []                    # nur Items ohne Geo-Koordinaten
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!

SELECT ?archive ?archiveLabel ?noStatements WHERE {
  ?archive wdt:P31/wdt:P279* wd:Q166118 ;
           wdt:P17 wd:Q183 ;
           wikibase:statements ?noStatements .
  FILTER(?noStatements<6)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
  } ORDER BY ?noStatements

Try it!