Property talk:P6135

From Wikidata
Jump to navigation Jump to search

Documentation

VD 18 ID
publication ID in the bibliography of 18th century printed material in the German speaking areas
[create Create a translatable help page (preferably in English) for this property to be included here]
Single value: this property generally contains a single value. (Help)
Exceptions are possible as rare values may exist.
List of this constraint violations: Database reports/Constraint violations/P6135#Single value, SPARQL, SPARQL (new)
Distinct values: this property likely contains a value that is different from all other items. (Help)
Exceptions are possible as rare values may exist.
List of this constraint violations: Database reports/Constraint violations/P6135#Unique value, SPARQL (every item), SPARQL (by value), SPARQL (new)
Format “[0-9]\d{7}: value must be formatted using this pattern (PCRE syntax). (Help)
Exceptions are possible as rare values may exist.
List of this constraint violations: Database reports/Constraint violations/P6135#Format, SPARQL, SPARQL (new)

Items that should have VD 18 identifiers[edit]

Filtering all publications results in a timeout but selected publication types from the 18th century can be queried like this:

SELECT ?p ?pLabel ?pDescription ?year ?vd18 WHERE {
  # books and periodicals (all publications would lead to timeout)
  { { ?p wdt:P31/wdt:P279* wd:Q571 } UNION
    { ?p wdt:P31/wdt:P279* wd:Q1002697 } }
  
  # filter by date
  ?p wdt:P577 ?date .  
  FILTER (year(?date) >= 1701) .
  FILTER (year(?date) <= 1800) .

  # Publications with German or unknown language
  OPTIONAL { 
    ?p wdt:P407 ?lang 
    FILTER NOT EXISTS { ?p wdt:P407 wd:Q188 }
  } 
  FILTER (!BOUND(?lang)) .
  
  # get VD 18 ID, year, and labels
  OPTIONAL { ?p wdt:P6135 ?vd18 }
  BIND (year(?date) AS ?year) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
} ORDER BY DESC(?vd18)

Try it!

See also Category 18th century in German Wikisource.

Items with VD18 ID and German Wikisource page[edit]

SELECT ?item ?itemLabel ?year ?vd18 ?wikisource ?wikipedia WHERE {
  ?item wdt:P6135 ?vd18 .     
  ?item wdt:P577 ?date .   
  OPTIONAL {
    ?wikisource schema:about ?item .   
    FILTER (SUBSTR(STR(?wikisource),1,25)="https://de.wikisource.org")
  }
  OPTIONAL {
    ?wikipedia schema:about ?item .
    FILTER (SUBSTR(STR(?wikipedia),1,25)="https://de.wikipedia.org/")
  }
  BIND (year(?date) AS ?year) .  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
} ORDER BY ASC(?year)

Try it!